#pragma TextEncoding = "UTF-8"
#pragma rtGlobals=3		// Use modern global access method and strict wave access.
#pragma rtFunctionErrors=1
#pragma ModuleName = TL //Transfer Layout (TL)

//Ben Murphy-Baum
//March, 2023

//******************* Transfer Layout **********************
//**********************************************************
// This package provides users a way to extract the data included in a layout to
// another Igor file for further work. 

//Access through the 'Data' menu or run manually as TL#SaveLayout(name=layoutNameStr) and TL#ImportLayout()

// Save Layout : 
// 	Save all waves associated with every graph in a layout to a HDF5 file,
// 	along with the window recreation code for each graph, and the layout itself.
//		Error waves, X scaling waves, contours, images, and normal traces are included.
//		Layouts are saved in User Procedures:NeuroTools+:Layouts

// Import Layout :
//		Loads the waves from the saved layout HDF5 file, and runs the window recreation
//		code for the graphs and then the layout to rebuild the layout in the new Igor file. 
//		If a wave being imported already exists, it is not overwritten and the original wave is maintained. 
//**********************************************************
//**********************************************************

Menu "Data",dynamic
	SubMenu "Transfer Layout"
		SubMenu "Save Layout"
			TL#GetLayoutList(),/Q, TL#SaveLayout()
		End
		"Import Layout",/Q, TL#ImportLayout()
	End
End

Static Function/S GetLayoutList()
	return WinList("*",";","WIN:4")
End

