#pragma rtGlobals=3
#pragma version=3.02
#pragma IgorVersion=7
#pragma moduleName=baselines

// by tony.withers@uwo.ca

// please tell me when you find bugs!

// How to use:
// Must have a spectrum plotted in the top graph window. When you select 
// Baselines from the macros menu a baseline control panel is attached to
// the graph. Select spectrum and baseline type from popup menus in the 
// control panel. Use the graph marquee tool (click and drag) to select a
// region of the spectrum, then either click within the marquee and 
// select "add region to fit", or click the + button in the control panel
// to add a fitting region. Subtract will make copies of the current 
// baseline and baseline-subtracted waves in the current data folder. The
// output waves have a _Sub or _BL suffix. Close the panel to clean up 
// after fitting.

// The tangent baseline will attempt to find a common tangent to two 
// cubic functions. You must have two regions selected for fitting. The 
// fit will be successful only if the selected regions can each be fit 
// nicely with a cubic function, and if the two cubics have a common 
// tangent. 

// The line between cursors baseline allows you to position the cursors 
// labelled I and J manually.

// The gauss3 baseline fits a Gauss1D function with the first coefficient
// set to 0.

// Version history
// 3.02 bug fix: spline fit was damaged by 'cosmetic' changes in version 3.01.
// 3.01  cosmetic changes
// 3.00  Sep 11 2017. Switch to panel interface. Closing panel should 
// clear baseline waves from graph. Baseline updates as user interacts 
// with controls on panel or changes mask wave. This was a major rewrite,
// so let me know when you find the bugs.
// 2.20  code cleanup to use waverefs instead of global string variables
// 2.10  Aug 22 2017 cleaned up the 'tangent' baseline for a beta release
// 2.00  1/2/15 made it work for X-Y data; added wave notes to output waves
// 1.50  finally fixed offsets
// 1.22  fixed offset calculation
// 1.21  12/10/09 
// 1.20  6/24/08 added line between cursors
// 1.12  6/9/08 
// 1.11  9/12/07
// 1.10  7/23/07 added smoothed spline baseline
// 1.00  7/3/07 

Menu "Analysis"
	Submenu "Packages"
		"Baselines",/Q, BL_init()
	end
end

Menu "Macros"
	"Baselines", /Q, BL_init()
end

Menu "GraphMarquee", dynamic
	BL_MarqueeMenu("-")
	BL_MarqueeMenu("Add Region to Fit"), /Q, BL_setMarquee(1)
	BL_MarqueeMenu("Remove Region From Fit"), /Q, BL_setMarquee(0)
	BL_MarqueeMenu("Clear All Fit Regions"), /Q, BL_SetRegion(-inf, inf, 0)
End

function BL_setMarquee(add)
	variable add
	
	GetWindow /Z BL_panel  activeSW 
	string s_graph = parseFilepath(0, s_value, "#", 0, 0)
	controlinfo /W=BL_panel popTrace
	string xAxisName= StringByKey("XAXIS", traceinfo(s_graph,s_value,0))
	getmarquee /W=$s_graph /Z $xAxisName	
	if (V_flag)
		BL_SetRegion(V_left, V_right, add)
		return 1
	endif
	return 0
end

static Function/DF GetDFREF()
	DFREF dfr = root:Packages:Baselines
	if (DataFolderRefStatus(dfr) != 1)	
		DFREF dfr = CreatePackageFolder()
	endif
	return dfr
End

static function /DF CreatePackageFolder()
	NewDataFolder /O root:Packages
	NewDataFolder /O root:Packages:Baselines
	DFREF dfr = root:Packages:Baselines
	
	return dfr
end
 
Function/S BL_MarqueeMenu(str)	
	string str
	
	GetWindow /Z BL_panel  activeSW 
	if (v_flag)
		return ""
	endif
	
	string s_graph=parseFilepath(0, s_value, "#", 0, 0)
	if (stringmatch(WinName(0,1),s_graph)==0)
		return ""
	endif
		
	DFREF dfr=GetDFREF()
	wave /SDFR=dfr w_display, w_mask
	
	if (waveexists(w_display)==0)
		return ""
	endif
	
	checkdisplayed /W=$s_graph w_display
	if(V_flag==0) // not initialized
		return ""
	endif
	
	strswitch(str)
		case "Remove Region From Fit":
			if(wavemax(w_mask)==0)
				return ""
			endif
		case "Clear All Fit Regions":
			if(wavemax(w_mask)==0)
				return ""
			endif
	endswitch
 	return str
end

function BL_init()
	if(BL_MakePanel())
		BL_ResetPackage() // create fit waves and add to plot
		BL_doFit()
	endif
end

