#pragma TextEncoding = "UTF-8"
#pragma rtGlobals=3				// Use modern global access method and strict wave access
#pragma DefaultTab={3,20,4}		// Set default tab width in Igor Pro 9 and later
#pragma version=3				// JP230609: v3, added missing gstop
								// JP230609: v2, uses DrawPoly/ABS, revised Graph user menus
#pragma moduleName=MoveTraceToBack

#include <Graph Utility Procs>

// work around Igor 9.02's AllTracesPopup QuickFit menu bug
#if IgorVersion() > 9.02 
Menu "TracePopup", dynamic
	MoveTraceToBack#MenuItemForTrace("Move %s to ProgBack"),/Q, GetLastUserMenuInfo; fMoveTraceToProgBack(S_graphName, S_traceName)
	Submenu "Restore ProgBack Trace"
		ProgBackTracesList(WinName(0,1,1)), /Q, GetLastUserMenuInfo; fRemoveProgBackTrace(S_graphName, S_value)
	End
End
Menu "AllTracesPopup"
	"Restore All ProgBack Traces",/Q, RemoveAllProgBackTraces(WinName(0,1,1))
End
#else
Menu "TracePopup", dynamic
	MoveTraceToBack#MenuItemForTrace("Move %s to ProgBack"),/Q, GetLastUserMenuInfo; fMoveTraceToProgBack(S_graphName, S_traceName)
	Submenu "Restore ProgBack Trace"
		ProgBackTracesList(WinName(0,1,1)), /Q, GetLastUserMenuInfo; fRemoveProgBackTrace(S_graphName, S_value)
		"Restore All ProgBack Traces",/Q, RemoveAllProgBackTraces(WinName(0,1,1))
	End
End
#endif

Menu "GraphPopup", dynamic
	Submenu "Restore ProgBack Trace"
		ProgBackTracesList(WinName(0,1,1)), /Q, GetLastUserMenuInfo; fRemoveProgBackTrace(S_graphName, S_value)
	End
	"Restore all ProgBack Traces",/Q, RemoveAllProgBackTraces(WinName(0,1,1))
	"Show all Traces", /Q, fShowAllTraces(WinName(0,1,1))
End

Menu "Graph"
	"-"
//	"Move a Trace to ProgBack...",/Q, MoveTraceToProgBack()
	Submenu "Move a Trace to ProgBack"
		NotProgBackTracesList(WinName(0,1,1)), /Q, GetLastUserMenuInfo; fMoveTraceToProgBack(S_graphName, S_value)
	End
//	"Restore a ProgBack Trace...",/Q, RemoveProgBackTrace()
	Submenu "Restore ProgBack Trace"
		ProgBackTracesList(WinName(0,1,1)), /Q, GetLastUserMenuInfo; fRemoveProgBackTrace(S_graphName, S_value)
	End
	"Restore all ProgBack Traces",/Q, RemoveAllProgBackTraces(WinName(0,1,1))
	"Show all Traces", /Q, fShowAllTraces(WinName(0,1,1))
	"-"
End

static Function/S MenuItemForTrace(String format) // format is menu item text with %s for trace name
	GetLastUserMenuInfo
	String traceName= "Trace"
	if( strlen(S_traceName)  )
		traceName= S_traceName
	endif
	String menuItem
	sprintf menuItem, format, traceName
	
	return menuItem
End

Proc MoveTraceToProgBack(traceName)
	String traceName
	Prompt traceName, "Trace to move to ProgBack", popup, TraceNameList(WinName(0,1,1),";",0x1)
	
	fMoveTraceToProgBack(WinName(0,1,1), traceName)
End

Function fMoveTraceToProgBack(String graphName, String traceName)

	// get information from trace to replicate selected properties in the polygon
	String info= TraceInfo(graphName, traceName, 0) // instance taken from traceName
	String xaxis = StringByKey("XAXIS", info)
	String yaxis = StringByKey("YAXIS", info)
	String rgbaStr = WMGetRECREATIONInfoByKey("rgb(x)", info)
	Variable red, green, blue, alpha
	ParseColor(rgbaStr, red, green, blue, alpha)
	Variable lSize = str2num(WMGetRECREATIONInfoByKey("lSize(x)", info))
	Variable lStyle = str2num(WMGetRECREATIONInfoByKey("lStyle(x)", info))
	
	WAVE wy = TraceNameToWaveRef(graphName, traceName)
	WAVE/Z wx = XWaveRefFromTrace(graphName, traceName)
	if( !WaveExists(wx) )
		// Create an x wave from the y wave's x scaling
		// in the same data folder as the y wave.
		String wxName= CleanupName(NameOfWave(wy)+"_x",0)
		DFREF waveDFR = GetWavesDataFolderDFR(wy)
		DFREF saveDFR = GetDataFolderDFR()
		SetDataFolder waveDFR
		Duplicate/O wy, $wxName // OVERWRITE
		WAVE wx = $wxName
		wx=x
		SetDataFolder saveDFR
	endif
	
	// replace any existing polygon in the group named after the trace.
	String groupName= GroupNameForTrace(traceName)
	
	SetDrawLayer/W=$graphName ProgBack	// TO DO: input destination layer name as parameter
	DrawAction/W=$graphName getgroup=$groupName, delete, begininsert
	
	SetDrawEnv/W=$graphName gstart,gname= $groupName
	SetDrawEnv/W=$graphName xcoord= $xaxis,ycoord= $yaxis, fillpat=0 // no fill
	SetDrawEnv/W=$graphName linefgc=(red,green,blue,alpha)
	SetDrawEnv/W=$graphName linethick=lSize
	SetDrawEnv/W=$graphName dash=lStyle