Static Function SaveLayout([name])
	String name
	//With this optional parameter, users can run the function manually through the command line
	//instead of through the 'Data' menu
	
	If(ParamIsDefault(name))
		GetLastUserMenuInfo
		If(!strlen(S_Value))
			return 0
		EndIf
		
		String layoutName = S_Value
	Else
		layoutName = name
	EndIf
	
	DFREF saveDF = GetDataFolderDFR()
	
	//This is important for getting the correct paths to waves with the recreation macro
	//ImportLayout() also bases itself from root:
	SetDataFolder root:
	
	Variable i,j,k,whichPage,groupRef,fileRef,objectRef
	String objectInfo = ""
	String graphName = ""
	
	//Close any open HDF5 files
	HDF5CloseFile/A 0
	
	//Saves the HDF5 files to specific location right now. 
	//Make the NeuroTools+ folder if it doesn't exist, and the layouts subfolder
	String pathStr = SpecialDirPath("Igor Pro User Files",0,0,0) + "User Procedures:NeuroTools+"
	NewPath/Q/Z/O/C layoutPath,pathStr
	pathStr += ":Layouts"
	NewPath/Q/Z/O/C layoutPath,pathStr
	
	If(V_flag)
		return 0
	EndIf
	
	//Ask what to name the layout file
	String savedLayoutName = layoutName
	Prompt savedLayoutName,"Layout Name:"
	DoPrompt "Save Layout",savedLayoutName
	
	If(V_flag || !strlen(savedLayoutName))
		return 0
	EndIf
	
	//Ensure correct extension	
	savedLayoutName = RemoveEnding(savedLayoutName,".h5") + ".h5"	
	
	//Loop around until we get a unique file name or we agree to overwrite or cancel
	Do
		//Create the h5 file, overwrite if asked
		HDF5CreateFile/Z/P=layoutPath fileRef as SavedLayoutName
		If(V_flag)
			
			DoAlert/T="Overwrite file" 1,"Overwrite existing file?"
			If(V_flag == 1)
				//Delete the file entirely to reclaim the memory for the 'overwrite'
				DeleteFile/P=layoutPath/Z SavedLayoutName
				HDF5CreateFile/O/Z/P=layoutPath fileRef as SavedLayoutName
				break
			Else
				savedLayoutName = RemoveEnding(savedLayoutName,".h5")
				DoPrompt "Save Layout",savedLayoutName
				If(V_flag)
					return 0
				EndIf
				savedLayoutName = RemoveEnding(savedLayoutName,".h5") + ".h5"	
			EndIf
		Else
			break
		EndIf
	While(1)

	//This will hold the waves we need to dispose of after the program finishes
	String cleanupList = ""
	
	//Put the layout window recreation macro into a text wave
	//Each line of the macro goes into a different row of the text wave
	String winRec = WinRecreation(layoutName,0)
	Make/T/N=1000/O root:$(layoutName + "_Code")/Wave=LayoutCode
	
	cleanupList += GetWavesDataFolder(LayoutCode,2) + ";"

	Variable pos = 0
	Variable startPos = 0
	Variable count = 0 
	Do
		startPos = pos
		pos = strsearch(winRec,"\r",startPos)
		
		If(pos == -1 || count + 1 > DimSize(LayoutCode,0) - 1)
			break
		EndIf
		
		LayoutCode[count] = winRec[startPos,pos]
		count += 1
		pos += 1 //move past the carriage return			
	While(1)
	Redimension/N=(count) LayoutCode
	
	String info = LayoutInfo	(layoutName,"Layout")
	Variable nPages = NumberByKey("NUMPAGES",info,":",";")
	
	//Saves the waves included in each page of the layout
	For(whichPage=1;whichPage < nPages + 1;whichPage ++)
		
		//Set the layout page
		LayoutPageAction/W=$layoutName page=whichPage
		
		info = LayoutInfo	(layoutName,"Layout")
		Variable nObjects = NumberByKey("NUMOBJECTS",info,":",";")
		
		//Saves the window recreation macro into a text wave for each graph object
		For(i=0;i<nObjects;i++)
			winRec = "" //reset this
			SetDataFolder root:
			
			objectInfo = LayoutInfo(layoutName,num2str(i))
			graphName = StringByKey("NAME",objectInfo,":",";")
			
			winRec = WinRecreation(graphName,0)
			
			If(!strlen(winRec))
				continue
			EndIf
			
			Make/T/N=1000/O root:$(graphName + "_Code")/Wave=Code
			
			cleanupList += GetWavesDataFolder(Code,2) + ";"
			
			//Get the window recreation macro
			Code = ""
			
			pos = 0
			startPos = 0
			count = 0 
			Variable isViolinPlot = 0
			String violinPath = ""
			
			Do
				startPos = pos
				pos = strsearch(winRec,"\r",startPos)
				
				If(pos == -1 || count + 1 > DimSize(Code,0) - 1)
					break
				EndIf
				
				Code[count] = winRec[startPos,pos]
				
				//Sketchy work around for violin plots. TraceNameList has a bug I think that will only detect
				//the first wave in the violin plot, if multiple have been appended.
				//This detects the line they are appended to the violin plot, so we can extract the full wave list from
				//the recreation macro later
				If(stringmatch(Code[count],"*AppendViolinPlot*"))
					isViolinPlot = count
				EndIf
				
				count += 1
				pos += 1 //move past the carriage return			
			While(1)
			Redimension/N=(count) Code
			
			//Get the data paths that go into the graph
			String traceType = ""
			String traceList = TraceNameList(graphName,";",2^0 + 2^1 + 2^3 + 2^4)
			
			//Violin plot fails to find all traces within it, so we need to manually find them all.
			If(isViolinPlot)
				String violinWaveList = Code[isViolinPlot]
				violinWaveList = violinWaveList[strlen("\tAppendViolinPlot "),strlen(violinWaveList)]
				traceList = RemoveListItem(ItemsInList(traceList,";")-1,traceList,";")
				
				For(k=0;k<ItemsInList(violinWaveList,",");k++)
					//Since the first wave of the violin plot is detected by tracenamelist, we can use it to get the folder path
					//that might be used for all the others. This is sketchy, since the other violin plot traces might not 
					//originate in the same folder. Probably better work around should be found, but this does the trick for now.
					If(k == 0)
						violinPath = GetWavesDataFolder(TraceNameToWaveRef(graphName,StringFromList(k,violinWaveList,",")),1)
					EndIf
					traceList += RemoveEnding(StringFromList(k,violinWaveList,","),"\r") + ";"
				EndFor
			EndIf
			
			//Keep track of the type of trace as well
			For(k=0;k<ItemsInList(traceList,";");k++)
				If(isViolinPlot)
					traceType += "VIOLIN;"
					
				Else
					traceType += "TRACE;"
				EndIf
			EndFor
			
			//Check for user tick waves in the axis
			String axList = AxisList(graphName)
			Variable m
			For(k=0;k<ItemsInList(axList,";");k++)
				String axisInfoStr = AxisInfo(graphName,StringFromList(k,axList,";"))
				axisInfoStr = StringByKey("userticks(x)",axisInfoStr,"=",";")
				
				If(!cmpstr(axisInfoStr,"0"))
					continue
				EndIf
				
				axisInfoStr = ReplaceString("{",axisInfoStr,"")
				axisInfoStr = ReplaceString("}",axisInfoStr,"")
				
				For(m=0;m<ItemsInList(axisInfoStr,",");m++)
					traceList += StringFromList(m,axisInfoStr,",") + ";"
					traceType += "AXIS;"
				EndFor
			EndFor
		
			
			//X waves aren't included in tracenamelist, so we have to loop through and 
			//find these ourselves.
			Variable nTraces = ItemsInList(traceList,";")
			For(k=0;k<nTraces;k++)
				String xwName = XWaveName(graphName,StringFromList(k,traceList,";"))
				If(strlen(xwName))
					//Adds the Y trace in the traceList again (not the x trace), but we log it
					//as an XTRACE. This lets us use xwavefromtrace() to retrieve the x wave ref later
					traceList += StringFromList(k,traceList,";") + ";"
					traceType += "XTRACE;"
				EndIf
			EndFor
			
			//Error bar waves are not included in tracenamelist, so we have to loop through
			//and find these ourselves using TraceInfo and StringByKey/strsearch
			pos = -1
			String key = "wave=("
			
			nTraces = ItemsInList(traceList,";")
			
			For(k=0;k<nTraces;k++)
			
				If(!cmpstr(StringFromList(k,traceType,";"),"XTRACE"))
					continue
				EndIf
				
				String errorInfo = TraceInfo(graphName,StringFromList(k,traceList,";"),0)
				errorInfo = StringByKey("ERRORBARS",errorInfo,":",";")
				
				If(!strlen(errorInfo))
					continue
				EndIf
				
				//Extracting the relevant string to identify the error waves
				pos = strsearch(errorInfo,key,0)
				If(pos != -1)
					errorInfo = errorInfo[pos + strlen(key),strlen(errorInfo)-1]
					errorInfo = RemoveEnding(errorInfo,")")
				Else
					continue
				EndIf
					
				//Plus error wave
				String errorWaveStr = StringFromList(0,errorInfo,",")
				traceList += errorWaveStr + ";"
				traceType += "TRACE_ERROR;"
				String tempErrorWaveStr = errorWaveStr
				
				//Minus error wave
				errorWaveStr = StringFromList(1,errorInfo,",")
			
				If(cmpstr(tempErrorWaveStr,errorWaveStr))
					//Different +/- error waves
					traceList += errorWaveStr + ";"
					traceType += "TRACE_ERROR;"
				EndIf
				
			EndFor
			
			//Add any images on the graph to the traceList
			String imageList = ImageNameList(graphName,";")
			traceList += imageList
			For(k=0;k<ItemsInList(imageList,";");k++)
				traceType += "IMAGE;"
			EndFor
			
			//Add any contours on the graph to the traceList
			String contourList = ContourNameList(graphName,";")
			traceList += contourList
			For(k=0;k<ItemsInList(contourList,";");k++)
				traceType += "CONTOUR;"
			EndFor
			
			nTraces = ItemsInList(traceList,";")
			
			//Create the Paths wave, which holds the full paths to the waves
			//that we identified in the layout page
			Make/T/N=(nTraces,1)/O root:$(graphName + "_Paths")/Wave=Paths
			SetDimLabel 1,0,IgorPath,Paths
			
			cleanupList += GetWavesDataFolder(Paths,2) + ";"
			
			//Create group for the Layout Code table
			HDF5CreateGroup/Z fileRef,"/LayoutCode",groupRef
			//Add data sets to the group that contains the data table wave
			HDF5SaveData/O/Z LayoutCode,groupRef
			HDF5CloseGroup/Z groupRef
		
			//Group for the raw data itself
			HDF5CreateGroup/Z fileRef,"/Data",groupRef
	
			//Add data sets to the group that contains the data table wave
			For(j=0;j<nTraces;j++)
				String type = StringFromList(j,traceType,";")
				strswitch(type)
					case "TRACE":
						Wave/Z w = TraceNameToWaveRef(graphName,StringFromList(j,traceList,";"))	
						break
					case "IMAGE":
						Wave/Z w = ImageNameToWaveRef(graphName,StringFromList(j,traceList,";"))
						break
					case "CONTOUR":
						Wave/Z w = ContourNameToWaveRef(graphName,StringFromList(j,traceList,";"))
						break
					case "TRACE_ERROR":
						errorWaveStr = StringFromList(j,traceList,";")
						Wave/Z w = $errorWaveStr
						//Find this in the graph macro code and replace with the full path to the error wave
						//This avoids some trickiness with relative paths for how error waves are referenced in the window macro
						For(k=0;k<DimSize(Code,0);k++)
							//including the comma ensures common base-named waves won't overwrite each other by mistake
							Code[k] = ReplaceString(errorWaveStr + ",",Code[k],GetWavesDataFolder($errorWaveStr,2) + ",") 
							Code[k] = ReplaceString(errorWaveStr + ")",Code[k],GetWavesDataFolder($errorWaveStr,2) + ")") 
						EndFor
						break
					case "XTRACE":
						Wave/Z w = XWaveRefFromTrace(graphName,StringFromList(j,traceList,";"))
						break
					case "VIOLIN":
						Wave/Z w = $(violinPath + StringFromList(j,traceList,";"))
						break
					case "AXIS":
						String axisWaveStr = StringFromList(j,traceList,";")
						Wave/Z w = $axisWaveStr
						For(k=0;k<DimSize(Code,0);k++)
							//including the comma ensures common base-named waves won't overwrite each other by mistake
							Code[k] = ReplaceString(axisWaveStr + ",",Code[k],GetWavesDataFolder($axisWaveStr,2) + ",")
							Code[k] = ReplaceString(NameOfWave($axisWaveStr) + ",",Code[k],GetWavesDataFolder($axisWaveStr,2) + ",")
							 
							Code[k] = ReplaceString(axisWaveStr + ")",Code[k],GetWavesDataFolder($axisWaveStr,2) + ")")
							Code[k] = ReplaceString(NameOfWave($axisWaveStr) + ")",Code[k],GetWavesDataFolder($axisWaveStr,2) + ")") 
						EndFor
						
						break
				endswitch
					
				If(WaveExists(w))
					//Add the full path the the 'Paths' wave
					Paths[j][%IgorPath] = GetWavesDataFolder(w,2)
					
					//Save the wave itself to the 'Data' group
					HDF5SaveData/O/Z w,groupRef	
				EndIf
				
				//Reset wave refs
				Wave/Z w = $""
			EndFor
			
			//Create group for the Code table
			HDF5CreateGroup/Z fileRef,"/Code",groupRef
			HDF5SaveData/O/Z Code,groupRef
			HDF5CloseGroup/Z groupRef
						
			//////////
			//Group for the data paths table
			HDF5CreateGroup/Z fileRef,"/Paths",groupRef
			HDF5SaveData/O/Z Paths,groupRef
			HDF5CloseGroup/Z groupRef
			
		EndFor

	EndFor
	
	//Cleanup
	For(i=0;i<ItemsInList(cleanupList,";");i++)
		KillWaves/Z $StringFromList(i,cleanupList,";")
	EndFor
	
	HDF5CloseFile/Z fileRef
	
	SetDataFolder saveDF