function BL_MakePanel()
	if (strlen(WinList("*",";","WIN:1"))==0)  // no graphs 
		doalert 0, "Baseline requires a trace plotted in a graph window."
		return 0
	endif

	// make sure the top graph is visible
	string s_graph=WinName(0,1)
	dowindow /F $s_graph
		
	// clear any package detritus from the last used baseline graph
	BL_clear()
	
	DFREF dfr=GetDFREF()
	
	// make sure there's space to the left of the graph for the panel
	getwindow /Z $s_graph wsize
	if (V_left<200)
		movewindow /W=$s_graph 200, V_top, -1, -1
	endif
	
	// make panel
	NewPanel /K=1/N=BL_panel/W=(200,0,0,320)/HOST=$s_graph/EXT=1 as "Baseline Controls"	
	ModifyPanel /W=$s_graph#BL_panel, noEdit=1	
	
	variable i=0, deltaY=30, v_L=30, v_T=10
	
	GroupBox group0,pos={v_L-20,v_T+deltaY*i},size={180.00,60.00},title="Data wave"
	GroupBox group0,fSize=14
	i++	
	// store values internally in these controls
	PopupMenu popTrace, mode=1, Value=BL_traces(), title="",pos={v_L,v_T+deltaY*i},size={130,20}
	PopupMenu popTrace, help={"select data wave" }, proc=BL_popup
	i+=1.5	
	GroupBox group1,pos={v_L-20,v_T+deltaY*i},size={180.00,60.00},title="Baseline type"
	GroupBox group1,fSize=14
	i++
	string fNames="\"line;poly 3;poly 4;gauss;gauss3;lor;exp;dblexp;sin;hillequation;sigmoid;power;lognormal;"
	fNames+="spline;line between cursors;tangent\""
	PopupMenu popBL, mode=1, title="",pos={v_L,v_T+deltaY*i},size={130,20}, Value=#fNames
	PopupMenu popBL, help={"select baseline type" }, proc=BL_popup
	
	SetVariable setvarSmooth,pos={v_L+30,v_T+deltaY*i},size={100,16},title=""
	SetVariable setvarSmooth,limits={1e-5,100,0.01},value=_NUM:0.1, bodyWidth=60
	SetVariable setvarSmooth,help={"spline smoothing factor"}, fsize=14, proc=BL_SetVar
	SetVariable setvarSmooth,disable=1
	i+=1.5
	GroupBox group2,pos={v_L-20,v_T+deltaY*i},size={180.00,70.00},title="Fit regions"
	GroupBox group2,fSize=14
	i+=1
	Button BL_reset,pos={v_L-5,v_T+deltaY*i+5},size={60,20},title="Clear all", proc=BL_button
	Button BL_reset,help={"Clear all fit regions"}	
	Button BL_add,pos={v_L+70,v_T+deltaY*i},size={30,30},title="+", proc=BL_button
	Button BL_add,help={"Remove marquee to fit region"}
	Button BL_remove,pos={v_L+115,v_T+deltaY*i},size={30,30},title="-", proc=BL_button
	Button BL_remove,help={"Remove marquee from fit region"}	
	i+=2
	Button BL_sub,pos={60,v_T+deltaY*i},size={70,20},title="Subtract", proc=BL_button
	Button BL_sub,help={"Subtract baseline"}
	i++
	Button BL_all,pos={60,v_T+deltaY*i},size={70,20},title="All in one", proc=BL_button
	Button BL_all,help={"Subtract baseline from all traces"}
	
	return 1
end

// create fit waves and add to plot
static function BL_ResetPackage()
	
	GetWindow /Z BL_panel  activeSW 
	string s_graph = parseFilepath(0, s_value, "#", 0, 0)
	removefromgraph /W=$s_graph /Z w_display, w_base, w_sub, tangent0, tangent1
	
	controlinfo /W=BL_panel popTrace
	string s_trace=s_value
	wave w=TraceNameToWaveRef(s_graph, s_trace)
	if (waveexists(w)==0)
		return 0
	endif
	wave w_x=XWaveRefFromTrace(s_graph, s_trace)
	
	DFREF dfr=GetDFREF()
	
	duplicate /O w dfr:w_Display /WAVE=w_display
	
	// don't reset the mask wave if new data wave has same length as previous one
	// in case we want to apply the same fit to many spectra
	wave w_mask=dfr:w_mask
	if (waveexists(w_mask))		
		if (numpnts(w_mask)!=numpnts(w_display))
			duplicate /O w dfr:w_mask
			w_mask=0
			w_display=nan
		endif
	else
		duplicate /O w dfr:w_mask
		wave w_mask=dfr:w_mask
		w_mask=0
	endif
	
	w_display = w_mask[p] ? inf : NaN
	
	if (waveexists(w_x))
		appendtograph /W=$s_graph w_display vs w_x
	else
		appendtograph /W=$s_graph w_display
	endif
	ModifyGraph /W=$s_graph mode(w_display)=7,hbFill(w_display)=4
	ModifyGraph /W=$s_graph rgb(w_display)=(49151,53155,65535,32768)
	
	string s_firsttrace=stringfromlist(0, tracenamelist(s_graph,";",5))
	ReorderTraces /W=$s_graph $s_firsttrace, {w_display}

	// preserve offsets in (vertical only)
	variable DataOffsetY=BL_getYoffset(s_graph, s_trace)
	ModifyGraph  /W=$s_graph offset(w_display)={0,-1e9}
		
	duplicate /O w  dfr:w_base /WAVE=w_base
	w_base=nan
	
	if (waveexists(w_x))
		appendtograph /W=$s_graph w_base vs w_x
	else
		appendtograph /W=$s_graph w_base
	endif
	
	// figure a contrasting colour for baseline and sub waves
	make /free w_c={0,10000,65535}
	BL_chooseColour(w_c, s_graph, s_trace)	
	ModifyGraph /W=$s_graph rgb(w_base)=(w_c[0],w_c[1],w_c[2])
	ModifyGraph  /W=$s_graph offset(w_base)={0,DataOffsetY}
	
	duplicate /O w  dfr:w_sub /WAVE=w_sub
	w_sub=nan
	
	if (waveexists(w_x))
		appendtograph /W=$s_graph w_sub vs w_x
	else
		appendtograph /W=$s_graph w_sub
	endif
	ModifyGraph /W=$s_graph rgb(w_sub)=(w_c[0],w_c[1],w_c[2])
	
	string yAxisName= StringByKey("YAXIS", traceinfo(s_graph,s_trace,0))
	getaxis /W=$s_graph /Q $yAxisName
	setaxis /W=$s_graph /Z $yAxisName, v_min, v_max
