#pragma TextEncoding = "MacRoman"
#pragma rtGlobals=3		// Use modern global access method and strict wave access.

// creates an image from all suitable waves in current folder
Function wave2image(String prefix, String suffix)
	
	String dataList = WaveList(prefix+"*"+suffix,";","")	// list of suitable waves in current folder
	dataList = SortList(dataList, ";", 16)					// make sure the list is in the right order
	Variable i, items = ItemsInList(dataList)
	
	Make/free/N=(items) tempIndices = NaN	// the free flag creates transient data
	for (i=0; i<items; i+=1)				// extract all indices from the names
		String currItem = StringFromList(i,dataList)
		tempIndices[i] = str2num(ReplaceString(prefix,ReplaceString(suffix,currItem,""),""))
	endfor
	WaveTransform/O zapNaNs tempIndices		// get rid of all invalid (NaN) entries
	items = numpnts(tempIndices)
	
	Make/free/N=(items-1) tempDiff			// the spacing will be the minimum of all distances between entries
	tempDiff = tempIndices[p+1]-tempIndices[p]
	
	Variable spacing = waveMin(tempDiff)
	Variable start 	 = tempIndices[0]
	Variable finish  = tempIndices[items-1]
	Variable imageSize = (finish-start)/spacing
	
	Wave currWave = $(prefix+num2str(start)+suffix)	// assumes that all waves have the same size and scaling
	Make/O/N=(imageSize,DimSize(currWave,0)) $(prefix+"Image"+suffix)=NaN
	Wave workImage = $(prefix+"Image"+suffix)
	SetScale/I x, start, finish, workImage
	SetScale/P y, DimOffset(currWave, 0), DimDelta(currWave, 0), workImage
	
	for (i=0; i<items; i+=1)				// write each wave from the list into the image
		Wave currWave = $(prefix+num2str(tempIndices[i])+suffix)
		workImage[x2pnt(workImage,tempIndices[i])][] = currWave[q]
	endfor
	
	return 0
End