End

Static Function ImportLayout()
	Variable fileRef
	
	String pathStr = SpecialDirPath("Igor Pro User Files",0,0,0) + "User Procedures:NeuroTools+:Layouts"
	NewPath/Q/Z/O/C layoutPath,pathStr
	
	HDF5CloseFile/A 0
	HDF5OpenFile/R/Z/I/P=layoutPath fileRef as ""
	
	If(V_flag)
		return 0
	EndIf
	
	String filePath = S_filename
	
	//Check if there is a data table in the file
	HDF5ListGroup/TYPE=1/Z fileRef,"/"
	String groupList = S_HDF5ListGroup
	
	If(WhichListItem("LayoutCode",groupList,";") == -1)
		print "No layout code could be found."
		return 0
	EndIf
	
	//Hold all of the import data in root, will be cleaned up later
	DFREF saveDF = GetDataFolderDFR()
	SetDataFolder root:
	
	Variable groupID
	
	//Layout code
	HDF5OpenGroup/Z fileRef,"/LayoutCode",groupID
	HDF5ListGroup/Z fileRef,"/LayoutCode"
	String name = StringFromList(0,S_HDF5ListGroup,";")
	HDF5LoadData/TYPE=2/O/IGOR=-1/N=$name groupID,name
	HDF5CloseGroup/Z groupID
	Wave/T layoutCode = $StringFromList(0,S_waveNames,";")
	
	//Full paths to the waves in Igor
	HDF5LoadGroup/IGOR=-1/O :,fileRef,"/Paths"
	String paths = S_objectPaths
	
	//Full paths to the waves in Igor
	HDF5LoadGroup/IGOR=-1/O :,fileRef,"/Data"
	String waves = S_objectPaths
	
	//Full paths to the waves in Igor
	HDF5LoadGroup/IGOR=-1/O :,fileRef,"/Code"
	String code = S_objectPaths	
	
	Variable i,j
	Variable nObjects = ItemsInList(paths,";")
	
	
	String skipRows = ""
	
	//Distribute the waves into the correct folder paths
	For(i=0;i<nObjects;i++)
		Wave/T ObjectPathWave = $StringFromList(i,paths,";")
		
		For(j=0;j<DimSize(ObjectPathWave,0);j++)
			String theWavePath = ParseFilePath(1,ObjectPathWave[j],":",1,0)
			String theWaveName = ParseFilePath(0,ObjectPathWave[j],":",1,0)
			
			//Create the path if necessary 
			DFREF df = CreateFolder(theWavePath)
			
			//Move the wave into its proper place
			If(WaveExists(root:$theWaveName) && !WaveExists($ObjectPathWave[j]) && cmpstr("root:" + theWaveName,ObjectPathWave[j]))
				MoveWave root:$theWaveName, $ObjectPathWave[j]
			EndIf
			
		EndFor
		
		//Run the macro code for each object
		Wave/T objectCode = $StringFromList(i,code,";")
		
		//Important to set to root for finding correct wave paths in the Macro code
		SetDataFolder root:
		
		//omits the initial and final lines of code, which just declare and close the macro code
		For(j=1;j<DimSize(objectCode,0) - 1;j++) 
			//Remove some macro code we don't need or can't execute from a user function
			objectCode[j] = ReplaceString("PauseUpdate",objectCode[j],"")
			objectCode[j] = ReplaceString("Silent 1",objectCode[j],"")
			objectCode[j] = ReplaceString("EndMacro",objectCode[j],"")
			objectCode[j] = ReplaceString("\t",objectCode[j],"")
			objectCode[j] = ReplaceString("\r",objectCode[j],";")
			Execute/Q/Z objectCode[j]
		EndFor
		
		//Change the name of the window to the one the layout macro code expects
		String oldWindowName = RemoveEnding(ParseFilePath(1,NameOfWave(ObjectPathWave),"_",1,0),"_")
		String newWindowName = oldWindowName
		
		GetWindow/Z kwTopWin activeSW
		
		Variable NameIsOK = CheckName(oldWindowName,6)
		If(!NameIsOK)
			DoWindow/C/W=$S_Value $newWindowName
			DoWindow/T $newWindowName,newWindowName
		Else
			newWindowName = UniqueName(oldWindowName + "_",6,0)
			DoWindow/C/W=$S_Value $newWindowName
			DoWindow/T $newWindowName,newWindowName
			//Must change the layout macro code to reflect this change in the window name
			For(j=1;j<DimSize(layoutCode,0) - 1;j++) 
				If(stringmatch(layoutCode[j],"*" + oldWindowName + "*"))
				
					//skipRows will log which rows have been edited, so we don't go back and re-edit them
					//for window names that share the same base name. 
					If(WhichListItem(num2str(j),skipRows,";") == -1)
						layoutCode[j] = ReplaceString(oldWindowName,layoutCode[j],newWindowName)
						skipRows += num2str(j) + ";"
					EndIf
				EndIf
				
			EndFor
			
		EndIf	
		
		//Cleanup
		KillWaves/Z objectCode,objectPathWave
		KillStrings/Z root:fldrSav0 //from the macro probably
	EndFor
	
	//Execute the layout macro code
	For(j=1;j<DimSize(layoutCode,0) - 1;j++) 
		//Remove some macro code we don't need or can't execute from a user function
		layoutCode[j] = ReplaceString("PauseUpdate",layoutCode[j],"")
		layoutCode[j] = ReplaceString("Silent 1",layoutCode[j],"")
		layoutCode[j] = ReplaceString("EndMacro",layoutCode[j],"")
		layoutCode[j] = ReplaceString("\t",layoutCode[j],"")
		layoutCode[j] = ReplaceString("\r",layoutCode[j],";")
		Execute/Z/Q layoutCode[j]
	EndFor

	HDF5CloseFile/A fileRef
	
	DoUpdate 
	
	//Optional deletion of the layout file. This is just duplicated data, so its probably best to
	//delete it unless you're trying to pull this layout into multiple Igor files or just want another
	//copy on disk for later.
	DoAlert/T="Transfer Layout" 1,"Layout transferred. Do you want to delete the intermediate layout file?"
	switch(V_flag)
		case 1:
			//yes
			DeleteFile/Z/P=layoutPath filePath
			break
		case 2:
			//no
			break
	endswitch
	
	//Clean up
	KillWaves/Z layoutCode, objectCode
	
	SetDataFolder saveDF
End

//Creates a new data folder along the specified location
//Creates the entire path if need be
Static Function/DF CreateFolder(path)
	String path
	 
	If(!strlen(path))
		return $""
	EndIf
	
	Variable i,numel = ItemsInList(path,":")
	For(i=1;i<numel;i+=1)
		String folder = ParseFilePath(1,path,":",0,i)
		
		If(!DataFolderExists(folder))
			folder = RemoveEnding(folder,":")
			NewDataFolder $folder
		EndIf
	EndFor
	
	//last element
	If(!DataFolderExists(path))
		path = RemoveEnding(path,":")
		NewDataFolder $path
	EndIf
	
	DFREF dfr = $path
	
	return dfr
End