end

// ------------ control action procedures --------------------

Function BL_popup(s)
	STRUCT WMPopupAction &s
	
	if (s.eventCode==-1)
		return 0
	endif
	
	string s_graph=parseFilepath(0, s.win, "#", 0, 0)
	controlinfo /W=BL_panel popTrace
	string s_trace=s_value
			
	if(stringmatch(s.ctrlName,"popTrace"))	
		BL_ResetPackage()	
		controlinfo /W=BL_panel popBL
		// force an update of baseline
		controlinfo /W=BL_panel popBL
		s.ctrlName="popBL"
		s.popStr=s_value		
	endif
	
	if(stringmatch(s.ctrlName,"popBL"))	
		if(stringmatch(s.popStr,"spline"))
			SetVariable setvarSmooth, Win=$s.win, disable=0
		else
			SetVariable setvarSmooth, Win=$s.win, disable=1
		endif	
		
		if(stringmatch(s.popStr,"line between cursors"))
			
			wave w=TraceNameToWaveRef(s_graph, s_trace)
			if (waveexists(w)==0)
				return 0
			endif
			wave w_x=XWaveRefFromTrace(s_graph, s_trace)
			
			// put cursors on graph
			variable Xval, Yval
			string xAxisName= StringByKey("XAXIS", traceinfo(s_graph,s_trace,0))
			string yAxisName= StringByKey("YAXIS", traceinfo(s_graph,s_trace,0))
			
			getaxis /W=$s_graph /Q $yAxisName
			setaxis $yAxisName, v_min, v_max
			Yval=V_min+(V_max-V_min)/2
			getaxis /W=$s_graph /Q $xAxisName
			Xval=V_min+(V_max-V_min)*.1
			if (waveexists(w_x)==0)
				Yval=WaveMin(w, V_min, Xval)+BL_getYoffset(s_graph, s_trace)
			endif
			cursor /F /W=$s_graph /N=1 I $s_trace Xval, Yval 
			Xval=V_min+(V_max-V_min)*.9
			if (waveexists(w_x)==0)
				Yval=WaveMin(w, Xval, V_max)+BL_getYoffset(s_graph, s_trace)
			endif
			
			// set the hook before placing second cursor on graph
			SetWindow $s_graph hook(BL_CsrHook)=BL_CsrLineHook
			cursor /F /W=$s_graph /N=1 J $s_trace Xval, Yval 	
		else
			Cursor /K /W=$s_graph I
			Cursor /K /W=$s_graph J
			SetWindow $s_graph  hook(BL_CsrHook)=$"" 
		endif
		
		if(stringmatch(s.popStr,"tangent"))
			DFREF dfr=GetDFREF()
			make /o/n=0 dfr:tangent0 /WAVE=tangent0, dfr:tangent1 /WAVE=tangent1
			checkdisplayed /W=$s_graph tangent0, tangent1
			if (!(v_flag&1))
				appendtograph /W=$s_graph tangent0
			endif
			if(!(v_flag&2))
				appendtograph /W=$s_graph tangent1
			endif
					
			// preserve Y offsets
			// X offsets will lead only to trouble
			variable DataOffsetY=BL_getYoffset(s_graph, s_trace)
			ModifyGraph  /W=$s_graph offset(tangent0)={0,DataOffsetY}
			ModifyGraph  /W=$s_graph offset(tangent1)={0,DataOffsetY}			
			
		else
			removefromgraph /Z /W=$s_graph tangent0, tangent1
		endif
	endif
	
	BL_DoFit()
end

function BL_getYoffset(s_graph, s_trace)
	string s_graph, s_trace
	
	variable OffsetX=0,OffsetY=0
	string infostr=TraceInfo(s_graph, s_trace, 0 )
	infostr = GrepList(infostr, "offset", 0,";")
	infostr=StringFromList(0, infostr,";")
	sscanf infostr, "offset(x)={%g,%g}", OffsetX,OffsetY
	return OffsetY	
end