//	DrawPoly /W=$graphName wx[0],wy[0],1,1,wx,wy
	DrawPoly /W=$graphName/ABS 0,0,1,1,wx,wy // this way, if wx[0] or wy[0] changes, so does the ProgBack poly
	SetDrawEnv/W=$graphName gstop

	DrawAction/W=$graphName  endinsert
	SetDrawLayer/W=$graphName $S_Name	

	ModifyGraph /W=$graphName hideTrace($traceName)=1
End

Proc RemoveProgBackTrace(traceName)
	String traceName
	Prompt traceName, "Trace to remove from ProgBack", popup, ProgBackTracesList(WinName(0,1,1))
	
	fRemoveProgBackTrace(WinName(0,1,1), traceName)
End


Function RemoveAllProgBackTraces(String graphName)

	String traces = TraceNameList(graphName,";",0x1) // 0x1 includes hidden traces
	Variable i, n=ItemsInList(traces)
	for(i=0; i<n; i+=1 )
		String traceName= StringFromList(i,traces)
		fRemoveProgBackTrace(graphName, traceName)
	endfor
End

Function fRemoveProgBackTrace(String graphName, String traceName)

	// delete any existing polygon in the group named after the trace.
	String groupName= GroupNameForTrace(traceName)
	
	SetDrawLayer/W=$graphName ProgBack	// TO DO: input destination layer name as parameter
	DrawAction/W=$graphName getgroup=$groupName, delete
	SetDrawLayer/W=$graphName $S_Name	

	// Delete any X wave we created for a waveform replicated as a polygon	
	WAVE wy = TraceNameToWaveRef(graphName, traceName)
	WAVE/Z wx = XWaveRefFromTrace(graphName, traceName)
	if( !WaveExists(wx) )
		String wxName= CleanupName(NameOfWave(wy)+"_x",0)
		DFREF waveDFR = GetWavesDataFolderDFR(wy)
		DFREF saveDFR = GetDataFolderDFR()
		SetDataFolder waveDFR
		WAVE/Z wx = $wxName
		if( WaveExists(wx) )
			KillWaves/Z wx
		endif
		SetDataFolder saveDFR
	endif
	
	ModifyGraph /W=$graphName hideTrace($traceName)=0
End

Function fShowAllTraces(String graphName)
	String traces = TraceNameList(graphName,";",0x1) // 0x1 includes hidden traces
	Variable i, n=ItemsInList(traces)
	for(i=0; i<n; i+=1 )
		String traceName= StringFromList(i,traces)
		ModifyGraph /W=$graphName hideTrace($traceName)=0
	endfor
End

Static Function/S GroupNameForTrace(String traceName) // can be "Q510415e#1", for example

	String cleaned = CleanupName(traceName,0)
	return cleaned
End

Static Function ParseColor(String rgbaStr, Variable &red, Variable &green, Variable &blue, Variable &alpha)

	red = 65535	// default is opaque red
	green = 0
	blue = 0
	alpha = 65535

	sscanf rgbaStr, "(%d,%d,%d,%d)", red, green, blue, alpha
	Variable valid = V_Flag == 4
	if( !valid ) // maybe just rgb
		alpha = 65535
		sscanf rgbaStr, "(%d,%d,%d)", red, green, blue
		valid = V_Flag == 3
	endif
	return valid
End

Function/S ProgBackTracesList(String graphName)

	String list=""
	if( WinType(graphName) == 1 )
		SetDrawLayer/W=$graphName ProgBack	// SetDrawLayer sets S_Name to the name of the previously-selected drawing layer
		String S_recreation="" 				// in case the layer has no drawing objects
		DrawAction/W=$graphName commands		// Stores commands in S_recreation
		// search S_recreation for group names
		String groupCommands= GrepList(S_recreation, ",gname=" ,0 , "\r" )
		// For example:
		//   	SetDrawEnv gstart,gname= Q510415a
		Variable i, n=ItemsInList(groupCommands,"\r")
		for(i=0; i<n; i+=1 )
			String cmd= StringFromList(i,groupCommands, "\r")
			String groupName
			SplitString/E=".*gname= (.*)" cmd, groupName
			list += groupName + ";"
		endfor

		SetDrawLayer/W=$graphName $S_Name
	endif

	return list
End

Function/S NotProgBackTracesList(String graphName)

	String list=""
	if( WinType(graphName) == 1 )
		String progBackList = ProgBackTracesList(graphName)
		// look though all visible traces, discard those that have a progback DrawPoly.
		// this case is unusual, since fMoveTraceToProgBack() hides the trace,
		// but the user is free to un-hide it.
		String traces = TraceNameList(graphName,";",0x3) // 0x3 does not include hidden traces
		Variable i, n=ItemsInList(traces)
		for(i=0; i<n; i+=1 )
			String traceName= StringFromList(i,traces)
			String groupName= GroupNameForTrace(traceName) // traceName can be "Q510415e#1", for example
			Variable which = WhichListItem(groupName,progBackList)
			if( which < 0 ) // no ProgBack poly for this trace
				list += traceName + ";"
			endif
		endfor
	endif

	return list
End