Function BL_SetVar(s) : SetVariableControl
	STRUCT WMSetVariableAction &s
	
	if (s.eventCode==-1)
		string s_graph=parseFilepath(0, s.win, "#", 0, 0)
		BL_RemoveWaves(s_graph)
		return 0
	endif
	
	if(stringmatch(s.ctrlName,"setvarSmooth"))	
		// reset increment value to 10% of current value
		SetVariable  setvarSmooth win=$s.win,limits={1e-5,inf,abs(s.dval/10)}	
	endif	
	BL_doFit()
	
	return 0
End

Function BL_button(s)
	STRUCT WMButtonAction &s
		
	if(s.eventCode!=2)
		return 0
	endif
	
	string s_graph=parseFilepath(0, s.win, "#", 0, 0)
			
	strswitch(s.ctrlName)
		case "BL_sub":	
			BL_subtract(0)
			break
		case "BL_all":
			string msg="subtract baseline from all traces using current settings?\r"
			msg+="existing baselines will be overwritten!"
			doalert 1, msg
			if(v_flag==2)
				return 0
			endif
			controlinfo /W=BL_panel popTrace
			variable savMode=v_value
			string s_list=BL_traces()
			variable i
			for(i=0;i<itemsinlist(s_list); i+=1)
				PopupMenu popTrace, win=$s.win, mode=i+1
				if (BL_doFit())
					BL_subtract(1)
				else
					print "Baselines all in one failed to fit "+stringfromlist(i, s_list)
				endif
			endfor	
			PopupMenu popTrace, win=$s.win, mode=savMode 
			// return to spectrum for which we initialized
			BL_doFit()
			break
		case "BL_reset":
			BL_SetRegion(-inf, inf, 0)	
			break
		default: // add or remove fit region
			variable add = stringmatch(	s.ctrlName, "BL_add") ? 1 : 0
			if(BL_setMarquee(add)==0)
				DoAlert 0, "first use marquee to select region on graph"
			endif	
	endswitch

	return 0
End

// --------------------------------------------------------

function /s BL_traces()
	
	GetWindow /Z BL_panel  activeSW 
	string s_graph=parseFilepath(0, s_value, "#", 0, 0)
	string s_list=TraceNameList(s_graph,";",1+4)
	variable i=0
	do
		if(stringmatch(stringfromlist(i,s_list), "w_base"))
			s_list=RemoveListItem(i, s_list)
		elseif(stringmatch(stringfromlist(i,s_list), "w_sub"))
			s_list=RemoveListItem(i, s_list)	
		elseif(stringmatch(stringfromlist(i,s_list), "w_display"))
			s_list=RemoveListItem(i, s_list)	
		elseif(stringmatch(stringfromlist(i,s_list), "tangent0"))
			s_list=RemoveListItem(i, s_list)	
		elseif(stringmatch(stringfromlist(i,s_list), "tangent1"))
			s_list=RemoveListItem(i, s_list)	
		elseif(stringmatch(stringfromlist(i,s_list), "*_sub"))
			s_list=RemoveListItem(i, s_list)	
		elseif(stringmatch(stringfromlist(i,s_list), "*_BL"))
			s_list=RemoveListItem(i, s_list)	
		else
			i+=1
		endif
	while (i<itemsinlist(s_list))
	
	return s_list
end

// set region between x1 and x2 to value
// value = 1 to include, 0 to exclude.
function BL_SetRegion(x1, x2, value)
	variable x1, x2, value
	
	DFREF dfr=GetDFREF()
	wave /SDFR=dfr w_mask, w_display

	if (waveexists(w_mask)==0)
		return 0
	endif
	
	GetWindow /Z BL_panel  activeSW 
	string s_graph=parseFilepath(0, s_value, "#", 0, 0)
	controlinfo /W=BL_panel popTrace
	if (V_flag==0)
		return 0
	endif
	wave w_data=TraceNameToWaveRef(s_graph, s_value)
	wave w_x=XWaveRefFromTrace(s_graph, s_value)
	
	variable p_low, p_high, p_left, p_right
	
	if (waveexists(w_x))		
		variable xmax=wavemax(w_x)
		variable xmin=wavemin(w_x)
		x1=min(x1,xmax)
		x1=max(x1,xmin)
		x2=min(x2,xmax)
		x2=max(x2,xmin)
		
		findlevel /Q/P w_x, x1
		if (v_flag) 
			print "baseline error: problem with findlevel"
			return 0
		endif
		p_left=V_LevelX	
		findlevel /Q/P w_x, x2
		if (v_flag) 
			print "baseline error: problem with findlevel"
			return 0
		endif
		p_right=V_LevelX
		
		p_low=min(p_left, p_right)
		p_high=max(p_left, p_right)
	else	
		p_low=min(x2pnt(w_data,x1), x2pnt(w_data,x2))
		p_high=max(x2pnt(w_data,x1), x2pnt(w_data,x2))
		p_low=max(0,p_low)
		p_high=min(numpnts(w_data)-1,p_high)
	endif
	w_mask[p_low, p_high]=value
	w_display = w_mask[p] ? inf : NaN
	
	BL_doFit()
end

// clear baseline paraphernalia from graph
function BL_clear()	
	
	GetWindow /Z BL_panel  activeSW 
	string s_graph=parseFilepath(0, s_value, "#", 0, 0)
	
	KillWindow /Z BL_panel
	if (strlen(winlist(s_graph,";","")))
		removefromgraph /W=$s_graph /Z w_display, w_base, w_sub, tangent0, tangent1
		// remove hook in case we were fitting to cursors
		SetWindow $s_graph  hook(BL_CsrHook)=$"" 
		Cursor /K /W=$s_graph I
		Cursor /K /W=$s_graph J	
	endif	
end

static function BL_RemoveWaves(s_graph)
	string s_graph
	
	if (strlen(s_graph)==0)
		return 0
	endif	
	
	DFREF dfr=GetDFREF()
	wave /SDFR=dfr w_display, w_base, w_sub, tangent0, tangent1
	
	do // remove all instances of w_display
		removefromgraph /W=$s_graph/Z w_display
		checkdisplayed /W=$s_graph w_display
	while (V_flag)
	do // remove all instances of w_base
		removefromgraph /W=$s_graph/Z w_base
		checkdisplayed /W=$s_graph w_base
	while (V_flag)
	do // remove all instances of w_sub
		removefromgraph /W=$s_graph/Z w_sub
		checkdisplayed /W=$s_graph w_sub
	while (V_flag)
	do // remove all instances of tangent waves
		removefromgraph /W=$s_graph /Z tangent0, tangent1
		checkdisplayed /W=$s_graph tangent0, tangent1
	while (V_flag)
	// remove hook in case we were fitting to cursors
	SetWindow $s_graph  hook(BL_CsrHook)=$"" 
	Cursor /K /W=$s_graph I
	Cursor /K /W=$s_graph J	 
	
	return 1
end

// subtract current baseline from w_data
function BL_Subtract(overwrite)
	variable overwrite
	
	DFREF dfr=GetDFREF()
	
	GetWindow /Z BL_panel  activeSW 
	string s_graph=parseFilepath(0, s_value, "#", 0, 0)
	
	controlinfo /W=BL_panel popTrace
	string s_trace=s_value
	wave w_data=TraceNameToWaveRef(s_graph, s_trace)
	if (waveexists(w_data)==0)
		return 0
	endif
	wave w_x=XWaveRefFromTrace(s_graph, s_trace)
	
	wave w_base=dfr:w_base
	if(numpnts(w_base)!=numpnts(w_data))
		if (overwrite)
			print nameofwave(w_data) +" and baseline have different length"
		else
			doalert 0, nameofwave(w_data) +" and baseline have different length"
		endif
		return 0
	endif
	
	wavestats /Q/M=1 w_base
	if (V_npnts==0)
		return 0
	endif
	
	// save a copy of the baseline
	string strNewName=CleanupName( nameofwave(w_data)+"_BL",0)
	if (overwrite==0 && exists(strNewName))
		doalert 1, strNewName+" exists. Overwrite?"
		if(V_flag==2)
			return 0
		endif
	endif
	duplicate /o w_base $strNewName
	wave newbase= $strNewName
	newbase=w_base
	
	// subtract baseline
	strNewName=CleanupName(nameofwave(w_data)+"_sub",0)
	if (overwrite==0 && exists(strNewName))
		doalert 1, strNewName+" exists. Overwrite?"
		if(V_flag==2)
			return 0
		endif
	endif
	duplicate /o w_data $strNewName
	wave subtracted= $strNewName
	subtracted=w_data-w_base
	
	// note subtracted, note(w_base) 
	// append note from baseline wave to output wave note
	string s_note=note(w_base)
	s_note+="data="+nameofwave(w_data)+";output="+nameofwave(subtracted)+","+nameofwave(newbase)+";"
	if (waveexists(w_x))
		s_note+="xwave="+nameofwave(w_x)+";"
	endif
	s_note+="\r"
	note subtracted, s_note
	printf s_note[strsearch(s_note, "Baseline Parameters",0), strlen(s_note)-1]
	
	checkdisplayed /W=$s_graph subtracted
	if (V_flag)
		return 1
	else
		if (waveexists(w_x))
			appendtograph /W=$s_graph subtracted vs w_x
		else
			appendtograph /W=$s_graph subtracted
		endif
		ModifyGraph /W=$s_graph rgb($nameofwave(subtracted))=(0,0,0)		
	endif
end


function BL_DoFit()
	
	controlinfo /W=BL_panel popBL
	if (V_Flag==0)
		return 0
	endif
	string type=s_value
	
	DFREF dfr=GetDFREF()
	wave /SDFR=dfr w_base,w_display,w_mask,w_sub
	
	GetWindow /Z BL_panel  activeSW 
	string s_graph=parseFilepath(0, s_value, "#", 0, 0)
	controlinfo /W=BL_panel popTrace
	wave w_data=TraceNameToWaveRef(s_graph, s_value)
	wave w_x=XWaveRefFromTrace(s_graph, s_value)
	
	if (waveexists(w_data)==0 && waveexists(w_base))
		w_base=nan; w_sub=nan
		return 0
	endif
	
	if (numpnts(w_data)!=numpnts(w_mask))
		return 0
	endif
	
	if(stringmatch(type, "line between cursors"))	
		return 1 // fit will be updated when cursors move
	endif
	
	if (wavemin(w_mask)==0 && wavemax(w_mask)==0) // no region to fit
		w_base=nan
		w_sub=nan
		return 0
	endif
	
	string s_log="Baseline Parameters\r"
	s_log+="type="+type+";"
	string s_range=""
	
	// treat spline and tangent as special cases, 
	// otherwise use CurveFit to fit selected function
	if (stringmatch(type, "spline"))
		
		w_display = w_mask[p] ? w_data : NaN
		
		controlinfo /W=BL_panel setVarSmooth
		variable v_smooth=V_Value
		
		if (waveexists(w_x))
			duplicate /o w_x dfr:w_splineX /WAVE=w_splineX
			interpolate2/T=3/I=3/F=(V_smooth)/X=w_splineX/Y=w_base w_x, w_display 
		else
			interpolate2/T=3/I=3/F=(V_smooth)/Y=dfr:w_base dfr:w_display 
		endif
		w_display = w_mask[p] ? inf : NaN
		sprintf s_log, "%ssmoothing=%g;", s_log,v_smooth
		
	elseif(stringmatch(type, "tangent"))
		// make sure we have two regions to fit
		findlevels /Q/EDGE=1/P w_mask, 1
		if(V_LevelsFound+(w_mask[0]==1)!=2)
			//doalert 0, "Select two fit regions for tangent fitting"
			w_base=nan
			w_sub=nan
			return 0
		endif
		
		// find the points at edges of fit regions
		make /free/n=4 w_limits, w_xrange
		
		variable pnt=0,j=0
		do
			if(pnt==0&&w_mask[pnt]==1)
				w_limits[j]=pnt
				j+=1		
			elseif(pnt==numpnts(w_mask)-1 && w_mask[pnt]==1)
				w_limits[j]=pnt
				j+=1			
			elseif(pnt>0 && w_mask[pnt]!=w_mask[pnt-1])
				w_limits[j]=pnt-w_mask[pnt-1]
				j+=1
			endif
			pnt+=1
		while(j<4 && pnt<numpnts(w_mask))
		if (j<3)
			w_base=nan
			w_sub=nan
			return 0
		endif

		sort w_limits, w_limits
		w_xrange = (waveexists(w_x)) ? w_x[w_limits] : pnt2x(w_data,w_limits)
		
		make /D /free/n=9 w_9coef=0
		make /o /n=200 dfr:tangent0 /WAVE=tangent0
		make /o /n=200 dfr:tangent1 /WAVE=tangent1
		setscale /i x, w_xrange[0], w_xrange[1], tangent0
		setscale /i x, w_xrange[2], w_xrange[3], tangent1
		
		variable V_FitError=0
		CurveFit /Q  poly 4,  w_data[w_limits[0],w_limits[1]] /X=w_x /NWOK
		
		wave w_coef=w_coef
		tangent0=poly(w_coef,x)
		w_9coef[0,3]=w_coef
		
		V_FitError=0
		CurveFit /Q  poly 4,  w_data[w_limits[2],w_limits[3]] /X=w_x /NWOK
		
		w_9coef[4,7]=w_coef[p-4]	
		tangent1=poly(w_coef,x)		
		
		sort w_xrange, w_xrange
		sprintf s_range, "%g-%g, %g-%g", w_xrange[0],w_xrange[1],w_xrange[2],w_xrange[3]
		
		// switch limits to x values
		w_limits = waveexists(w_x) ? w_x[w_limits] : pnt2x(w_mask, w_limits)
		
		// pass the mid position of second poly to function
		// to help choose the correct root
		w_9coef[8]=(w_limits[2]+w_limits[3])/2
		
		make /free/n=300 w_temp
		setscale /i x, w_limits[0], w_limits[1], w_temp
		w_temp=abs(BL_TangentDistance(w_9coef, x))	
		wavestats /Q w_temp
				
		variable delta=abs(w_limits[1]-w_limits[0])/150
		findroots /H=(v_minloc+delta) /L=(v_minloc-delta) /Q BL_TangentDistance, w_9coef
		if (V_flag)
			w_base=nan; w_sub=nan
			return 0
		endif
				
		variable grad=w_9coef[1]+2*w_9coef[2]*V_Root+3*w_9coef[3]*V_Root^2
		variable intercept=w_9coef[0]+w_9coef[1]*V_Root+w_9coef[2]*V_Root^2+w_9coef[3]*V_Root^3-grad*V_Root
		
		variable x1,y1,x2,y2
		x1=v_root
		y1=intercept+grad*x1
			
		// figure out second tangent point	
		variable a,b,c, root1, root2
		a=3*w_9coef[7]
		b=2*w_9coef[6]
		c=w_9coef[5]-grad
		
		root1=(-b+sqrt(b^2-4*a*c))/(2*a)
		root2=(-b-sqrt(b^2-4*a*c))/(2*a)
	
		// choose root closest to midpoint of x range
		x2 = (abs(root1-w_9coef[8])<abs(root2-w_9coef[8])) ? root1 : root2
		duplicate /o/free /r=[4,7], w_9coef, w_coef
		y2 = intercept+grad*x2
					
		w_base = waveexists(w_x) ? intercept + grad*w_x[p] : intercept + grad*x
		
		sprintf s_log, "%sintercept=%g;gradient=%g;contact points=(%g,%g), (%g,%g);", s_log, intercept, grad, x1, y1, x2, y2

	else // not one of the 'special case' baselines	
		variable success=BL_FitWrap(w_data, w_x, w_mask, w_base, type)
	endif
	
	// figure out ranges used for fitting from mask wave
	variable i, v_num
	wave w_mask=dfr:w_mask
	variable v_used=0
	for(i=0;i<numpnts(w_mask); i+=1)
		if(w_mask[i]!=v_used)
			v_used=1-v_used
			if(v_used) // started to include
				v_num = (waveexists(w_x)) ? w_x[i] : pnt2x(w_mask, i)		
				sprintf s_range, "%s%g", s_range, v_num
			else // stopped including
				v_num = (waveexists(w_x)) ? w_x[i] : pnt2x(w_mask, i-1)
				sprintf s_range, "%s-%g, ", s_range, v_num
			endif
		elseif( (i==numpnts(w_mask)-1) && v_used)
			v_num = (waveexists(w_x)) ? w_x[i] : pnt2x(w_mask, i)
			sprintf s_range, "%s-%g", s_range, v_num
		endif
	endfor
	s_range=removeending(s_range, ", ")
	s_log+="range="+s_range+";"
	
	w_sub=w_data-w_base	
	
	// update note in w_base so that it's copied to output wave by SubtractBaseline()
	string s_note=note(w_data)
	s_note=removeending(s_note, "\r")
	if (strlen(s_note))
		s_note+="\r"
	endif
	s_note+=s_log
	note /K w_base s_note	
	// the format of the note follows style of Bruker FTIR file header 
	// not easily interrogated with StringByKey, unfortunately
	
	return 1
end

// for finding tangent to two 4th order polynomials
function BL_TangentDistance(w, x)
	wave w
	variable x
	
	// first poly 4 is y=w[0]+w[1]*x+w[2]*x^2+w[3]*x^3
	// second poly 4 is y=w[4]+w[5]*x+w[6]*x^2+w[7]*x^3
	// w[8] is midpoint of x range for second poly
	
	// find gradiant of tangent at position x on first poly
	variable grad=w[1]+2*w[2]*x+3*w[3]*x^2
	variable intercept=w[0]+w[1]*x+w[2]*x^2+w[3]*x^3-grad*x
	
	// find distance from tangent to second poly
	// start by finding tangent to second poly with gradient == grad
		
	variable a, b, c, root1, root2
	
	// gradient of second poly is w[5]+2*w[6]*x+3*w[7]*x^2
	// so 3*w[7]*x^2 + 2*w[6]*x + w[5]-grad = 0
	
	a=3*w[7]
	b=2*w[6]
	c=w[5]-grad
	
	root1=(-b+sqrt(b^2-4*a*c))/(2*a)
	root2=(-b-sqrt(b^2-4*a*c))/(2*a)
	
	variable x0, y0
	
	// choose root closest to midpoint of x range
	x0 = (abs(root1-w[8])<abs(root2-w[8])) ? root1 : root2
	y0 = w[4]+w[5]*x0+w[6]*x0^2+w[7]*x0^3
	
	// distance to tangent
	return (intercept + grad*x0 - y0)/sqrt(1+grad^2)
	
end

// ------------------- hook functions ---------------

function BL_CsrLineHook(s)
	STRUCT WMWinHookStruct &s
	
	if (s.eventcode!=7)
		return 0
	endif
	
	controlinfo /W=BL_panel popTrace
	if (v_flag==0)
		return 0
	endif	
	string s_trace=s_value
	
	wave w_data=TraceNameToWaveRef(s.winName, s_value)
	wave w_x=XWaveRefFromTrace(s.winName, s_value)
	if (waveexists(w_data)==0)
		return 0
	endif
	
	DFREF dfr=GetDFREF()
	wave /SDFR=dfr w_base,w_sub
	variable x1=hcsr(I), x2=hcsr(J), y1=vcsr(I), y2=vcsr(J)
		
	w_base =	(waveexists(w_x)) ? y1+(w_x[p]-x1)*(y2-y1)/(x2-x1) : y1+(x-x1)*(y2-y1)/(x2-x1)
	
	// figure out vertical offset
	variable DataOffsetY=BL_getYoffset(s.winName, s_trace)
	w_base-=DataOffsetY
	
	w_sub=w_data-w_base
	
	string s_log="Baseline Parameters\r"
	sprintf s_log "%stype=line between cursors;coordinates=(%g,%g),(%g,%g);", s_log, x1, y1, x2, y2
	
	// update note in w_base so that it's copied to output wave by SubtractBaseline()
	string s_note=note(w_data)
	s_note=removeending(s_note, "\r")
	if (strlen(s_note))
		s_note+="\r"
	endif
	s_note+=s_log
	note /K w_base s_note	
	
	return 1
end

function BL_FitWrap(w, w_x, w_mask, w_out, fName)
	wave w, w_x, w_mask, w_out
	string fName
	
	DebuggerOptions
	variable sav_debug=V_debugOnError 
	DebuggerOptions debugOnError=0 // switch this off in case the fit fails
	
	variable V_FitError=0
	try
		strswitch (fName)
			case "line":
				CurveFit /Q line, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				w_out = waveexists(w_x) ? w_coef[0]+w_coef[1]*w_x : w_coef[0]+w_coef[1]*x
				break
			case "poly 3":
				CurveFit /Q poly 3, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				w_out = waveexists(w_x) ? poly(w_coef,w_x) : poly(w_coef,x)
				break
			case "poly 4":
				CurveFit /Q poly 4, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				w_out = waveexists(w_x) ? poly(w_coef,w_x) : poly(w_coef,x)
				break
			case "gauss":
				CurveFit /Q gauss, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				w_out = waveexists(w_x) ? gauss1D(w_coef,w_x) : gauss1D(w_coef,x)
				break
			case "gauss3":
				CurveFit /Q gauss, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				w_coef[0]=0
				CurveFit /Q /H="1000" gauss, kwCWave=w_coef, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				print w_coef
				w_out = waveexists(w_x) ? gauss1D(w_coef,w_x) : gauss1D(w_coef,x)
				break
			case "lor":
				CurveFit /Q lor, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				wave w=w_coef
				w_out = waveexists(w_x) ? w[0]+w[1]/((w_x-w[2])^2+w[3]) : w[0]+w[1]/((x-w[2])^2+w[3])
				break
			case "exp":
				CurveFit /Q exp, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				w_out = waveexists(w_x) ? w_coef[0]+w_coef[1]*exp(-w_coef[2]*w_x) : w_coef[0]+w_coef[1]*exp(-w_coef[2]*x)
				break
			case "dblexp":
				CurveFit /Q dblexp, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				wave w=w_coef
				w_out = waveexists(w_x) ? w[0]+w[1]*exp(-w[2]*w_x)+w[3]*exp(-w[4]*w_x) : w[0]+w[1]*exp(-w[2]*x)+w[3]*exp(-w[4]*x)
				break
			case "sin":
				CurveFit /Q sin, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				wave w=w_coef
				w_out = waveexists(w_x) ? w[0]+w[1]*sin(w[2]*w_x+w[3]) : w[0]+w[1]*sin(w[2]*x+w[3])
				break
			case "hillequation":
				CurveFit /Q hillequation, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				wave w=w_coef
				w_out = waveexists(w_x) ? w[0]+(w[1]-w[0])*(w_x^w[2]/(1+(w_x^w[2]+w[3]^w[2]))) : w[0]+(w[1]-w[0])*(x^w[2]/(1+(x^w[2]+w[3]^w[2])))
				break
			case "sigmoid":
				CurveFit /Q sigmoid, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				wave w=w_coef
				w_out = waveexists(w_x) ? w[0] + w[1]/(1+exp(-(w_x-w[2])/w[3])) : w[0] + w[1]/(1+exp(-(x-w[2])/w[3]))
				break
			case "power":
				CurveFit /Q power, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				w_out = waveexists(w_x) ? w_coef[0]+w_coef[1]*w_x^w_coef[2] : w_coef[0]+w_coef[1]*x^w_coef[2]
				break
			case "lognormal":
				CurveFit /Q lognormal, w /M=w_mask /X=w_x /NWOK; AbortOnRTE
				wave w_coef
				wave w=w_coef
				w_out = waveexists(w_x) ? w[0]+w[1]*exp(-(ln(w_x/w[2])/w[3])^2) : w[0]+w[1]*exp(-(ln(x/w[2])/w[3])^2)
				break
		endswitch
	catch
		if (V_AbortCode == -4)
			Print "Error during curve fit:"
			Variable CFerror = GetRTError(1)	// 1 to clear the error
			Print GetErrMessage(CFerror)
		endif
	endtry
	
	DebuggerOptions debugOnError=sav_debug
	
	return (V_FitError	==0)
end

// set colour wave w_color for visibility against w_target.
function BL_chooseColour(w_color, s_graph, s_trace)
	wave w_color
	string s_graph, s_trace
	
	// figure out a contrasting colour for baseline and sub waves
	variable c0,c1,c2
	string s_temp=traceinfo(s_graph, s_trace, 0)
	variable v_start=strsearch(s_temp, ";rgb(x)=", 0)
	sscanf s_temp[v_start,strlen(s_temp)-1], ";rgb(x)=(%d,%d,%d*", c0,c1,c2
	make /free w_cTrace={c0,c1,c2}, w_index={1,2,3}
	MakeIndex /R w_cTrace, w_index
	IndexSort  w_index, w_color 
	return 1	
end

//static function BeforeDebuggerOpensHook(errorInRoutineStr, stoppedByBreakpoint )
//	string errorInRoutineStr
//	variable stoppedByBreakpoint
//		
//	if (stringmatch(errorInRoutineStr,"ProcGlobal#baselines#BL_FitWrap"))
//		return !stoppedByBreakpoint
//	endif
//end