#pragma rtGlobals=3		// Use modern global access method and strict wave access.\
#include <Axis Utilities>


//#include <Graph Utility Procs>
menu "Graph"
	"GraphControl",/q, GraphControlInit()
end

menu "Layout"
	"LayoutControl",/q, LayoutControl()
end

menu "AllTracesPopup" 
	"GraphControl",/q,GraphControlInit()
end

menu "TracePopup" 
	"GraphControl",/q,GraphControlInit()
end
//---------------Layout control

Window LayoutControl() : Panel
	PauseUpdate; Silent 1		// building window...
	NewPanel /W=(36,65,365,400)
	ShowTools/A
	SetVariable Left_LC,pos={10.00,22.00},size={80.00,18.00},proc=Left_Right_LC,title="Left"
	SetVariable Left_LC,value= _NUM:125
	SetVariable Top_LC,pos={10.00,42.00},size={80.00,18.00},proc=Left_Right_LC,title="Top"
	SetVariable Top_LC,value= _NUM:10
	Button SetFrame_LC,pos={275.00,63.00},size={40.00,24.00},proc=SetFrame_LC,title="frame"
	Button SetFrame_LC,labelBack=(65535,65535,65535),fColor=(65535,65535,65535)
	Button SetFrame_LC,valueColor=(34952,34952,34952)
	Button MoveLeft_LC,pos={190.00,96.00},size={30.00,30.00},proc=MoveGraphs,title="\\W546"
	Button MoveLeft_LC,fSize=9
	Button MoveRight_LC,pos={270.00,96.00},size={30.00,30.00},proc=MoveGraphs,title="\\W549"
	Button MoveRight_LC,fSize=9
	Button MoveTop_LC,pos={230.00,66.00},size={30.00,30.00},proc=MoveGraphs,title="\\W517"
	Button MoveTop_LC,fSize=9
	Button MoveBottom_LC,pos={230.00,126.00},size={30.00,30.00},proc=MoveGraphs,title="\\W523"
	Button MoveBottom_LC,fSize=9
	GroupBox LayoutGB_LC,pos={100.00,6.00},size={65.00,60.00},title="position  "
	SetVariable PLOT_TOP,pos={38.00,89.00},size={70.00,18.00},proc=LC_PLOTSIZE,title="Top"
	SetVariable PLOT_TOP,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_TOP,limits={-1,1000,10},value= _NUM:0
	SetVariable PLOT_BOTTOM,pos={18.00,131.00},size={90.00,18.00},proc=LC_PLOTSIZE,title="Bottom"
	SetVariable PLOT_BOTTOM,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_BOTTOM,limits={-1,1000,10},value= _NUM:0
	SetVariable PLOT_LEFT,pos={9.00,110.00},size={45.00,18.00},proc=LC_PLOTSIZE
	SetVariable PLOT_LEFT,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_LEFT,limits={-1,1000,10},value= _NUM:0
	SetVariable PLOT_Right,pos={106.00,110.00},size={45.00,18.00},proc=LC_PLOTSIZE
	SetVariable PLOT_Right,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_Right,limits={-1,1000,10},value= _NUM:0
	TitleBox PLOT_LEFTtitle,pos={9.00,96.00},size={20.00,15.00},title="Left",frame=0
	TitleBox PLOT_RIGHTtitle,pos={120.00,96.00},size={28.00,15.00},title="Right"
	TitleBox PLOT_RIGHTtitle,frame=0
	SetVariable PLOT_SIZEH,pos={170.00,22.00},size={95.00,18.00},proc=LC_PLOTSIZE,title="Width"
	SetVariable PLOT_SIZEH,limits={-1,1000,10},value= _NUM:0
	SetVariable PLOT_SIZEV,pos={170.00,42.00},size={95.00,18.00},proc=LC_PLOTSIZE,title="Height"
	SetVariable PLOT_SIZEV,limits={-1,1000,10},value= _NUM:0
	GroupBox PLOT_GBmargins,pos={2.00,70.00},size={163.00,88.00},title="Plot Area"
	GroupBox PLOT_GBmargins,fSize=12
	TitleBox LT_LC,pos={104.00,24.00},size={47.00,15.00},title="(100,100)"
	TitleBox LT_LC,labelBack=(65535,65535,65535),fSize=12,frame=0
	TitleBox RB_LC,pos={166.00,64.00},size={47.00,15.00},title="(100,100)"
	TitleBox RB_LC,labelBack=(65535,65535,65535),fSize=12,frame=0
	SetVariable MOVE_NUM,pos={223.00,102.00},size={45.00,18.00},title=" "
	SetVariable MOVE_NUM,valueBackColor=(56576,56576,56576)
	SetVariable MOVE_NUM,limits={1,1000,1},value= _NUM:5
	Button AlignLeft_LC,pos={190.00,162.00},size={60.00,24.00},proc=AlignGraphs,title="\\Z12align\\Z09\\W546"
	Button AlignLeft_LC,fSize=9
	Button AlignTop_LC1,pos={255.00,162.00},size={60.00,24.00},proc=AlignGraphs,title="\\Z12align\\Z09\\W517"
	Button AlignTop_LC1,fSize=9
	
	Button BringFront_LC,pos={275.00,17.00},size={40.00,24.00},proc=BringFront,title="front"
	Button BringFront_LC,labelBack=(65535,65535,65535),fColor=(65535,65535,65535)
	Button PLOT_Layout,pos={275.00,40.00},size={40.00,24.00},proc=GraphControlLayout,title="Layout"
	Button PLOT_Layout,fSize=10,fColor=(61166,61166,61166)
	Button SetGrid_LC,pos={105.00,162.00},size={60.00,24.00},proc=SetGrid,title="set grid"
	Button SetGrid_LC,labelBack=(65535,65535,65535),fColor=(65535,65535,65535)
	SetVariable Grid_LC,pos={3.00,164.00},size={100.00,18.00},proc=LC_PLOTSIZE,title="grid size"
	SetVariable Grid_LC,limits={0,100,1},value= _NUM:5
	Button LCcopy,pos={102.00,41.00},size={40.00,22.00},proc=copy_LC,title="copy"
	Button LCcopy,labelBack=(65535,65535,65535),fColor=(65535,65535,65535)
	Button LC_showG_on_L,pos={28.00,228.00},size={40.00,22.00},proc=LC_G_on_L,title="show"
	Button LC_showG_on_L,labelBack=(65535,65535,65535),fColor=(65535,65535,65535)
	TitleBox LC_G_on_L,pos={10.00,210.00},size={101.00,15.00},title="Graphs: on Layouts"
	TitleBox LC_G_on_L,fSize=12,frame=0
	Button LC_hideG_on_L1,pos={68.00,228.00},size={40.00,22.00},proc=LC_G_on_L,title="hide"
	Button LC_hideG_on_L1,labelBack=(65535,65535,65535),fColor=(65535,65535,65535)
	TitleBox LC_G_noton_L,pos={130.00,210.00},size={79.00,15.00},title="not on Layouts"
	TitleBox LC_G_noton_L,fSize=12,frame=0
	Button LC_shG_not_on_L,pos={128.00,228.00},size={40.00,22.00},proc=LC_G_on_L,title="show"
	Button LC_shG_not_on_L,labelBack=(65535,65535,65535)
	Button LC_shG_not_on_L,fColor=(65535,65535,65535)
	Button LC_hiG_not_on_L2,pos={168.00,228.00},size={40.00,22.00},proc=LC_G_on_L,title="hide"
	Button LC_hiG_not_on_L2,labelBack=(65535,65535,65535)
	Button LC_hiG_not_on_L2,fColor=(65535,65535,65535)
	Button LC_showPlotsFromDF,pos={28.00,258.00},size={180.00,22.00},proc=LC_plotsfromDF,title="Graphs from selected datafolder"
	Button LC_showPlotsFromDF,labelBack=(65535,65535,65535)
	Button LC_showPlotsFromDF,fColor=(65535,65535,65535)
	CheckBox LC_subDF,pos={212.00,262.00},size={104.00,15.00},title="check subfolders"
	CheckBox LC_subDF,value= 1
	Button LC_Kill_DF,pos={28.00,288.00},size={180.00,22.00},proc=LC_deleteDF_plots,title="Delete datafolder and graphs"
	Button LC_Kill_DF,labelBack=(65535,65535,65535),fColor=(65535,65535,65535)
	GroupBox Manage_Windows,pos={2.00,190.00},size={320.00,127.00},title="Manage Windows"
	GroupBox Manage_Windows,fSize=12

	SetWindow kwTopWin,hook(newLayoutControl)=LayoutControlPanelHook
EndMacro

//events that happen when graphcontrol panel is activated or resized
function LayoutControlPanelHook(s)
	STRUCT WMWinHookStruct &s	
	if ((s.eventcode==0))//&&(strlen(winname(0,1+2+4+16+128+4096))))//activate
		if(strlen(winname(0,4))>0)
			SetWindow $winname(0,4) hook(newLayoutControl)=LayoutControlHook			
		endif
	endif
end



//the layout is now lnked to layoutcontrol panel
function LayoutControlHook(s)
	STRUCT WMWinHookStruct &s
	dowindow LayoutControl
	if (v_flag)
		if ((s.eventcode==5)||(s.eventcode==11))
			execute /p /q "Measure_LC(\"\")"
		endif
		if (s.eventcode!=4)
		//	print s.eventcode
		endif
	endif
End

//set the position of active graphs
Function Left_Right_LC(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName
	if(strlen(winname(0,4))>0)
		string info=layoutinfo("","layout")
		string selected=stringbykey("SELECTED",info,":")
		//print selected
		variable i
		for(i=0;i<itemsinlist(selected,",");i+=1)
			if(stringmatch("left_LC",ctrlName))
				ModifyLayout left($stringfromlist(i,selected,","))=varNum
			else
				ModifyLayout top($stringfromlist(i,selected,","))=varNum
			endif
		endfor
		dowindow /F $winname(0,4)
		dowindow /F LayoutControl
	endif	
End

Function copy_LC(ctrlName) : ButtonControl
	String ctrlName
	controlinfo/w=layoutcontrol LT_LC
	variable startpos=strsearch(S_recreation,"(",0),endpos=strsearch(S_recreation,")",0)
	if(endpos-startpos>3)
		SetVariable Left_LC win=layoutcontrol,value= _NUM:str2num(S_recreation[startpos+1,strsearch(S_recreation,",",startpos)-1])
		SetVariable Top_LC win=layoutcontrol,value= _NUM:str2num(S_recreation[strsearch(S_recreation,",",startpos)+1,endpos-1])

	endif
End

Function SetGrid(ctrlName) : ButtonControl
	String ctrlName
	string S_recreation=""
	drawaction /w=$winname(0,4) commands
	if(strlen(S_recreation)>0)
		string items=S_recreation,item,text,command
		drawaction /w=$winname(0,4) delete
		variable line,locx,locy,locR,locB
		controlinfo/w=layoutcontrol Grid_LC
		variable gridsize=v_value
		dowindow/f $winname(0,4)
		//doupdate
		for(line=0;line<itemsinlist(items);line+=1)
			//print line,
			item=stringfromlist(line,items)
			if (stringmatch(item,"*item*")==0)
				command=""
				if (stringmatch(item,"*DrawRect*"))
					command="DrawRect"
				endif
				if (stringmatch(item,"*DrawLine*"))
					command="DrawLine"
				endif
				if (stringmatch(item,"*DrawRRect*"))
					command="DrawRRect"
				endif
				if (stringmatch(item,"*DrawOval*"))
					command="DrawOval"
				endif												
				if (stringmatch(item,"*DrawText*"))					
					sscanf item, " DrawText %f,%f,%s ", locx,locy,text
					text=item[strsearch(item,",",strlen(item),1)+1,strlen(item)-1]
					//print text
					locx=round(locx/gridsize)*gridsize
					locy=round(locy/gridsize)*gridsize
					sprintf item, "DrawText/w=%s %g,%g,%s",winname(0,4), locx,locy,text		
					//print item
				endif
				if (strlen(command)>0)					
					sscanf item, " "+command+" %f,%f,%f,%f", locx,locy,locR,locB
					locx=round(locx/gridsize)*gridsize
					locy=round(locy/gridsize)*gridsize
					locR=round(locR/gridsize)*gridsize
					locB=round(locB/gridsize)*gridsize
					sprintf item, command+"/w=%s %g,%g,%g,%g",winname(0,4), locx,locy,locR,locB		
				endif
												
				if (stringmatch(item,"*SetDrawEnv*"))
					item=replacestring("SetDrawEnv",item,"SetDrawEnv/w="+winname(0,4))//+",save, ")
					
				endif
				item=replacestring("//",item,"")
				item=replacestring("\r",item,"")
				execute/p/q item
			endif
	//			print item		
		endfor
	endif
	//execute S_recreation
End

//measure the location of active graphs
Function Measure_LC(ctrlName) : ButtonControl
	String ctrlName
	if(strlen(winname(0,4))>0)
		string info=layoutinfo("","layout")
		string selected=stringbykey("SELECTED",info,":")
		if(itemsinlist(selected,",")>0)
			variable posLeft=str2num(stringbykey("left",layoutinfo("",stringfromlist(0,selected,",")))) 
			variable posTop=str2num(stringbykey("top",layoutinfo("",stringfromlist(0,selected,",")))) 
			if (strlen(winlist(stringfromlist(0,selected,","),";","win:1"))>0)//graph exists
	 			getwindow $stringfromlist(0,selected,",") gsize
				variable left=v_left,right=v_right,top=v_top,bottom=v_bottom
				getwindow $stringfromlist(0,selected,",") psize
				left+=v_left;right-=v_right;top+=v_top;bottom-=v_bottom
				SetVariable PLOT_TOP, win=LayoutControl,value= _NUM:round(top)
				SetVariable PLOT_LEFT, win=LayoutControl,value= _NUM:round(left)
				TitleBox LT_LC , win=LayoutControl,title="("+num2str((posLeft))+","+num2str((postop))+")"
				TitleBox RB_LC , win=LayoutControl,title="("+num2str(round(posLeft+v_right-v_left))+","+num2str(round(postop+v_bottom-v_top))+")"
				SetVariable PLOT_RIGHT, win=LayoutControl,value= _NUM:round(right)
				SetVariable PLOT_BOTTOM, win=LayoutControl,value= _NUM:round(bottom)
				SetVariable PLOT_SIZEH, win=LayoutControl,value= _NUM:round(v_right-v_left)
				SetVariable PLOT_SIZEV, win=LayoutControl,value= _NUM:round(v_bottom-v_top)
			endif
		else
			TitleBox LT_LC , win=LayoutControl,title="(,)"
			TitleBox RB_LC , win=LayoutControl,title="(,)"
			
		endif
	endif
End


//moves selected graphs by a number
Function MoveGraphs(ctrlName) : ButtonControl
	String ctrlName
	variable moveleft=0,movetop=0
	controlinfo/w=LayoutControl Move_num
	if(stringmatch(ctrlName,"*left*"))
		moveleft=-v_value			
	endif
	if(stringmatch(ctrlName,"*right*"))
		moveleft=v_value				
	endif
	if(stringmatch(ctrlName,"*top*"))
		movetop=-v_value				
	endif
	if(stringmatch(ctrlName,"*bottom*"))
		movetop=v_value				
	endif
	if(stringmatch(ctrlName,"*100*"))
		moveleft*=10
		movetop*=10
	endif
	if(strlen(winname(0,4))>0)
		string info=layoutinfo("","layout")
		string selected=stringbykey("SELECTED",info,":")
		variable i
		for(i=0;i<itemsinlist(selected,",");i+=1)
			ModifyLayout left($stringfromlist(i,selected,","))=str2num(stringbykey("left",layoutinfo("",stringfromlist(i,selected,","))))+moveleft
			ModifyLayout top($stringfromlist(i,selected,","))=str2num(stringbykey("top",layoutinfo("",stringfromlist(i,selected,","))))+movetop
		endfor
		dowindow /F $winname(0,4)
		dowindow /F LayoutControl	
	endif
	execute /p /q "Measure_LC(\"\")"
End

//alighs selected graphs left
Function AlignGraphs(ctrlName) : ButtonControl
	String ctrlName
	controlinfo/w=LayoutControl Move_num
	variable moveleft=(stringmatch(ctrlName,"*left*"))
	variable movetop=(stringmatch(ctrlName,"*top*"))
	
	if(strlen(winname(0,4))>0)
		string info=layoutinfo("","layout")
		string selected=stringbykey("SELECTED",info,":")
		if(strlen(selected)>0)
			variable i,mostleftpos=inf,mosttoppos=inf
			for(i=0;i<itemsinlist(selected,",");i+=1)
				mostleftpos=min(mostleftpos,str2num(stringbykey("left",layoutinfo("",stringfromlist(i,selected,",")))))
				mosttoppos=min(mosttoppos,str2num(stringbykey("top",layoutinfo("",stringfromlist(i,selected,",")))))
			endfor	
			for(i=0;i<itemsinlist(selected,",");i+=1)
				if(moveleft)
					ModifyLayout left($stringfromlist(i,selected,","))=mostleftpos
				else
					ModifyLayout top($stringfromlist(i,selected,","))=mosttoppos
				endif
			endfor
		endif
		dowindow /F $winname(0,4)
		dowindow /F LayoutControl	
	endif
	execute /p /q "Measure_LC(\"\")"
End

//update of the plot params for graphs selected on alyout
Function LC_PLOTSIZE(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName
	variable minval,maxval

	if(strlen(winname(0,4))>0)
		string info=layoutinfo("","layout")
		string selected=stringbykey("SELECTED",info,":")
		variable i
		for(i=0;i<itemsinlist(selected,",");i+=1)
			
			if(stringmatch(ctrlName,"*left*"))
				ModifyGraph/w=$stringfromlist(i,selected,",") margin(left)=varNum
			endif
			if(stringmatch(ctrlName,"*right*"))
				ModifyGraph/w=$stringfromlist(i,selected,",") margin(right)=varNum
			endif			
			if(stringmatch(ctrlName,"*top*"))
				ModifyGraph/w=$stringfromlist(i,selected,",") margin(top)=varNum
			endif	
			if(stringmatch(ctrlName,"*bottom*"))
				ModifyGraph/w=$stringfromlist(i,selected,",") margin(bottom)=varNum
			endif			
			if(stringmatch(ctrlName,"*sizev*"))
				ModifyGraph/w=$stringfromlist(i,selected,",") height=varNum
			endif		
			if(stringmatch(ctrlName,"*sizeh*"))
				ModifyGraph/w=$stringfromlist(i,selected,",") width=varNum
			endif	
		endfor
		execute /p /q "dowindow /F "+winname(0,4)
		execute /p /q "dowindow /F LayoutControl"	
		execute /p /q "Measure_LC(\"\")"					
	endif	
	
end

//changes to transparent and no frame
Function SetFrame_LC(ctrlName) : ButtonControl
	String ctrlName
	if(strlen(winname(0,4))>0)
		ModifyLayout trans=1,frame=0
		dowindow /F $winname(0,4)
		dowindow /F LayoutControl
	endif
End

//brings the graph to front
Function BringFront(ctrlName) : ButtonControl
	String ctrlName
	if(strlen(winname(0,4))>0)
		string info=layoutinfo("","layout")
		string selected=stringbykey("SELECTED",info,":")
		variable i
		for(i=0;i<itemsinlist(selected,",");i+=1)
			
			dowindow /f $stringfromlist(i,selected,",") 
		endfor
	endif
End

//-----manage windows procedures-----------------

//----manages graphs on layouts
Function LC_G_on_L(ctrlName) : ButtonControl
	String ctrlName
	string graphs
	string graphlist_onlayouts=""
	variable laynum,graphnum,pagenum
	for (laynum=0;laynum<itemsinlist(winlist("*",";","WIN:4"));laynum+=1)//finds all layouts
		string currentlayout=stringfromlist(laynum,winlist("*",";","WIN:4"))
		string info=layoutinfo(currentlayout,"layout")
		variable currentpage=numberbykey("CURRENTPAGENUM",info,":")
		for(pagenum=0;pagenum<numberbykey("NUMPAGES",info,":");pagenum+=1)//finds all pages
			LayoutPageAction/w=$currentlayout page=pagenum+1
			for(graphnum=0;graphnum<numberbykey("NUMOBJECTS",layoutinfo(currentlayout,"layout"),":");graphnum+=1)//finds all graphs
				if(stringmatch(ctrlName,"*show*"))
					dowindow/F $stringbykey("NAME",layoutinfo(currentlayout,num2str(graphnum)),":")
				elseif(stringmatch(ctrlName,"*hide*"))
					dowindow/HIDE=1 $stringbykey("NAME",layoutinfo(currentlayout,num2str(graphnum)),":")
				endif
				graphlist_onlayouts+=stringbykey("NAME",layoutinfo(currentlayout,num2str(graphnum)),":")+";"
			endfor
		endfor
		LayoutPageAction/w=$currentlayout page=currentpage
	endfor
	if(stringmatch(ctrlName,"*not*"))//work on graphs not on layouts
		for (graphnum=0;graphnum<itemsinlist(winlist("*",";","WIN:1"));graphnum+=1)//finds all graphs
			graphs=stringfromlist(graphnum,winlist("*",";","WIN:1"))
			if(FindListItem(graphs,graphlist_onlayouts,";")==-1)//not on layout
				if(stringmatch(ctrlName,"*sh*"))
					dowindow/F $graphs
				elseif(stringmatch(ctrlName,"*hi*"))
					dowindow/HIDE=1 $graphs
				endif
			
			endif
		endfor
	endif
End

//-----show plots that reference DF
function DF_plot(DF,deep,delete)
	string DF
	variable deep,delete
	variable graphnum,tracenum,foundplot,subDF
	string graphname,tracename
	setdatafolder DF
	for (graphnum=0;graphnum<itemsinlist(winlist("*",";","WIN:1"));graphnum+=1)//finds all graphs
		graphname=stringfromlist(graphnum,winlist("*",";","WIN:1"),";")
		if(strlen(WaveList("*", ";", "win:"+graphname ))>0)
			
			if(delete)
				killwindow /z $graphname
			else
				dowindow/f $graphname
			endif
		endif
	endfor
	if(deep)
		string Folders=stringbykey("FOLDERS",DataFolderDir(1),":")
		for (subDF=0;subDF<itemsinlist(Folders,",");subDF+=1)
			if(DataFolderExists(getdatafolder(1)+""+stringfromlist(subDF,Folders,",")))
				DF_plot(getdatafolder(1)+""+stringfromlist(subDF,Folders,","),deep,delete)
			else
				DF_plot(getdatafolder(1)+"'"+stringfromlist(subDF,Folders,",")+"'",deep,delete)
			endif
			setdatafolder DF
		endfor
	endif
	
	return 1
end

//---shows all plots that reference waves in selected datafolder
Function LC_plotsfromDF(ctrlName) : ButtonControl
	String ctrlName

	string DF=getdatafolder(1),checkDF=DF+";"
	controlinfo/w=LayoutControl LC_subDF
	DF_plot(DF,v_value,0)
	setdatafolder DF
End



Function LC_deleteDF_plots(ctrlName) : ButtonControl
	String ctrlName

	string DF=getdatafolder(1),checkDF=DF+";"
	controlinfo/w=LayoutControl LC_subDF
	DF_plot(DF,v_value,1)
	setdatafolder DF
	killdatafolder/z DF
End


//-----------------------------------GC---------------------------------------

//creates the graphcontrol panel and initializes the graphcontrol directory
function GraphControlInit()
	string DF=getdatafolder(1)
	newdatafolder/o/s root:graphcontrol
	make/o/n=0/t listtext,listtitle
	make/o/n=0 listselect
	make/o/n=9/t listcol={"Pos","Color","Y wave","X Wave","Y DF","X DF","Error Bars","Y Axis","X Axis"}
	make/o/n=9 listcolselect=1
	string/g axisleft,axisbottom
	
	dowindow /k GraphControl
	NewPanel /k=1/W=(200,50,1064,400)/n=GraphControl/flt=0 as "Graph Contol" 

	PopupMenu TRACE_COL,pos={267.00,62.00},size={50.00,19.00},disable=1,proc=TRACE_PARAMS
	PopupMenu TRACE_COL,mode=1,popColor= (0,0,0),value= #"\"*COLORPOP*\""
	PopupMenu TRACE_LINE,pos={213.00,62.00},size={50.00,19.00},bodyWidth=50,disable=1,proc=TRACE_PARAMS
	PopupMenu TRACE_LINE,mode=1,value= #"\"*LINESTYLEPOP*\""
	PopupMenu TRACE_MARKER,pos={95.00,103.00},size={50.00,19.00},disable=1,proc=TRACE_PARAMS
	PopupMenu TRACE_MARKER,mode=9,value= #"\"*MARKERPOP*\""
	PopupMenu TRACE_MODE,pos={5.00,61.00},size={117.00,19.00},disable=1,proc=TRACE_PARAMS
	PopupMenu TRACE_MODE,mode=5,popvalue="Lines and markers",value= #"\"Lines;Sticks to zero;Dots;Markers;Lines and markers;Bars;Cityscape;Fill to zero;Sticks and markers\""
	SetVariable TRACE_LINESIZE,pos={125.00,62.00},size={85.00,18.00},disable=1,proc=TRACE_VAR,title="Line size:"
	SetVariable TRACE_LINESIZE,limits={0,10,1},value= _NUM:1
	PopupMenu TRACE_MARKERCOLSTROKE,pos={95.00,125.00},size={50.00,19.00},disable=1,proc=TRACE_PARAMS
	PopupMenu TRACE_MARKERCOLSTROKE,mode=1,popColor= (0,0,0),value= #"\"*COLORPOP*\""
	SetVariable TRACE_MARKERSIZE,pos={7.00,104.00},size={85.00,18.00},disable=1,proc=TRACE_VAR,title="Size:"
	SetVariable TRACE_MARKERSIZE,limits={0,10,1},value= _NUM:0
	SetVariable TRACE_MARKERTHICK,pos={7.00,126.00},size={85.00,18.00},disable=1,proc=TRACE_VAR,title="Thick:"
	SetVariable TRACE_MARKERTHICK,limits={0,10,1},value= _NUM:0.5
	CheckBox TRACE_MARKEROPAQUE,pos={149.00,106.00},size={57.00,15.00},disable=1,proc=TRACE_CHECK,title="Opaque"
	CheckBox TRACE_MARKEROPAQUE,value= 1
	CheckBox TRACE_MARKERSTROKE,pos={149.00,128.00},size={48.00,15.00},disable=1,proc=TRACE_CHECK,title="Stroke"
	CheckBox TRACE_MARKERSTROKE,value= 0
	PopupMenu TRACE_FILLTYPEplus,pos={14.00,104.00},size={138.00,19.00},bodyWidth=60,disable=1,proc=TRACE_PARAMS,title="\\W600 Fill type:"
	PopupMenu TRACE_FILLTYPEplus,mode=1,popvalue="None",value= #"\"None;Erase;Solid;75%;50%;25%\""
	PopupMenu TRACE_COLFILLplus,pos={156.00,104.00},size={50.00,19.00},disable=1,proc=TRACE_PARAMS
	PopupMenu TRACE_COLFILLplus,mode=1,popColor= (65535,0,0),value= #"\"*COLORPOP*\""
	CheckBox TRACE_FILLCOLORplus,pos={7.00,107.00},size={13.00,13.00},disable=1,proc=TRACE_CHECK,title=""
	CheckBox TRACE_FILLCOLORplus,value= 0
	PopupMenu TRACE_FILLTYPEneg,pos={14.00,126.00},size={138.00,19.00},bodyWidth=60,disable=1,proc=TRACE_PARAMS,title="\\W609 Fill type:"
	PopupMenu TRACE_FILLTYPEneg,mode=1,popvalue="Same",value= #"\"Same;None;Erase;Solid;75%;50%;25%\""
	PopupMenu TRACE_COLFILLneg,pos={156.00,126.00},size={50.00,19.00},disable=1,proc=TRACE_PARAMS
	PopupMenu TRACE_COLFILLneg,mode=1,popColor= (65535,0,0),value= #"\"*COLORPOP*\""
	CheckBox TRACE_FILLCOLORneg,pos={7.00,129.00},size={13.00,13.00},disable=1,proc=TRACE_CHECK,title=""
	CheckBox TRACE_FILLCOLORneg,value= 0
	Button TRACE_REMOVE,pos={55.00,15.00},size={55.00,25.00},disable=1,proc=TRACEREMOVE,title="Remove"
	Button TRACE_REMOVE,fSize=12
	Button buttonTRACE_APPEND,pos={5.00,15.00},size={50.00,25.00},proc=TRACEAPPEND,title="Append"
	Button buttonTRACE_APPEND,fSize=12
	Button TRACE_COPY,pos={110.00,15.00},size={70.00,25.00},disable=1,proc=TRACECOPY,title="Copy trace"
	Button TRACE_COPY,fSize=12
	Button buttonTRACE_PASTE,pos={180.00,15.00},size={70.00,25.00},proc=TRACE_PASTE,title="Paste trace"
	Button buttonTRACE_PASTE,fSize=12
	GroupBox TRACE_GBline,pos={2.00,45.00},size={410.00,40.00},disable=1,title="Selected trace"
	GroupBox TRACE_GBline,fSize=12
	GroupBox TRACE_GBfill,pos={2.00,85.00},size={210.00,65.00},disable=1,title="Fill"
	GroupBox TRACE_GBfill,fSize=12
	GroupBox TRACE_GBmarker,pos={2.00,85.00},size={210.00,65.00},disable=1,title="Marker"
	GroupBox TRACE_GBmarker,fSize=12
	GroupBox GBTRACES,pos={2.00,0.00},size={252.00,44.00},title="Traces"
	TitleBox TRACE_INFO,pos={72.00,152.00},size={56.00,15.00},disable=1,title="Recreation"
	TitleBox TRACE_INFO,labelBack=(61166,61166,61166),frame=0
	SetVariable PLOT_TOP,pos={609.00,17.00},size={70.00,18.00},proc=PLOTSIZE,title="Top"
	SetVariable PLOT_TOP,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_TOP,limits={-1,1000,10},value= _NUM:20
	SetVariable PLOT_BOTTOM,pos={589.00,59.00},size={90.00,18.00},proc=PLOTSIZE,title="Bottom"
	SetVariable PLOT_BOTTOM,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_BOTTOM,limits={-1,1000,10},value= _NUM:30
	SetVariable PLOT_LEFT,pos={573.00,38.00},size={45.00,18.00},proc=PLOTSIZE
	SetVariable PLOT_LEFT,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_LEFT,limits={-1,1000,10},value= _NUM:35
	SetVariable PLOT_Right,pos={680.00,38.00},size={45.00,18.00},proc=PLOTSIZE
	SetVariable PLOT_Right,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_Right,limits={-1,1000,10},value= _NUM:35
	TitleBox PLOT_LEFTtitle,pos={573.00,24.00},size={20.00,15.00},title="Left"
	TitleBox PLOT_LEFTtitle,frame=0
	TitleBox PLOT_RIGHTtitle,pos={694.00,24.00},size={28.00,15.00},title="Right"
	TitleBox PLOT_RIGHTtitle,frame=0
	SetVariable PLOT_SIZEH,pos={769.00,17.00},size={80.00,18.00},proc=PLOTSIZE,title="Width"
	SetVariable PLOT_SIZEH,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_SIZEH,limits={-1,1000,10},value= _NUM:120
	SetVariable PLOT_SIZEV,pos={764.00,37.00},size={85.00,18.00},proc=PLOTSIZE,title="Height"
	SetVariable PLOT_SIZEV,valueBackColor=(56576,56576,56576)
	SetVariable PLOT_SIZEV,limits={-1,1000,10},value= _NUM:100
	PopupMenu PLOT_AXIS_LEFT,pos={420.00,103.00},size={124.00,19.00},bodyWidth=100,proc=PLOTAXISSEL,title="Axis"
	PopupMenu PLOT_AXIS_LEFT,mode=1,popvalue="left",value= #"getaxistype(0)"
	PopupMenu PLOT_AXIS_BOTTOM,pos={640.00,103.00},size={124.00,19.00},bodyWidth=100,proc=PLOTAXISSEL,title="Axis"
	PopupMenu PLOT_AXIS_BOTTOM,mode=1,popvalue="bottom",value= #"getaxistype(1)"
	SetVariable PLOT_BOTTOM_MAX,pos={798.00,126.00},size={35.00,18.00},proc=PLOTSIZE
	SetVariable PLOT_BOTTOM_MAX,labelBack=(65535,65535,65535),value= _NUM:10
	SetVariable PLOT_BOTTOM_MIN,pos={798.00,104.00},size={31.00,18.00},proc=PLOTSIZE
	SetVariable PLOT_BOTTOM_MIN,labelBack=(65535,65535,65535),value= _NUM:0
	SetVariable PLOT_LEFT_MAX,pos={579.00,126.00},size={31.00,18.00},proc=PLOTSIZE
	SetVariable PLOT_LEFT_MAX,labelBack=(65535,65535,65535),value= _NUM:1
	SetVariable PLOT_LEFT_MIN,pos={579.00,104.00},size={51.00,18.00},proc=PLOTSIZE
	SetVariable PLOT_LEFT_MIN,labelBack=(65535,65535,65535),value= _NUM:1e-307
	SetVariable ERROR_YP,pos={305.00,103.00},size={110.00,18.00},disable=1
	SetVariable ERROR_YP,labelBack=(60928,60928,60928),frame=0
	SetVariable ERROR_YP,valueBackColor=(60928,60928,60928)
	SetVariable ERROR_YP,limits={0,10,1},value= _STR:"am_sd_nd",noedit= 1
	CheckBox ERROR_YP_CHECK,pos={279.00,106.00},size={23.00,15.00},disable=1,proc=ERRORBARS_CHECK,title="+"
	CheckBox ERROR_YP_CHECK,value= 1,side= 1
	SetVariable ERROR_YN,pos={305.00,125.00},size={110.00,18.00},disable=1
	SetVariable ERROR_YN,labelBack=(60928,60928,60928),frame=0
	SetVariable ERROR_YN,valueBackColor=(60928,60928,60928)
	SetVariable ERROR_YN,limits={0,10,1},value= _STR:"am_sd_nd",noedit= 1
	CheckBox ERROR_YN_CHECK,pos={282.00,128.00},size={20.00,15.00},disable=1,proc=ERRORBARS_CHECK,title="-"
	CheckBox ERROR_YN_CHECK,value= 1,side= 1
	SetVariable ERROR_XP,pos={289.00,108.00},size={50.00,18.00},disable=1
	SetVariable ERROR_XP,labelBack=(60928,60928,60928),frame=0
	SetVariable ERROR_XP,valueBackColor=(60928,60928,60928)
	SetVariable ERROR_XP,limits={0,10,1},value= _STR:"",noedit= 1
	CheckBox ERROR_XP_CHECK,pos={278.00,111.00},size={13.00,13.00},disable=1,proc=ERRORBARS_CHECK,title=""
	CheckBox ERROR_XP_CHECK,value= 0,mode=2,side= 1
	SetVariable ERROR_XN,pos={289.00,122.00},size={50.00,18.00},disable=1
	SetVariable ERROR_XN,labelBack=(60928,60928,60928),frame=0
	SetVariable ERROR_XN,valueBackColor=(60928,60928,60928)
	SetVariable ERROR_XN,limits={0,10,1},value= _STR:"",noedit= 1
	CheckBox ERROR_XN_CHECK,pos={278.00,125.00},size={13.00,13.00},disable=1,proc=ERRORBARS_CHECK,title=""
	CheckBox ERROR_XN_CHECK,value= 1,mode=2,side= 1
	TitleBox ERROR_X,pos={283.00,97.00},size={5.00,15.00},disable=1,title="x"
	TitleBox ERROR_X,frame=0

	SetVariable ERROR_CAPW,pos={269.00,148.00},size={40.00,18.00},proc=ERR_VISUAL,title="-"
	SetVariable ERROR_CAPW,limits={0,10,1},value= _NUM:4
	SetVariable ERROR_CAPH,pos={311.00,148.00},size={40.00,18.00},proc=ERR_VISUAL,title="|"
	SetVariable ERROR_CAPH,limits={0,10,1},value= _NUM:1
	SetVariable ERROR_BAR,pos={353.00,148.00},size={55.00,18.00},proc=ERR_VISUAL,title="Bar:"
	SetVariable ERROR_BAR,limits={0,10,1},value= _NUM:1

	TitleBox PLOT_INFO,pos={710.00,65.00},size={56.00,15.00},title="Recreation"
	TitleBox PLOT_INFO,frame=0
	Button PLOTINFO_COPY,pos={770.00,60.00},size={40.00,25.00},proc=PLOTINFOCOPY,title="Copy"
	Button PLOTINFO_PASTE,pos={810.00,60.00},size={40.00,25.00},proc=PLOTINFOPASTE,title="Paste"
	SetVariable PLOT_BOTTOM_LABEL,pos={687.00,148.00},size={163.00,18.00},proc=PLOT_LABEL,title="Label:"
	SetVariable PLOT_BOTTOM_LABEL,value= _STR:"σ\\BAmp\\M modulation (SNR)"
	CheckBox TRANS_HIDE_BOTTOM,pos={640.00,150.00},size={40.00,15.00},proc=AXISHIDE,title="Hide"
	CheckBox TRANS_HIDE_BOTTOM,value= 0
	SetVariable PLOT_LEFT_LABEL,pos={467.00,148.00},size={163.00,18.00},proc=PLOT_LABEL,title="Label:"
	SetVariable PLOT_LEFT_LABEL,value= _STR:"norm. IPSC"
	CheckBox TRANS_HIDE_LEFT,pos={420.00,150.00},size={40.00,15.00},proc=AXISHIDE,title="Hide"
	CheckBox TRANS_HIDE_LEFT,value= 0
	GroupBox ERRORBARS_GB,pos={214.00,85.00},size={200.00,86.00},disable=1,title="Error bars"
	GroupBox PLOT_AXES,pos={416.00,85.00},size={443.00,86.00},title="Axes"
	GroupBox PLOT_AXES,fSize=12
	GroupBox PLOT_GBmargins,pos={560.00,1.00},size={299.00,90.00},title="Plot Area"
	GroupBox PLOT_GBmargins,fSize=12
	ListBox PLOTLIST,pos={5.00,175.00},size={859.00,149.00},proc=TRACELIST,frame=2
	ListBox PLOTLIST,listWave=root:graphcontrol:listtext
	ListBox PLOTLIST,selWave=root:graphcontrol:listselect
	ListBox PLOTLIST,titleWave=root:graphcontrol:listtitle,mode= 9
	ListBox PLOTLIST,widths={41,40,96,54,188,75,215,183,199},userColumnResize= 1
	CheckBox PLOT_LEFT_MODE_LINEAR,pos={420.00,128.00},size={47.00,15.00},proc=PLOTAXISMODE,title="Linear"
	CheckBox PLOT_LEFT_MODE_LINEAR,value= 1,mode=1
	CheckBox PLOT_LEFT_MODE_LOG,pos={471.00,128.00},size={35.00,15.00},proc=PLOTAXISMODE,title="Log"
	CheckBox PLOT_LEFT_MODE_LOG,value= 0,mode=1
	CheckBox PLOT_LEFT_MODE_LOG2,pos={510.00,128.00},size={41.00,15.00},proc=PLOTAXISMODE,title="Log2"
	CheckBox PLOT_LEFT_MODE_LOG2,value= 0,mode=1
	CheckBox PLOT_BOTTOM_MODE_LINEAR,pos={640.00,128.00},size={47.00,15.00},proc=PLOTAXISMODE,title="Linear"
	CheckBox PLOT_BOTTOM_MODE_LINEAR,value= 1,mode=1
	CheckBox PLOT_BOTTOM_MODE_LOG,pos={691.00,128.00},size={35.00,15.00},proc=PLOTAXISMODE,title="Log"
	CheckBox PLOT_BOTTOM_MODE_LOG,value= 0,mode=1
	CheckBox PLOT_BOTTOM_MODE_LOG2,pos={730.00,128.00},size={41.00,15.00},proc=PLOTAXISMODE,title="Log2"
	CheckBox PLOT_BOTTOM_MODE_LOG2,value= 0,mode=1
	Button PLOT_LEFT_AUTO_MIN,pos={562.00,105.00},size={16.00,16.00},proc=AUTOAXIS,title="*"
	Button PLOT_LEFT_AUTO_MAX,pos={562.00,127.00},size={16.00,16.00},proc=AUTOAXIS,title="*"
	Button PLOT_BOTTOM_AUTO_MIN,pos={781.00,105.00},size={16.00,16.00},proc=AUTOAXIS,title="*"
	Button PLOT_BOTTOM_AUTO_MAX,pos={781.00,127.00},size={16.00,16.00},proc=AUTOAXIS,title="*"
	SetVariable TRACE_TRANS,pos={323.00,62.00},size={85.00,18.00},disable=1,proc=TRACE_VAR,title="Alpha:"
	SetVariable TRACE_TRANS,limits={0,1,0.1},value= _NUM:1,format="%.3g"
	Button PLOT_LINK,pos={480.00,12.00},size={50.00,32.00},proc=GraphControlLinktoGraph,title="Unlink"
	Button PLOT_LINK,userdata=  "1",labelBack=(39168,39168,39168),fStyle=1
	Button PLOT_LINK,fColor=(48896,49152,65280)
	Button PLOT_DUPLICATE,pos={390.00,12.00},size={90.00,32.00},proc=GraphControlDuplicateDF,title="Duplicate @DF"
	Button PLOT_DUPLICATE,fColor=(48896,49152,65280)
	Button PLOT_ENHANCE,pos={475.00,77.00},size={80.00,22.00},disable=0,proc=GraphControlEnhance,title="Enhance"
	Button PLOT_ENHANCE,fSize=12
	Button TRACEINFO_COPY,pos={132.00,147.00},size={40.00,24.00},disable=1,proc=INFOCOPY,title="Copy"
	Button TRACEINFO_COPY,fSize=12
	Button TRACEINFO_PASTE,pos={172.00,147.00},size={40.00,24.00},disable=1,proc=INFOPASTE,title="Paste"
	Button TRACEINFO_PASTE,fSize=12
	Button PLOT_FRONT,pos={290.00,12.00},size={40.00,32.00},proc=GraphControlShowPlot,title="Show"
	Button PLOT_FRONT,fColor=(48896,49152,65280)
	Button PLOT_Layout,pos={330.00,12.00},size={60.00,32.00},proc=GraphControlLayout,title="To Layout"
	Button PLOT_Layout,fColor=(48896,49152,65280)
	CheckBox ERROR_SHADE,pos={217.00,150.00},size={46.00,15.00},proc=ERRORBARS_CHECK,title="shade"
	CheckBox ERROR_SHADE,labelBack=(65535,32768,32768),value= 0
	PopupMenu TRACE_SHADE_EB,pos={267.00,148.00},size={50.00,19.00},proc=TRACE_SHADE_EBpopup
	PopupMenu TRACE_SHADE_EB,mode=1,popColor= (0,0,0),value= #"\"*COLORPOP*\""
	SetVariable TRACE_TRANS_SHADE,pos={323.00,148.00},size={85.00,18.00},proc=TRACE_TRANS_SHADE,title="Alpha:"
	SetVariable TRACE_TRANS_SHADE,format="%.3g",limits={0,1,0.05},value= _NUM:1


	SetWindow GraphControl,hook(newgraphcontrol)=GraphControlPanelHook	
	getwindow GraphControl wsizeDC
	ListBox PLOTLIST size={V_right-V_left-11,V_bottom-V_top-180}
	
	setdatafolder DF	
	updatetracelist(0)
	execute "updatetracecontrols(-1)"	
end



//updates the trace information according to selection 
function updatetracelist(event)
	variable event
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:
	wave listcolselect 
	//setdatafolder DF
	variable colnum=sum(	listcolselect)	,stop=0
	dowindow GraphControl	
	if(V_flag==1) //graph control exists
		if((event==2)||(event==15))//kill or hide target window
			make/o/n=(1,colnum) listselect=0
			make/o/t/n=(1,colnum) listtext
			stop=1						
		endif
		if ((strlen(winname(0,1)))&&(stop==0))//target windows exists
			DoWindow/T GraphControl,"Graph Contol - "+winname(0,1)
			SetWindow $winname(0,1) hook(newgraphcontrol)=GraphControlHook
			
			variable tracesnum=itemsinlist(TraceNameList("", ";", 1 ))
			if((event==0)||(event==16))//activate or unhide
				make/o/n=(tracesnum,colnum) listselect=0
				make/o/WAVE/n=(tracesnum) ywaveref,xwaveref
			endif
			Redimension/N=(tracesnum,colnum) listselect
			Redimension/N=(tracesnum) ywaveref,xwaveref
			updateplotparams()
			//fill the information
			make/o/t/n=(tracesnum,colnum) listtext
			make/o/t/n=(colnum) listtitle
			wave/t listcol
			variable tnum,ncol
			string st 
			for (tnum=0;tnum<tracesnum;tnum+=1)
				ncol=0
				string tracename=stringfromlist(tnum,TraceNameList("", ";", 1 ))	
				string info =traceinfo("",tracename,0)
				ywaveref[tnum]=waverefindexed("",tnum,1)
				xwaveref[tnum]=XWaveRefFromTrace("", tracename )

				
				if (listcolselect[0])//pos
					listtext[tnum][ncol]=num2str(tnum+1)
					if((tnum==0)&&(tnum<tracesnum-1))
						listtext[tnum][ncol]+="\W523"//+"\W522"506
					endif					
					if((tnum>0)&&	(tnum<tracesnum-1))
						listtext[tnum][ncol]+="\W523"//529"//+"\W522"506
					endif
					if(tnum==tracesnum-1)
						listtext[tnum][ncol]+="\W517"
					endif
					listtitle[ncol]=listcol[0]
					ncol+=1
				endif
				if (listcolselect[1])//color
					listtext[tnum][ncol]="\\JC\\k"+stringbykey("rgb(x)",info,"=")+"\\W509"//\W516"
					listtitle[ncol]=listcol[1]		
					listselect[tnum][ncol]=0	
					ncol+=1
				endif
				if (listcolselect[2])//y wave
					listtext[tnum][ncol]=tracename
					listtitle[ncol]=listcol[2]		
					listselect[tnum][ncol]=6	
					ncol+=1
				endif
				if (listcolselect[3])//x wave
					listtext[tnum][ncol]=stringbykey("XWAVE",info,":")
					listselect[tnum][ncol]=6
					if(strlen(stringbykey("XWAVE",info,":"))==0)
						listtext[tnum][ncol]=""
						listselect[tnum][ncol]=0
					endif			
					listtitle[ncol]=listcol[3]			
					ncol+=1
				endif
				if (listcolselect[4])//y df
					listtext[tnum][ncol]=GetWavesDataFolder(WaveRefIndexed("", tnum, 1 ),1)
					listtitle[ncol]=listcol[4]			
					ncol+=1
				endif
				if (listcolselect[5])//x df
					if(waveexists(XWaveRefFromTrace("",tracename)))
						listtext[tnum][ncol]=GetWavesDataFolder(XWaveRefFromTrace("",tracename),1)
					else
						listtext[tnum][ncol]=""
					endif
					listtitle[ncol]=listcol[5]			
					ncol+=1
				endif		
				if (listcolselect[6])//error
					st=stringbykey("ERRORBARS",info,":",";")
					st=replacestring("ERRORBARS ",st,"")
					st=replacestring(tracename+" ",st,"")

					variable del=strsearch(st,"X",0)
					if(del==-1)
						del=strsearch(st,"Y",0)
					endif
					st=replacestring(st[0,del-1],st,"")					
					listtext[tnum][ncol]=st
					listtitle[ncol]=listcol[6]			
					ncol+=1
				endif
				if (listcolselect[7])//y axis
					listtext[tnum][ncol]=stringbykey("YAXIS",info,":")
					listtitle[ncol]=listcol[7]	
					listselect[tnum][ncol]=6		
					ncol+=1
				endif	
				if (listcolselect[8])//x axis
					listtext[tnum][ncol]=stringbykey("XAXIS",info,":")
					listtitle[ncol]=listcol[8]		
					listselect[tnum][ncol]=6	
					ncol+=1
				endif							
			endfor
		else //no top plot
			colnum=sum(listcolselect)	
			make/o/n=(0,colnum) listselect=0
			make/o/t/n=(0,colnum) listtext
			make/o/t/n=(colnum) listtitle
		endif
	endif
	setdatafolder DF	
end

//executes edit of selected wave
function editwaves(listselect,row)
	wave listselect
	variable row
	string wavey=GetWavesDataFolder(WaveRefIndexed("", row, 1 ),2)
	string tracename=stringfromlist(row,TraceNameList("", ";", 1 ))
	if(waveexists(XWaveRefFromTrace("",tracename)))
		string wavex=GetWavesDataFolder(XWaveRefFromTrace("",tracename),2)
		edit/k=1 $wavey,$wavex
	else
		edit/k=1 $wavey
	endif
	string ERR=stringbykey("ERRORBARS",traceinfo("",tracename,0),":")
	//,(traceinfo("",tracename,0))
//	
	if(strlen(ERR)>0)
		
		variable del=strsearch(ERR,"(",strlen(ERR),1)
		
		ERR=replacestring(ERR[0,del],ERR,"")
		ERR=removeending(ERR)
		del=strsearch(ERR,",",0)
		string PERR=ERR[0,del-1],NERR=ERR[del+1,strlen(ERR)-1]
		if(strlen(PERR)>0)
			appendtotable $PERR
		endif
		if(strlen(NERR)>0)
			appendtotable $NERR
		endif		
		//print ERR[0,del-1]
		//print stringfromlist(0,EBdata("ywave",ERR),",")
	endif
//		st=replacestring("wave",st,"ywave",0,1)	
//		
//		
//	else
//		CheckBox ERROR_SHADE value= 0,win=graphcontrol
//		del=strsearch(st,"X",0)
//		if(del==-1)
//			del=strsearch(st,"Y",0)
//		endif
//		st=replacestring(st[0,del-1],st,"")
//	
//		if (stringmatch(st,"XY*"))
//			st=replacestring(",wave",st,";xwave",0,1)	
//			st=replacestring(",wave",st,";ywave",0,1)	
//		else
//			if (stringmatch(st,"Y*"))
//				st=replacestring(",wave",st,";ywave",0,1)	
//			else			
//				st=replacestring(",wave",st,";xwave",0,1)	
//			endif
//		endif
//	endif
//
//	yp=stringfromlist(0,EBdata("ywave",st),",")
//	yn=stringfromlist(1,EBdata("ywave",st),",")
end

function/s fixDOTwaves(wavestr)
	string wavestr
	string dfstr,wavest
	variable findwavestart
	if(stringmatch(wavestr,"*.*"))
		findwavestart=strsearch(wavestr,":",strlen(wavestr)-1,1)		
		dfstr=wavestr[0,findwavestart]
		wavest=wavestr[findwavestart+1,strlen(wavestr)-1]
		return dfstr+"'"+wavest+"'"
	else
		return wavestr
	endif
end

//opens a dialog to replace the selected wave
function replacewavedialog(tracename,y0x1)
	string tracename
	variable y0x1
	string DF=getdatafolder(1)
	setdatafolder root:DFselect:	
	svar wavesel,savedDF	
	if(strlen(wavesel))
		if(y0x1==0)
			replacewave trace=$(tracename),$fixDOTwaves(wavesel)
			print "replacewave trace="+(tracename)+","+fixDOTwaves(wavesel)
		else
			replacewave/X trace=$(tracename),$fixDOTwaves(wavesel)
			print "replacewave/X trace="+(tracename)+","+fixDOTwaves(wavesel)

		endif
	endif
	
	updatetracelist(0)
	setdatafolder DF	
end



//the graphs are now lnked to graphcontrol panel
function GraphControlHook(s)
	STRUCT WMWinHookStruct &s
	dowindow GraphControl

	if (v_flag)
		controlinfo/w=GraphControl PLOT_LINK
		if(strlen(S_userdata))
			if (s.eventcode==6)
				updateplotparams()
			endif
			if ((s.eventcode==0)||(s.eventcode==2)||(s.eventcode==8))//||(s.eventcode==15)||(s.eventcode==16))
				//0-activate;2-kill;8-change;hide-15;unhide-16
				execute/p/q "updatetracelist("+num2str(s.eventcode)+")"
				execute/p/q "updatetracecontrols(-1)"
			endif
		endif
	endif
End

//events that happen when graphcontrol panel is activated or resized
function GraphControlPanelHook(s)
	STRUCT WMWinHookStruct &s
	controlinfo/w=GraphControl PLOT_LINK
	if(strlen(S_userdata))
	
		if ((s.eventcode==0)&&(strlen(winname(0,1+2+4+16+128+4096))))//activate
			if (WinType(winname(0,1+2+4+16+128+4096) )==1)
				getwindow $winname(0,1) hook(newgraphcontrol)
				updatetracelist(0)
				//print S_value
				if(strlen(S_value)==0)	
					execute "updatetracecontrols(-1)"							
				endif	

			endif
		endif
	endif

		if ((s.eventcode==6))//resize
			getwindow GraphControl wsize
			if(V_bottom-V_top<200)
				MoveWindow /w=GraphControl V_left,V_top,V_right,V_top+200
				getwindow GraphControl wsize
			endif
			getwindow GraphControl wsizeDC
			ListBox PLOTLIST size={V_right-V_left-5,V_bottom-V_top-180}
		endif
	//endif
End

//finds the user selected trace
function gettracenumber(number)
	variable number	//if -1 searches for the first selected row
	variable tnum,found
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	wave listselect
	if(number==-1)
		found=0
		for (tnum=0;tnum<dimsize(listselect,0);tnum+=1)
			if ((listselect[tnum][0])&&(found==0))
				found=1
				number=tnum
			endif
		endfor	
	endif
	setdatafolder DF	
	return number	//row number or -1 if none was selected
end
	
//changes the trace controls on graphcontrol panel accordingly to selected trace
function updatetracecontrols(number)
	variable number
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	string/g enablelist="",disablelist=""
	string info="",tracename
	variable found,tnum,i
	setdatafolder DF
	number=gettracenumber(number)
	dowindow GraphControl
	if(v_flag==1)
		enablelist=ControlNameList("GraphControl", ";", "TRACE*")+ControlNameList("GraphControl", ";", "ERROR*")//ControlNameList("GraphControl", ";", "*")//+ControlNameList("GraphControl", ";", "ERROR*")
		if(number==-1)
			disablelist=ControlNameList("GraphControl", ";", "TRACE*")+ControlNameList("GraphControl", ";", "ERROR*")+"PLOT_LINK;"
		endif

		if(number>=0) //trace selected
			tracename=stringfromlist(number,TraceNameList("", ";", 1 ))
			info =traceinfo("",tracename,0)		
					//print info

			UpdateControl("popupmenu", "TRACE_MODE","mode",numberbykey("mode(x)",info,"=")+1,"","GraphControl" , "")
			UpdateControl("popupmenu", "TRACE_FILLTYPEplus","mode",numberbykey("hbFill(x)",info,"=")+1,"","GraphControl" , "")
			UpdateControl("popupmenu", "TRACE_FILLTYPEneg","mode",numberbykey("hBarNegFill(x)",info,"=")+1,"","GraphControl" , "")
			UpdateControl("popupmenu", "TRACE_LINE","mode",numberbykey("lstyle(x)",info,"=")+1,"","GraphControl" , "")
			UpdateControl("popupmenu", "TRACE_MARKER","mode",numberbykey("marker(x)",info,"=")+1,"","GraphControl" , "")
			UpdateControl("popupmenu", "TRACE_MARKERCOLSTROKE","popcolor",nan,stringbykey("mrkStrokeRGB(x)",info,"="),"GraphControl" , "")
			UpdateControl("popupmenu", "TRACE_COLFILLplus","popcolor",nan,stringbykey("plusRGB(x)",info,"="),"GraphControl" , "")
			UpdateControl("popupmenu", "TRACE_COLFILLneg","popcolor",nan,stringbykey("negRGB(x)",info,"="),"GraphControl" , "")
			UpdateControl("SetVariable", "TRACE_LINESIZE","value",numberbykey("lsize(x)",info,"="),"","GraphControl" , "_NUM:")
			UpdateControl("SetVariable", "TRACE_MARKERSIZE","value",numberbykey("msize(x)",info,"="),"","GraphControl" , "_NUM:")
			UpdateControl("SetVariable", "TRACE_MARKERTHICK","value",numberbykey("mrkThick(x)",info,"="),"","GraphControl" , "_NUM:")
			variable alpha=1
			string colRGB=stringbykey("rgb(x)",info,"=")
			if( itemsinlist(stringbykey("rgb(x)",info,"="),",")==4)
				colRGB=removeending (removelistitem(3,colRGB,","))+")"
				alpha=str2num(stringfromlist(3,stringbykey("rgb(x)",info,"="),","))/((2^16))				
			endif
			
			UpdateControl("popupmenu", "TRACE_COL","popcolor",nan,colRGB,"GraphControl" , "")			
			UpdateControl("SetVariable", "TRACE_TRANS","value",alpha,"","GraphControl" , "_NUM:")
			UpdateControl("CheckBox", "TRACE_MARKERSTROKE","value",numberbykey("useMrkStrokeRGB(x)",info,"="),"","GraphControl","")
			UpdateControl("CheckBox", "TRACE_MARKEROPAQUE","value",numberbykey("opaque(x)",info,"="),"","GraphControl","")
			UpdateControl("CheckBox", "TRACE_FILLCOLORplus","value",numberbykey("usePlusRGB(x)",info,"="),"","GraphControl","")
			UpdateControl("CheckBox", "TRACE_FILLCOLORneg","value",numberbykey("usenegRGB(x)",info,"="),"","GraphControl","")

			readEB(info,stringfromlist(number,TraceNameList("", ";", 1 )),1)
			controlinfo/w=GraphControl TRACE_MODE 
			if((V_value!=6)&&(V_value!=8))
				disablelist+=ControlNameList("GraphControl", ";", "*fill*")
			else
				//disablelist+=ControlNameList("GraphControl", ";", "trace_trans*")			
			endif
			if((V_value<4)||(V_value>5))
				disablelist+=ControlNameList("GraphControl", ";", "*MARKER*") 
			endif
			UpdateControl("popupmenu", "PLOT_AXIS_LEFT","mode",whichlistitem(stringbykey("YAXIS",info,":"),getaxistype(0))+1,"","GraphControl" , "")
			UpdateControl("popupmenu", "PLOT_AXIS_BOTTOM","mode",whichlistitem(stringbykey("XAXIS",info,":"),getaxistype(1))+1,"","GraphControl" , "")
			updateplotparams()
		else	//no trace selected
			controlinfo/w=graphcontrol PLOT_AXIS_LEFT
			if(v_value>0)//there are axes
				if(stringmatch(s_value,stringfromlist(0,getaxistype(0)))==0)
					popupmenu PLOT_AXIS_LEFT mode=1,win= graphcontrol 	
				endif
				controlinfo/w=graphcontrol PLOT_AXIS_BOTTOM
				if(stringmatch(s_value,stringfromlist(0,getaxistype(1)))==0)
					popupmenu PLOT_AXIS_BOTTOM mode=1,win= graphcontrol 
				endif
				UpdateControl("popupmenu", "PLOT_AXIS_LEFT","mode",1,"","GraphControl" , "")
				UpdateControl("popupmenu", "PLOT_AXIS_BOTTOM","mode",1,"","GraphControl" , "")
			endif
		endif
		
		for(i=0;i<itemsinlist(enablelist);i+=1)	//disable controls not in use
			variable dis=(WhichListItem( stringfromlist(i,enablelist), disablelist)>-1)
			controlinfo /w=GraphControl  $stringfromlist(i,enablelist)
			if(dis!=v_disable)
				modifycontrollist stringfromlist(i,enablelist) disable=dis,win=GraphControl 
			endif
		endfor
	endif
	setdatafolder DF
end

//update of the axis and plot controls
function updateplotparams()
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:		
	svar axisleft,axisbottom
	variable updatelabel=0,vmin,vmax
	string labelname
	if(strlen(winname(0,1))>0 )
		getwindow $winname(0,1) gsize
		variable left=v_left,right=v_right,top=v_top,bottom=v_bottom
		getwindow $winname(0,1) psize
		left+=v_left;right-=v_right;top+=v_top;bottom-=v_bottom
		UpdateControl("SetVariable", "PLOT_LEFT","value",round(left),"","GraphControl","_NUM:")
		UpdateControl("SetVariable", "PLOT_RIGHT","value",round(right),"","GraphControl","_NUM:")
		UpdateControl("SetVariable", "PLOT_TOP","value",round(top),"","GraphControl","_NUM:")
		UpdateControl("SetVariable", "PLOT_BOTTOM","value",round(bottom),"","GraphControl","_NUM:")
		UpdateControl("SetVariable", "PLOT_SIZEH","value",round(v_right-v_left),"","GraphControl","_NUM:")
		UpdateControl("SetVariable", "PLOT_SIZEV","value",round(v_bottom-v_top),"","GraphControl","_NUM:")

		
		controlinfo/w=GraphControl PLOT_AXIS_BOTTOM
		getaxis/w=$winname(0,1)/q $S_value
		labelname=S_value
		updatelabel+=((stringmatch(s_value,AxisLabel(winname(0,1),labelname))==0))
		UpdateControl("SetVariable", "PLOT_BOTTOM_MIN","value",(V_min),"","GraphControl","_NUM:")
		UpdateControl("SetVariable", "PLOT_BOTTOM_MIN","width",round(strlen(num2str(V_min))*4+27),"","GraphControl","")
		UpdateControl("SetVariable", "PLOT_BOTTOM_MAX","value",(V_max),"","GraphControl","_NUM:")
		UpdateControl("SetVariable", "PLOT_BOTTOM_MAX","width",round(strlen(num2str(V_max))*4+27),"","GraphControl","")
		UpdateControl("SetVariable", "PLOT_BOTTOM_LABEL","value",nan,"\""+AxisLabel(winname(0,1),labelname)+"\"","GraphControl","_str:")
		UpdateControl("checkbox", "PLOT_BOTTOM_MODE_LINEAR","value",numberbykey("log(x)",axisinfo("",s_value),"=")==0,"","GraphControl","")
		UpdateControl("checkbox", "PLOT_BOTTOM_MODE_LOG","value",numberbykey("log(x)",axisinfo("",s_value),"=")==1,"","GraphControl","")
		UpdateControl("checkbox", "PLOT_BOTTOM_MODE_LOG2","value",numberbykey("log(x)",axisinfo("",s_value),"=")==2,"","GraphControl","")
		if(stringmatch(axisbottom,AxisLabel(winname(0,1),labelname))==0)
		 	axisbottom=AxisLabel(winname(0,1),labelname)
		endif

		CheckBox TRANS_HIDE_BOTTOM ,win=GraphControl,value=((numberbykey("nticks(x)",axisinfo("",s_value),"=")+numberbykey("axThick(x)",axisinfo("",s_value),"="))==0)

		controlinfo/w=GraphControl PLOT_AXIS_LEFT
		getaxis/w=$winname(0,1)/q $S_value
		labelname=S_value	


		updatelabel+=((stringmatch(s_value,AxisLabel(winname(0,1),labelname))==0))

		UpdateControl("SetVariable", "PLOT_LEFT_MIN","value",(V_min),"","GraphControl","_NUM:")
		UpdateControl("SetVariable", "PLOT_LEFT_MIN","width",round(strlen(num2str(V_min))*4+27),"","GraphControl","")
		UpdateControl("SetVariable", "PLOT_LEFT_MAX","value",(V_max),"","GraphControl","_NUM:")
		UpdateControl("SetVariable", "PLOT_LEFT_MAX","width",round(strlen(num2str(V_max))*4+27),"","GraphControl","")
		UpdateControl("SetVariable", "PLOT_LEFT_LABEL","value",nan,"\""+AxisLabel(winname(0,1),labelname)+"\"","GraphControl","_str:")
		UpdateControl("checkbox", "PLOT_LEFT_MODE_LINEAR","value",numberbykey("log(x)",axisinfo("",s_value),"=")==0,"","GraphControl","")
		UpdateControl("checkbox", "PLOT_LEFT_MODE_LOG","value",numberbykey("log(x)",axisinfo("",s_value),"=")==1,"","GraphControl","")
		UpdateControl("checkbox", "PLOT_LEFT_MODE_LOG2","value",numberbykey("log(x)",axisinfo("",s_value),"=")==2,"","GraphControl","")
		CheckBox TRANS_HIDE_LEFT ,win=GraphControl,value=((numberbykey("nticks(x)",axisinfo("",s_value),"=")+numberbykey("axThick(x)",axisinfo("",s_value),"="))==0)

		if(stringmatch(axisleft,AxisLabel(winname(0,1),labelname))==0)
		 	axisleft=AxisLabel(winname(0,1),labelname)
		endif	

	endif
	setdatafolder DF
end

//determines if controls needs updating- used to prevent flicker
function UpdateControl(ctrl,name,keyword,var,str,win ,modstr)
	string ctrl,name,keyword,str,win,modstr
	variable var
	dowindow GraphControl
	if(v_flag)
		if((stringmatch(keyword,"width")))
			controlinfo/w=$win $name
			if(v_width!=var)
				execute ctrl+" "+name+",size={"+modstr+num2str(var)+","+num2str(v_height)+"},win="+win
			endif
		else	
			if(numtype(var)==0) //numeric
				controlinfo/w=$win $name
				if(v_value!=var)
					execute ctrl+" "+name+","+keyword+"="+modstr+num2str(var)+",win="+win
				endif
			else	
				if(strlen(str))
						//string
					controlinfo/w=$win $name					
					if(stringmatch(replacestring("\"",str,""),s_value)==0)
						execute ctrl+" "+name+","+keyword+"="+modstr+""+str+",win="+win
					endif
				endif
			endif
		endif
	endif
end






//--------------------error bars functions----------------------//
function/s EBdata(type,help)
	string type,help
	help=stringbykey(type,help,"=",";")
	help=replacestring("(",help,"")
	help=replacestring(")",help,"")	
	return help
end	

//update error bars according to selected trace
function readEB(info,tracename,docapbar)
	string info,tracename
	variable docapbar
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:		
	svar disablelist
	setdatafolder DF
	string st,yp="",yn="",xp="",xn="",help=""
	st=stringbykey("ERRORBARS",info,":",";")
	st=replacestring("ERRORBARS",st,"")	

	if(docapbar)
		if(numtype(numberbykey("/T",st,"="))==0)
			UpdateControl("SetVariable", "ERROR_CAPH","value",numberbykey("/T",st,"="),"","GraphControl","_Num:")
		endif
		if(numtype(numberbykey("/Y",st,"="))==0)
			UpdateControl("SetVariable", "ERROR_CAPW","value",numberbykey("/Y",st,"="),"","GraphControl","_Num:")
		endif
		if(numtype(numberbykey("/L",st,"="))==0)
			UpdateControl("SetVariable", "ERROR_BAR","value",numberbykey("/L",st,"="),"","GraphControl","_Num:")
		endif
	endif
	variable alpha=1
	string EBcolor=stringfromlist(2,st,",")+","+stringfromlist(3,st,",")+","+stringfromlist(4,st,",")
	if((stringmatch(stringfromlist(4,st,","),"*)*")==0)&&(stringmatch(st,"*SHADE*")>0))
		EBcolor+=")"//","+stringfromlist(5,st,",")
		alpha=str2num(removeending(stringfromlist(5,st,",")))/(2^16)
	endif
	if((stringmatch(st,"*SHADE*")==0))
		disablelist+= "TRACE_TRANS_SHADE;TRACE_SHADE_EB;" 
	endif
	SetVariable TRACE_TRANS_SHADE win=graphcontrol,value= _NUM:alpha
	 
	st=replacestring(tracename+" ",st,"")
	if(stringmatch(st,"*shade*"))
		CheckBox ERROR_SHADE value= 1,win=graphcontrol
		variable del=strsearch(st,"wave",0)
		st=replacestring(st[0,del-1],st,"")
		st=replacestring("wave",st,"ywave",0,1)	
		disablelist+="ERROR_CAPW;"
		disablelist+="ERROR_CAPH;"
		disablelist+="ERROR_BAR;"
		UpdateControl("popupmenu", "TRACE_SHADE_EB","popColor",nan,EBcolor,"GraphControl" , "")
		
		
	else
		CheckBox ERROR_SHADE value= 0,win=graphcontrol
		del=strsearch(st,"X",0)
		if(del==-1)
			del=strsearch(st,"Y",0)
		endif
		st=replacestring(st[0,del-1],st,"")
	
		if (stringmatch(st,"XY*"))
			st=replacestring(",wave",st,";xwave",0,1)	
			st=replacestring(",wave",st,";ywave",0,1)	
		else
			if (stringmatch(st,"Y*"))
				st=replacestring(",wave",st,";ywave",0,1)	
			else			
				st=replacestring(",wave",st,";xwave",0,1)	
			endif
		endif
	endif

	yp=stringfromlist(0,EBdata("ywave",st),",")
	yn=stringfromlist(1,EBdata("ywave",st),",")
//print st,yp,yn
	CheckBox ERROR_YP_CHECK value=(strlen(yp)>0),win=graphcontrol
	CheckBox ERROR_YN_CHECK value=(strlen(yn)>0),win=graphcontrol

	
	xp=stringfromlist(0,EBdata("xwave",st),",")
	xn=stringfromlist(1,EBdata("xwave",st),",")
	UpdateControl("SetVariable", "ERROR_YP","value",nan,"\""+yp+"\"","GraphControl","_STR:")
	UpdateControl("SetVariable", "ERROR_YN","value",nan,"\""+yn+"\"","GraphControl","_STR:")
	UpdateControl("SetVariable", "ERROR_XP","value",nan,"\""+xp+"\"","GraphControl","_STR:")
	UpdateControl("SetVariable", "ERROR_XN","value",nan,"\""+xn+"\"","GraphControl","_STR:")
	UpdateControl("CheckBox", "ERROR_XP_CHECK","value",0,"","GraphControl","")
	UpdateControl("CheckBox", "ERROR_XN_CHECK","value",1,"","GraphControl","")
	//if(strlen(stringbykey("XWAVE",info,":",";"))==0)
		disablelist+="ERROR_XP;"
		disablelist+="ERROR_XN;"
		disablelist+="ERROR_XP_CHECK;"
		disablelist+="ERROR_XN_CHECK;"
		disablelist+="ERROR_X;"
	//endif	
	setdatafolder DF
end

//reads the error bar information to controls
function writeEB(controlname,docapbar)
	string controlname
	variable docapbar
	
	setdatafolder root:DFselect:	
	svar wavesel,savedDF
	setdatafolder root:graphcontrol:	
	wave listselect
	variable tnum,tracesnum=1
	setdatafolder savedDF
	if(strlen(controlname))
		SetVariable $replacestring("_CHECK",controlname,"") win=graphcontrol,value= _STR:wavesel
	endif
	string st="",yp="",yn="",xp="",xn="",xwaves="",ywaves="",cap="",bar="",shade=""
	controlinfo/w=graphcontrol ERROR_YP
	yp=s_value	
	controlinfo/w=graphcontrol ERROR_YN
	yn=s_value
	if(stringmatch(controlname,"error_yp_check"))
		yn=yp
	endif

	controlinfo/w=graphcontrol ERROR_SHADE
	if ((v_value)&&((strlen(yp)||(strlen(yn)))))//shade
		controlinfo/w=graphcontrol TRACE_TRANS_SHADE
		variable alpha=v_value
		controlinfo/w=graphcontrol TRACE_SHADE_EB
		if((alpha<1)&&(itemsinlist(s_value,",")<=3))
			s_value= removeending(addlistitem(num2str(alpha*(2^16)),removeending(s_value),",",3))+")"
		endif
		shade=" shade = {0,0,"+s_value+",(0,0,0,0)} "
		st=" wave=( "+yp+","+yn+")"
	else
		controlinfo/w=graphcontrol ERROR_XP
		xp=s_value
		controlinfo/w=graphcontrol ERROR_XN
		xn=s_value
		controlinfo/w=graphcontrol ERROR_CAPH
		cap="/T="+num2str(v_value)	
		controlinfo/w=graphcontrol ERROR_CAPW
		cap+="/Y="+num2str(v_value)	
		controlinfo/w=graphcontrol ERROR_BAR
		bar="/L="+num2str(v_value)
		if((strlen(xp)||(strlen(xn)))&&(V_disable==0))
			st="X"
			xwaves=", wave=( "+xp+","+xn+")"
		endif
		if(strlen(yp)||(strlen(yn)))
			st+="Y"
			ywaves=", wave=( "+yp+","+yn+")"
		endif
		st+=xwaves+ywaves
		if(strlen(st)==0)
			st="OFF"
		endif
	endif


	for (tnum=0;tnum<dimsize(listselect,0);tnum+=1)
		if (listselect[tnum][0])
			execute "errorbars "+cap+bar+" "+stringfromlist(tnum,TraceNameList("", ";", 1 ))+shade+" "+st
			print "errorbars "+cap+bar+" "+stringfromlist(tnum,TraceNameList("", ";", 1 ))+shade+" "+st
		endif
	endfor	
	readEB(traceinfo("",stringfromlist(gettracenumber(-1),TraceNameList("", ";", 1 ))	,0),stringfromlist(gettracenumber(-1),TraceNameList("", ";", 1 )),docapbar)	

End

//*************************************************************CONTROLS*********************************************//
Function TRACE_PARAMS(ctrlName,popNum,popStr) : PopupMenuControl
	String ctrlName
	Variable popNum
	String popStr
	changetraceparams(ctrlName,popNum,popStr)
	//execute /p/q "updatetracecontrols(-1)"
	//execute /p/q "updatetracelist(8)"
	
End
Function TRACE_CHECK(ctrlName,checked) : CheckBoxControl
	String ctrlName
	Variable checked
	changetraceparams(ctrlName,checked,"")
End
Function TRACE_VAR(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName
	changetraceparams(ctrlName,varNum,varStr)
End

//updates the selected traces according to the selected control
function changetraceparams(ctrlName,Num,Str)
	String ctrlName
	Variable Num
	String Str
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:
	variable tnum
	wave listselect
	variable r,g,b

	for (tnum=0;tnum<dimsize(listselect,0);tnum+=1)
		if (listselect[tnum][0])
			string tracename=stringfromlist(tnum,TraceNameList("", ";", 1 ))	
			if (stringmatch(ctrlName,"*mode"))//mode style
				execute/p "ModifyGraph mode(" +tracename+")="+num2str(Num-1)
				execute/p/q "updatetracecontrols(-1)"
				///			
			endif
			if (stringmatch(ctrlName,"*col"))//color
				//execute/p "ModifyGraph rgb("+tracename+")="+Str
				r=str2num(replacestring("(",stringfromlist(0,Str,","),""))
				g=str2num(stringfromlist(1,Str,","))
				b=str2num(stringfromlist(2,Str,","))
				controlinfo/w=graphcontrol TRACE_TRANS
				execute/p "ModifyGraph rgb("+tracename+")=("+num2str(r)+","+num2str(g)+","+num2str(b)+","+num2str(v_value*(2^16-1))+")"
			endif	
			if (stringmatch(ctrlName,"*trans"))//color
				r=str2num(replacestring("(",stringfromlist(0,stringbykey("rgb(x)",traceinfo("",tracename,0)	,"="),","),""))
				g=str2num(stringfromlist(1,stringbykey("rgb(x)",traceinfo("",tracename,0)	,"="),","))
				b=str2num(stringfromlist(2,stringbykey("rgb(x)",traceinfo("",tracename,0)	,"="),","))
				execute/p "ModifyGraph rgb("+tracename+")=("+num2str(r)+","+num2str(g)+","+num2str(b)+","+num2str(num*(2^16-1))+")"
			endif	
			if (stringmatch(ctrlName,"*marker"))//marker type
				execute/p "ModifyGraph marker(" +tracename+")="+num2str(Num-1)			
			endif		
			if (stringmatch(ctrlName,"*filltypeplus"))//fill type+
				execute/p "ModifyGraph hbFill(" +tracename+")="+num2str(Num-1)			
			endif
			if (stringmatch(ctrlName,"*filltypeneg"))//fill type-
				execute/p "ModifyGraph useNegPat(" +tracename+")="+num2str(Num>1)			
				execute/p "ModifyGraph hBarNegFill(" +tracename+")="+num2str(Num-2)			
			endif			
			if (stringmatch(ctrlName,"*fillcolorplus"))//fill color check
				execute/p "ModifyGraph usePlusRGB(" +tracename+")="+num2str(Num)			
			endif
			if (stringmatch(ctrlName,"*fillcolorneg"))//fill color check
				execute/p "ModifyGraph usenegRGB(" +tracename+")="+num2str(Num)			
			endif
			if (stringmatch(ctrlName,"*colfillplus"))//fill color 
				execute/p "ModifyGraph plusRGB("+tracename+")="+Str
				CheckBox TRACE_FILLCOLORplus value=1,win=GraphControl
				execute/p "ModifyGraph usePlusRGB(" +tracename+")=1"		
			endif													
			if (stringmatch(ctrlName,"*colfillneg"))//fill color 
				execute/p "ModifyGraph negRGB("+tracename+")="+Str
				CheckBox TRACE_FILLCOLORneg value=1,win=GraphControl
				execute/p "ModifyGraph usenegRGB(" +tracename+")=1"		
			endif													
			if (stringmatch(ctrlName,"*line"))//linestyle
				execute/p "ModifyGraph lstyle(" +tracename+")="+num2str(Num-1)			
			endif	
			if (stringmatch(ctrlName,"*linesize"))//line size
				execute/p "ModifyGraph lsize(" +tracename+")="+num2str(Num)			
			endif				
			if(stringmatch(ctrlName,"*MARKERSIZE"))//mode style
				execute/p "ModifyGraph msize(" +tracename+")="+num2str(Num)			
			endif
			if (stringmatch(ctrlName,"*thick"))//stroke thick style
				execute/p "ModifyGraph mrkThick(" +tracename+")="+num2str(Num)			
			endif	
			if (stringmatch(ctrlName,"*COLSTROKE"))//stroke color style
				ModifyGraph useMrkStrokeRGB($tracename)=1
				execute/p "ModifyGraph mrkStrokeRGB("+tracename+")="+Str
				CheckBox TRACE_MARKERSTROKE value=1,win=GraphControl
			endif	
			if (stringmatch(ctrlName,"*STROKE"))//stroke
				execute/p "ModifyGraph useMrkStrokeRGB(" +tracename+")="+num2str(Num)			
			endif	
			if (stringmatch(ctrlName,"*opaque"))//stroke
				execute/p "ModifyGraph opaque(" +tracename+")="+num2str(Num)			
			endif																			
		endif
	endfor
	setdatafolder DF		
end

//removes selected trace(s)
Function TRACEREMOVE(ctrlName) : ButtonControl
	String ctrlName
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	variable	tnum,i
	wave listselect
	//svar recreation
	string st=""
	for (tnum=0;tnum<dimsize(listselect,0);tnum+=1)
		if (listselect[tnum][0])
			st+=stringfromlist(tnum,TraceNameList("", ";", 1 ))+","
		endif
	endfor
	execute "removefromgraph "+removeending(st)
	
	updatetracelist(0)
	setdatafolder DF
End

//adds a new trace
Function TRACEAPPEND(ctrlName) : ButtonControl
	String ctrlName	
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	variable	found=0,tnum
	setdatafolder DF
	DFdialog(DF,"appendtographdialog()",1,-1,1,1)
	updatetracelist(0)
	setdatafolder DF
End

//opens a dialog to select a wave
function appendtographdialog()
	string DF=getdatafolder(1)
	setdatafolder root:DFselect:
	svar wavesel
	string dfstr,wavest
	//if(strlen(wavesel))
	variable i,findwavestart=0
	for (i=0;i<itemsinlist(wavesel);i+=1)
		//if(stringmatch(stringfromlist(i,wavesel),"*.*"))
		//	findwavestart=strsearch(stringfromlist(i,wavesel),":",100,1)		
		//	dfstr=stringfromlist(i,wavesel)[0,findwavestart]
		//	wavest=stringfromlist(i,wavesel)[findwavestart+1,strlen(stringfromlist(i,wavesel))-1]
		//	appendtograph $dfstr+"'"+wavest+"'"
		//else
			appendtograph $fixDOTwaves(stringfromlist(i,wavesel))
		//endif
	endfor
	//endif
	updatetracelist(0)
	setdatafolder DF
end

//copies the trace appearance information
Function INFOCOPY(ctrlName) : ButtonControl
	String ctrlName
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	variable	found=0,tnum
	wave listselect
	
	for (tnum=0;tnum<dimsize(listselect,0);tnum+=1)
		if ((listselect[tnum][0])&&(found==0))
			string tracename=stringfromlist(tnum,TraceNameList("", ";", 1 ))
			string info=traceinfo("",tracename,0)
			found=1
			//print tracename
			string/g recreation=replacestring("RECREATION:",info[strsearch(info,"RECREATION",0),strlen(info)-1],"")
			if(stringmatch(info,"*errorbars:errorbars*"))
			//print info
				recreation+=info[strsearch(info,"ERRORBARS:ErrorBars",0),strsearch(info,tracename,strsearch(info,"ERRORBARS:ErrorBars",0))-1]
				if(stringmatch(info,"*shade*"))
					recreation+=info[strsearch(info,"SHADE=",0),strsearch(info,"}",strsearch(info,"SHADE=",0))]
				endif
			//	recreation+=" " +getdatafolder(1)
			endif
			//print recreation
		endif
	endfor
	setdatafolder DF
End

//pastes trace info saved before
Function INFOPASTE(ctrlName) : ButtonControl
	String ctrlName
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	variable	tnum,i
	wave listselect
	svar recreation
//	nvar transrecreation
	string st
	for (tnum=0;tnum<dimsize(listselect,0);tnum+=1)
		if (listselect[tnum][0])
			string tracename=stringfromlist(tnum,TraceNameList("", ";", 1 ))
			for(i=0;i<itemsinlist(recreation,";");i+=1)
	//print recreation
				if(stringmatch(stringfromlist(i,recreation),"*errorbars:errorbars*"))//check that  error bars are present
					if(stringmatch(traceinfo("",tracename,0),"*errorbars:errorbars*"))
						string ErrorOriginal=traceinfo("",tracename,0)
						ErrorOriginal=ErrorOriginal[strsearch(ErrorOriginal,":ErrorBars",0)+1,strsearch(ErrorOriginal,";RECREATION",strsearch(ErrorOriginal,"ERRORBARS:ErrorBars",0))-1]
						string EWaveOriginal=ErrorOriginal[strsearch(ErrorOriginal,"wave=(",0),strsearch(ErrorOriginal,")",strsearch(ErrorOriginal,"wave=(",0))]
						if(stringmatch(stringfromlist(i,recreation),"*shade*"))//check that shaded error bars are present
							execute  "ErrorBars "+tracename+replacestring("ERRORBARS:ErrorBars",stringfromlist(i,recreation)," ")+" "+EWaveOriginal
						else
							execute  "ErrorBars "+replacestring("ERRORBARS:ErrorBars",stringfromlist(i,recreation)," ")+" "+tracename+" Y,"+EWaveOriginal
						
						endif
					endif
				else
					if(stringmatch(stringfromlist(i,recreation),"*(x)*"))
						execute "ModifyGraph "+replacestring("(x)",stringfromlist(i,recreation),"("+tracename+")")		
					endif
				endif
			endfor
			execute "updatetracecontrols("+num2str(tnum)+")"
		endif
	endfor
	
	setdatafolder DF
	//execute/p/q "updatetracecontrols(-1)"
	//execute/p/q "updatetracelist(0)"
End

//copies trace  for other graphs
Function TRACECOPY(ctrlName) : ButtonControl
	String ctrlName
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	variable	tnum
	wave listselect
	make/o/t/n=0 tracecopyrecreation ,tracecopyY
	//make/o/n=0 tracetranscopy
	for (tnum=0;tnum<dimsize(listselect,0);tnum+=1)
		if (listselect[tnum][0])
			string tracename = stringfromlist(tnum,TraceNameList("", ";", 1 ))
			insertpoints 0,1,tracecopyrecreation,tracecopyY//,tracetranscopy
			tracecopyrecreation[0]="NAME:"+tracename+";"+traceinfo("",tracename,0)
			tracecopyY[0]=GetWavesDataFolder(WaveRefIndexed("", tnum, 1 ),2)
		endif
	endfor
	setdatafolder DF
End

//paste the selected traces, used to duplicate traces to the same or other plots
function pastetrace(laxisname,baxisname)
	string laxisname,baxisname
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	wave/t  tracecopyrecreation ,tracecopyY
	wave tracetranscopy,listselect
	variable	tnum,location=itemsinlist(TraceNameList("", ";", 1 )),i
	string recreation,laxis,baxis,tracename="",newtrace
	for (tnum=0;tnum<dimsize(listselect,0);tnum+=1)
		if(listselect[tnum][0]==1)
			location=tnum
			tracename=stringfromlist(tnum,tracenamelist("",";",1))
		endif
	endfor
	for (tnum=numpnts(tracecopyY)-1;tnum>=0;tnum-=1)
		location+=1
		if(strlen(laxisname)==0)
			laxisname=stringbykey("YAXIS",tracecopyrecreation[tnum],":")
		endif
		if (stringmatch(laxisname,"*right*"))
			laxis="/R="+laxisname
		else
			laxis="/L="+laxisname
		endif
		if(strlen(baxisname)==0)
			baxisname=stringbykey("XAXIS",tracecopyrecreation[tnum],":")
		endif		
		if (stringmatch(baxisname,"*top*"))
			baxis="/T="+baxisname
		else
			baxis="/B="+baxisname
		endif		
		if(strlen(stringbykey("XWAVE",tracecopyrecreation[tnum],":")))
			execute "appendtograph "+laxis+baxis+" "+ tracecopyY[tnum]+" vs "+(stringbykey("XWAVEDF",tracecopyrecreation[tnum],":"))+(stringbykey("XWAVE",tracecopyrecreation[tnum],":"))
		else
			execute "appendtograph "+laxis+baxis +" "+ tracecopyY[tnum]
		endif
		doupdate
		string newtracename=stringfromlist(itemsinlist(TraceNameList("", ";", 1 ))-1,TraceNameList("", ";", 1 ))

		updatetracelist(0)
		recreation=tracecopyrecreation[tnum]
		//print newtracename
		//print recreation
		recreation=replacestring("RECREATION:",recreation[strsearch(recreation,"RECREATION",0),strlen(recreation)-1],"")
		for(i=0;i<itemsinlist(recreation,";");i+=1)
			//execute "ModifyGraph "+replacestring("(x)",stringfromlist(i,recreation),"("+stringfromlist(location-1,TraceNameList("", ";", 1 ))+")")		
			if(stringmatch(stringfromlist(i,recreation),"*(x)*"))
				execute "ModifyGraph "+replacestring("(x)",stringfromlist(i,recreation),"("+newtracename+")")		
			endif
		endfor
		recreation=StringByKey("ERRORBARS",  tracecopyrecreation[tnum])//tracecopyrecreation[tnum]
		//execute recreation
				

		tracename=StringByKey("NAME",  tracecopyrecreation[tnum])
		execute replacestring(tracename,recreation,newtracename,0,1)

	endfor	
	updatetracelist(0)		
	execute/p/q "updatetracecontrols(-1)"
	execute/p/q "updatetracelist(0)"

	setdatafolder DF
end

//pastes traces saved before
Function TRACE_PASTE(ctrlName) : ButtonControl
	String ctrlName
	pastetrace("","")
End




//update of the plot and axis parameters
Function PLOTSIZE(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName
	variable minval,maxval
	string side="print 0" ,st
	if(stringmatch(ctrlName,"*left*"))
		side="ModifyGraph/w="+winname(0,1)+" margin(left)="+varstr
		side="ModifyGraph margin(left)="+varstr
	endif
	if(stringmatch(ctrlName,"*top*"))
		side="ModifyGraph/w="+winname(0,1)+" margin(top)="+varstr
		side="ModifyGraph margin(top)="+varstr
	endif
	if(stringmatch(ctrlName,"*bottom*"))
		side="ModifyGraph/w="+winname(0,1)+" margin(bottom)="+varstr
		side="ModifyGraph margin(bottom)="+varstr
	endif
	if(stringmatch(ctrlName,"*right*"))
		side="ModifyGraph/w="+winname(0,1)+" margin(right)="+varstr
		side="ModifyGraph margin(right)="+varstr
	endif	
	if(stringmatch(ctrlName,"*sizev"))
		side="ModifyGraph/w="+winname(0,1)+" height="+varstr
		side="ModifyGraph height="+varstr
	endif		
	if(stringmatch(ctrlName,"*sizeh"))
		side="ModifyGraph/w="+winname(0,1)+" width="+varstr
		side="ModifyGraph width="+varstr
	endif		
	if(stringmatch(ctrlName,"*bottom_max*"))
		controlinfo/w=GraphControl PLOT_AXIS_BOTTOM
		getaxis/w=$winname(0,1)/q $S_value
		side="SetAxis  /w="+winname(0,1)+" "+S_value+" "+num2str(V_min)+" ,"+varstr
		side="SetAxis "+S_value+" "+num2str(V_min)+" ,"+varstr
	endif
	if(stringmatch(ctrlName,"*bottom_min*"))
		controlinfo/w=GraphControl PLOT_AXIS_BOTTOM
		getaxis/w=$winname(0,1)/q $S_value
		side="SetAxis  /w="+winname(0,1)+" "+S_value+" "+varstr+","+num2str(V_max)
		side="SetAxis "+S_value+" "+varstr+","+num2str(V_max)
	endif	
	if(stringmatch(ctrlName,"*left_max*"))
		controlinfo/w=GraphControl PLOT_AXIS_LEFT
		getaxis/w=$winname(0,1)/q $S_value
		side="SetAxis  /w="+winname(0,1)+" "+S_value+" "+num2str(V_min)+" ,"+varstr
		side="SetAxis "+S_value+" "+num2str(V_min)+" ,"+varstr
	endif
	if(stringmatch(ctrlName,"*left_min*"))
		controlinfo/w=GraphControl PLOT_AXIS_LEFT
		getaxis/w=$winname(0,1)/q $S_value
		side="SetAxis  /w="+winname(0,1)+" "+S_value+" "+varstr+","+num2str(V_max)
		side="SetAxis  "+S_value+" "+varstr+","+num2str(V_max)
	endif	
		
	if (strlen(winname(0,1)))
		execute side
		print side	//user can then use the command window to duplicate commands
		updateplotparams()		
	endif
End

//selection of an axis
Function PLOTAXISSEL(ctrlName,popNum,popStr) : PopupMenuControl
	String ctrlName
	Variable popNum
	String popStr
	updateplotparams()
End

//selects the vertical or the horizontal axes
function/s getaxistype(left0bottom1)
	variable left0bottom1
	variable i
	string result=""
	for(i=0;i<itemsinlist(axislist(winname(0,1)));i+=1)
		if((stringmatch( stringbykey("AXTYPE",AxisInfo(winname(0,1), stringfromlist(i,axislist(winname(0,1)))) ,":"),"*left*")) ||(stringmatch( stringbykey("AXTYPE",AxisInfo(winname(0,1), stringfromlist(i,axislist(winname(0,1)))) ,":"),"*right*")))
			if((left0bottom1==0)&&(stringmatch(stringfromlist(i,axislist(winname(0,1))),"*limage*")==0))
				result+=stringfromlist(i,axislist(winname(0,1)))+";"
			endif
		endif
		if((stringmatch( stringbykey("AXTYPE",AxisInfo(winname(0,1), stringfromlist(i,axislist(winname(0,1)))) ,":"),"*bottom*")) ||(stringmatch( stringbykey("AXTYPE",AxisInfo(winname(0,1), stringfromlist(i,axislist(winname(0,1)))) ,":"),"*top*")))
			if((left0bottom1==1)&&(stringmatch(stringfromlist(i,axislist(winname(0,1))),"*bimage*")==0))
				result+=stringfromlist(i,axislist(winname(0,1)))+";"
			endif
		endif
	endfor
	return result
end

function adderrorbar(ctrlName,checked,tnum)
	String ctrlName
	Variable checked,tnum
	controlinfo/w=graphcontrol $replacestring("_CHECK",ctrlName,"")
	string info =traceinfo("",stringfromlist(tnum,TraceNameList("", ";", 1 ))	,0)	
	info=stringbykey("ERRORBARS",info,":",";")
end


Function TRACE_TRANS_SHADE(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName
	ERRORBARS_CHECK("shade",1)
End

Function TRACE_SHADE_EBpopup(ctrlName,popNum,popStr) : PopupMenuControl
	String ctrlName
	Variable popNum
	String popStr
	ERRORBARS_CHECK("shade",1)
End
//opens a dialog for new error bars
Function ERRORBARS_CHECK(ctrlName,checked) : CheckBoxControl
	String ctrlName
	Variable checked
	if(gettracenumber(-1)>=0)
		if( (stringmatch(ctrlName,"*link") )||(stringmatch(ctrlName,"*shade*")))			
			execute /p/q "writeEB(\"\",0)"
			execute /p/q "updatetracecontrols(-1)"
		else
			string DF=getdatafolder(1)
			setdatafolder root:graphcontrol:			
			controlinfo/w=graphcontrol $replacestring("_CHECK",ctrlName,"")
			string DFnew=""
			if (strsearch(s_value,":",1))
			 	DFnew=s_value[0,strsearch(s_value,":",1)]
			endif
			DFnew= GetWavesDataFolder(WaveRefIndexed("", gettracenumber(-1),1),1)
			setdatafolder DF
			DFdialog(DFnew,"writeEB(\""+ctrlName+"\",1)",1,numpnts(WaveRefIndexed("", gettracenumber(-1),1)),1,0)
		endif
	endif
end	

//updates error bars
Function ERR_VISUAL(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName
	writeEB("",0)
End

//copies the plot and axis information
Function PLOTINFOCOPY(ctrlName) : ButtonControl
	String ctrlName
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	make/o/n=6 plotval
	make/t/o/n=(0,3) axesval
	variable i
	for (i=0;i<itemsinlist(AxisList("" ));i+=1)
		insertpoints/m=0 0,1, axesval
		axesval[0][0]=stringfromlist(i,axislist(""))
		axesval[0][1]=AxisInfo("", axesval[0][0])
		axesval[0][2]=AxisLabelText(winname(0,1),axesval[0][0])
	endfor	
	controlinfo /w=GraphControl PLOT_LEFT
	plotval[0]=v_value
	controlinfo /w=GraphControl PLOT_RIGHT
	plotval[1]=v_value
	controlinfo /w=GraphControl PLOT_TOP
	plotval[2]=v_value
	controlinfo /w=GraphControl PLOT_BOTTOM
	plotval[3]=v_value
	controlinfo /w=GraphControl PLOT_SIZEH
	plotval[4]=v_value
	controlinfo /w=GraphControl PLOT_SIZEV
	plotval[5]=v_value		
	setdatafolder DF
End

//paste plot and axis information
Function PLOTINFOPASTE(ctrlName) : ButtonControl
	String ctrlName
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:	
	wave plotval
	wave/t  axesval	
	variable i,items
	for (i=0;i<dimsize(axesval,0);i+=1)	
		if (whichlistitem(axesval[i][0],AxisList("" ))>=0)//axis exists
			execute stringbykey("SETAXISCMD", axesval[i][1],":")
			string info=axesval[i][1]
			string recreation=replacestring("RECREATION:",info[strsearch(info,"RECREATION",0),strlen(info)-1],"")
			for (items=0;items<itemsinlist(recreation);items+=1)
				execute "ModifyGraph "+ReplaceString("(x)",stringfromlist(items,recreation),"("+axesval[i][0]+")",1)	
			endfor	
			execute /p "label /w="+winname(0,1)+" " + axesval[i][0]+" \""+ replacestring("\\", axesval[i][2],"\\")+"\""
		endif
	endfor
	ModifyGraph/w=$winname(0,1) margin(left)=plotval[0],margin(right)=plotval[1],margin(top)=plotval[2],margin(bottom)=plotval[3],width=plotval[4],height=plotval[5]
	setdatafolder DF
End

//changes plot label
Function PLOT_LABEL(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName
	if(stringmatch(ctrlName,"*bottom*"))
		controlinfo/w=GraphControl PLOT_AXIS_BOTTOM
	else
		controlinfo/w=GraphControl PLOT_AXIS_LEFT
	endif
	getaxis/w=$winname(0,1)/q $S_value	
 	label $S_value varStr 
End

//selects a new axis mode -linear,log,log2
Function PLOTAXISMODE(ctrlName,checked) : CheckBoxControl
	String ctrlName
	Variable checked
	
	string axname="BOTTOM"
	controlinfo/w=GraphControl PLOT_AXIS_BOTTOM
	if(stringmatch(ctrlName,"*left*"))
		axname="LEFT"
		controlinfo/w=GraphControl PLOT_AXIS_LEFT
		CheckBox PLOT_LEFT_MODE_LINEAR value=0,win=GraphControl
		CheckBox PLOT_LEFT_MODE_LOG value=0,win=GraphControl
		CheckBox PLOT_LEFT_MODE_LOG2 value=0,win=GraphControl
		CheckBox $ctrlName value=1,win=GraphControl
	else
		CheckBox PLOT_BOTTOM_MODE_LINEAR value=0,win=GraphControl
		CheckBox PLOT_BOTTOM_MODE_LOG value=0,win=GraphControl
		CheckBox PLOT_BOTTOM_MODE_LOG2 value=0,win=GraphControl
		CheckBox $ctrlName value=1,win=GraphControl		
	endif
	if(stringmatch(ctrlName,"*linear*"))
		execute/p "ModifyGraph log("+s_value+")=0"
	endif
	if(stringmatch(ctrlName,"*log"))
		execute/p "ModifyGraph log("+s_value+")=1"
	endif
	if(stringmatch(ctrlName,"*log2"))
		execute/p "ModifyGraph log("+s_value+")=2"
	endif
End

Function AUTOAXIS(ctrlName) : ButtonControl
	String ctrlName
	if((stringmatch(ctrlName,"*left*")))
		controlinfo/w=GraphControl PLOT_AXIS_LEFT
	else
		controlinfo/w=GraphControl PLOT_AXIS_BOTTOM
	endif
	getaxis/w=$winname(0,1)/q $S_value
	if((stringmatch(ctrlName,"*auto_min*")))
		execute/p "setaxis "+S_value+" *,"+num2str(v_max)
	endif
	if((stringmatch(ctrlName,"*auto_max")))
		setaxis $S_value v_min,*
		execute/p "setaxis "+S_value+" "+num2str(v_min)+",*"
	endif
	execute/p/q "updateplotparams()"
End

//unshows or shows the selected axis
Function AXISHIDE(ctrlName,checked) : CheckBoxControl
	String ctrlName
	Variable checked
	if((stringmatch(ctrlName,"*left*")))
		controlinfo/w=GraphControl PLOT_AXIS_LEFT
	else
		controlinfo/w=GraphControl PLOT_AXIS_BOTTOM
	endif
	if(checked)
		execute/p "ModifyGraph nticks("+S_value+")=0,axThick("+S_value+")=0"
	else
		execute/p "ModifyGraph nticks("+S_value+")=2,axThick("+S_value+")=1"
	endif
End

//find the label of the axis
Function/S AxisLabel(graphName, axisName, [SuppressEscaping])
	String graphName, axisName
	Variable SuppressEscaping
	
	if (ParamIsDefault(SuppressEscaping))
		SuppressEscaping = 0
	endif
	
	String axisLabelST=""
	String info= WinRecreation(graphName,04)
	Variable start= strsearch(info, "Label "+axisName+" ", 0)
	if( start >= 0 )
		start = strsearch(info, "\"", start)+1
		Variable theEnd= strsearch(info, "\"", start)-1
		axisLabelST= info[start,theEnd]
	endif
	if (SuppressEscaping)
		start = 0
		do
			start = strsearch(axisLabelST, "\\\\", start)	// search for double backslash
			if (start >= 0)
				string newLabel = axisLabelST[0,start-1]
				newLabel += axisLabelST[start+1, strlen(axisLabelST)-1]
				axisLabelST = newLabel
			else
				break
			endif
		while(1)
	endif
	return axisLabelST
End

//user selection on tracelist listbox
Function TRACELIST(LB_Struct) : ListBoxControl
	STRUCT WMListboxAction &LB_Struct
	Variable row=LB_Struct.row
	Variable col=LB_Struct.col
	Variable event=LB_Struct.eventcode	
	
	string DF=getdatafolder(1)
	setdatafolder root:graphcontrol:
	wave listcolselect,listselect 
	wave/t listcol	,listtext,listtitle
	wave/wave ywaveref,xwaveref

	variable i,tnum,found
	variable/g selectedrow
	//wave selectrows

	if ((event==1)&&(row>=-1))//mouse down, used for reorder	,replace waves

		if(row<0)//header
			if(LB_Struct.eventMod==17)//right mouse click
				string listdata="\\M1"
				for(i=0;i<numpnts(listcol);i+=1)
					listdata+=listcol[i]
					if(listcolselect[i])
						listdata+="!"+ num2char(18)
					endif
					listdata+=";\\M1"
				endfor
				PopupContextualMenu listdata
				if(V_flag>0)
					listcolselect[V_flag-1]=1-listcolselect[V_flag-1]
					execute/p/q "updatetracelist(0)"
				endif
			else //left mouse click
				listselect=floor(listselect/2)*2+1-mod(listselect,2)
			endif
		elseif (row<dimsize(listtext,0))	//main body
		
	
			selectedrow=-1
			if(LB_Struct.eventMod==17)//right mouse click,replace
				if(stringmatch(listtitle[col],"Y axis"))
					PopupContextualMenu getaxistype(0)

					tracecopy("")
					traceremove("")
					pastetrace(stringfromlist(V_flag-1,getaxistype(0)),"")
				endif
				if(stringmatch(listtitle[col],"X axis"))
					PopupContextualMenu getaxistype(1)
					tracecopy("")
					traceremove("")
					if(row<dimsize(listselect,0))
					//	listselect[row][0]=floor(listselect[row][0]/2)*2+1
					endif
					pastetrace("",stringfromlist(V_flag-1,getaxistype(1)))
				endif
				if(stringmatch(listtitle[col],"Y wave"))
					PopupContextualMenu "Edit;Replace"
					if(V_flag==1)
						editwaves(listselect,row)
					endif
					if(V_flag==2)
						DFdialog(DF,"replacewavedialog(\""+listtext[row][col]+"\",0)",1,-1,1,0)
						
					endif
				endif
				if(stringmatch(listtitle[col],"X wave"))
					PopupContextualMenu "Edit;Replace;Remove"
					if(V_flag==1)
						editwaves(listselect,row)
					endif
					if((V_flag==2))
						DFdialog(DF,"replacewavedialog(\""+stringfromlist(row,TraceNameList("", ";", 1 ))+"\",1)",1,numpnts(WaveRefIndexed("", row, 1)),1,0)
						
					endif
					if((V_flag==3))
						execute "ReplaceWave/w="+winname(0,1)+"/X trace="+stringfromlist(row,TraceNameList("", ";", 1 ))+", $\"\" "
						updatetracelist(0)
					endif
				endif
				if(stringmatch(listtitle[col],"* DF"))
					PopupContextualMenu "Set DF"
					execute /p "setdatafolder "+listtext[row][col]
				endif
			else	

			endif
		endif
	endif
	variable mousev
	if (event==2)//mouse up
		if(row>=0)
	
			if(stringmatch(listtitle[col],"Pos"))
//print row,dimsize(listselect,0)
				if(row<dimsize(listselect,0)-1)
					ReorderTraces /w=$winname(0,1) _front_, {$stringfromlist(row,TraceNameList("", ";", 1 ))}
				else
				//print "g"
					ReorderTraces /w=$winname(0,1) _back_,{$stringfromlist(row,TraceNameList("", ";", 1 ))}
				endif
				execute /p/q "updatetracelist(8)"
			endif
			execute /p/q "updatetracecontrols(-1)"
		endif
	endif	

	if ((event==12))//&&(listselect[row][col]==6))//double click
		if(row==43)//add
			TRACEAPPEND("")
		endif
		if((row==127)||(row==43))//delete
			TRACEREMOVE("")
		endif
	endif
	string newwave
	if (event==7)//finish edit double click
		if(stringmatch(listtitle[col],"Y axis"))	
			string axisname=listtext[row][col]
			tracecopy("")
			traceremove("")
			if(row<dimsize(listselect,0))
				listselect[row][0]=floor(listselect[row][0]/2)*2+1
			endif
			pastetrace(axisname,"")
		endif
		if(stringmatch(listtitle[col],"X axis"))	
			axisname=listtext[row][col]
			tracecopy("")
			traceremove("")
			if(row<dimsize(listselect,0))
				listselect[row][0]=floor(listselect[row][0]/2)*2+1
			endif
			pastetrace("",axisname)
		endif		
		if(stringmatch(listtitle[col],"Y wave"))						
			newwave=GetWavesDataFolder(WaveRefIndexed("", row, 1 ),1)+listtext[row][col]
			if(exists(newwave))
				listtext[row][col]=stringfromlist(row,TraceNameList("", ";", 1 ))
			else
				rename $GetWavesDataFolder(WaveRefIndexed("", row, 1 ),2),$listtext[row][col]
			endif	
			updatetracelist(0)	
		endif
		if(stringmatch(listtitle[col],"X wave"))						
			newwave=GetWavesDataFolder(XWaveRefFromTrace("",stringfromlist(row,TraceNameList("", ";", 1 )) ),1)+listtext[row][col]
			if(exists(newwave))
				listtext[row][col]=nameofwave(XWaveRefFromTrace("",stringfromlist(row,TraceNameList("", ";", 1 ))))
			else
				rename $GetWavesDataFolder(XWaveRefFromTrace("",stringfromlist(row,TraceNameList("", ";", 1 ))),2),$listtext[row][col]
			endif	
			updatetracelist(0)	
		endif		
	endif
	setdatafolder DF
	return 0
End


//=============================data folder wave selector===========================//
//=============================data folder wave selector===========================//
//=============================data folder wave selector===========================//
//=============================data folder wave selector===========================//

//opens the selection dialog window
function DFdialog(newDF,stcommand,ndim1,npoint1,wtype1,multiple)
	variable ndim1,npoint1,wtype1,multiple //filter waves by the number of dimensions / points /type (1 num, 2-txt)-1-accept all; multiple-allow multiple selection
	string newDF,stcommand//the datafolder of the requested wave selection
	//the execution command when the user clicks on ok
	if(strlen(newDF)==0)
		newDF="root:"
	endif
	setdatafolder newDF
	string DF=getdatafolder(1)
	newdatafolder/o/s root:DFselect
	string/g savedDF=DF
	string/g wavesel=""
	string/g command=stcommand
	variable/g ndim=ndim1	//1-only 1d waves
	variable/g npoint=npoint1
	variable/g wtype=wtype1
	make/o/n=(1,2) DFselect=0
	make/o/t/n=(1,2) DFname=""
	DFname[0][1]="_None_"	
	setdatafolder DF		
	dowindow/k DataFolderDialog
	//getmouse -can be used on igor 6.3
	GetWindow/z kwFrameOuter wsizeDC
	variable left=v_left,top=v_top
	GetWindow/z kwTopWin wsizeOuter
	v_left+=left+100
	v_top+=top+100
	newpanel/n=DataFolderDialog/FLT=1/k=1/W=(v_left,v_top,v_left+400,v_top+330)as "Select a wave"
	//newpanel/n=DataFolderDialog/FLT=1/k=1/W=(100,100,100+300,100+330) as "Select a wave"
	ListBox DFselect,pos={2,28},size={250,300},proc=DFSELECTListBoxProc
	ListBox DFselect,labelBack=(56576,56576,56576)
	ListBox DFselect,appearance={native,Win},listWave=root:DFselect:DFname
	ListBox DFselect,selWave=root:DFselect:DFselect,mode= 6+multiple*4,widths={11,60}
	PopupMenu DFparents,pos={2,5},size={250,21},bodyWidth=250,proc=DFselctecPopMenuProc
	PopupMenu DFparents,mode=2,popvalue="graphcontrol",value= #"replacestring(\":\",getdatafolder(1),\";\")"
	Button DFOK,pos={260,300},size={60,25},proc=DFOK,title="OK"
	Button DFcancel,pos={326,300},size={60,25},title="Cancel",proc=DFcancel
	Display/W=(257,6,392,288)/HOST=# /N=waveplay
	setwindow DataFolderDialog hook(resize)=DataFolderDialoghook
	ModifyPanel/w=DataFolderDialog fixedSize=0	
	SetActiveSubwindow _endfloat_
	wavesinDF()
end

//hook to resize
Function DataFolderDialoghook(s)
	STRUCT WMWinHookStruct &s
	if(s.eventcode==6)//resize
		getwindow DataFolderDialog wsize
		if(V_bottom-V_top<100)
			getwindow DataFolderDialog wsize
			MoveWindow /w=DataFolderDialog V_left,V_top,V_right,V_top+100					
		endif	
		getwindow DataFolderDialog wsizeDC		
		ListBox DFselect size={150,V_bottom-30},win=DataFolderDialog
		Button DFOK,pos={160,V_bottom-30},win=DataFolderDialog
		Button DFcancel,pos={226,V_bottom-30},win=DataFolderDialog
		MovesubWindow /w=DataFolderDialog#waveplay fnum=(157,6,292,V_bottom-42)							
	endif
end

//gets the wave names in current datafolder
Function wavesinDF()
	string DF=getdatafolder(1)
	setdatafolder root:DFselect:
	make/o/n=(1,2) DFselect=0
	make/o/t/n=(1,2) DFname=""
	DFname[0][1]="_None_"

	nvar ndim,npoint,wtype	//modifiers ndim-number of dimentions,npoint-number of points,wtype-type of wave
	setdatafolder DF
	if(itemsinlist(getdatafolder(1),":")>1)
		DFname[0][0]="\\W547"	//can go up
	endif		
	variable numDF=CountObjects("", 4 )
	variable numwave=CountObjects("", 1 )
	variable wnum
	string waveref
	for(wnum=0;wnum<numDF;wnum+=1)
		insertpoints/m=0 dimsize(DFname,0),1, DFname,DFselect
		DFname[dimsize(DFname,0)-1][1]= GetIndexedObjName("", 4, wnum)
		DFname[dimsize(DFname,0)-1][0]= ""
		DFselect[dimsize(DFname,0)-1][0]=64		
	endfor
	for(wnum=0;wnum<numwave;wnum+=1)
		waveref=GetIndexedObjName("", 1, wnum)
		if((WaveType($waveref,1)==wtype )||(wtype==-1))
			if ((ndim==-1)||(WaveDims($waveref)==ndim))
				if((numpnts($waveref)==npoint)||(npoint==-1))
					insertpoints/m=0 dimsize(DFname,0),1, DFname,DFselect
					DFname[dimsize(DFname,0)-1][1]= waveref
					DFname[dimsize(DFname,0)-1][0]= ""
				endif
			endif
		endif
	endfor
	PopupMenu DFparents mode=itemsinlist(getdatafolder(1),":"),win=DataFolderDialog	
	DFselectok(0,"")
End

//events that occur when user click the listbox
Function DFSELECTListBoxProc(ctrlName,row,col,event) : ListBoxControl
	String ctrlName
	Variable row
	Variable col
	Variable event	
	string DF=getdatafolder(1)
	setdatafolder root:DFselect:
	wave DFselect
	wave/t  DFname
	variable i
	setdatafolder DF	
	if((event<8)&&(row<dimsize(DFselect,0)))
		if((col==0)&&(row==0)&&(event>0))//go up one level
			DFselect[][]=0
			if(itemsinlist(getdatafolder(1),":")>1)
				setdatafolder ::
			endif
			wavesinDF()
		endif
		if((col==0)&&(row>0)&&(event>0))
			DFselect[][1]=0
			DFselect[row][0]=floor(DFselect[row][0]/2)*2
			DFselect[row][1]=1
		endif
		if((event==2)&&(DFselect[row][col]==80))
			setdatafolder DFname[row][1]
			DFselect[row][1]=0
			wavesinDF()		
		endif
		if((event==3)&&(DFselect[row][0]>0))//double click
			setdatafolder DFname[row][1]
			DFselect[0][1]=0
			wavesinDF()
		endif	
		if(row<dimsize(DFselect,0))
			DFselectok(((DFselect[row][0]==0)&&(DFselect[row][1]>0)),DFname[row][1] )
		endif
	endif
	return 0
End

//can ok button be visible, based on user selection
function DFselectok(ok,trace)
	variable ok
	string trace
	variable i	
	Button DFOK,win=DataFolderDialog, disable=2
	for(i=0;i<itemsinlist(tracenamelist("DataFolderDialog#waveplay",";",1));i+=1)
		removefromgraph/z/w=DataFolderDialog#waveplay $stringfromlist(0,tracenamelist("DataFolderDialog#waveplay",";",1))
	endfor
	if((ok))
		Button DFOK,win=DataFolderDialog, disable=0
		if (stringmatch(trace,"_None_")==0)
			appendtograph/w=DataFolderDialog#waveplay $trace
			ModifyGraph/w=DataFolderDialog#waveplay rgb=(0,0,0)
		endif
	endif
end	

//data folder selection
Function DFselctecPopMenuProc(ctrlName,popNum,popStr) : PopupMenuControl
	String ctrlName
	Variable popNum
	String popStr
	variable i
	string DFname=""
	for(i=0;i<popnum;i+=1)
		DFname+=stringfromlist(i,getdatafolder(1),":")+":"
	endfor
	setdatafolder DFname
	wavesinDF()
End

//ok button
Function DFOK(ctrlName) : ButtonControl
	String ctrlName
	string DF=getdatafolder(1)
	setdatafolder root:DFselect:
	wave DFselect
	wave/t  DFname
	svar wavesel,command
	svar savedDF
	setdatafolder DF			
	variable i	
	killwindow DataFolderDialog
	wavesel=""		
	for(i=0;i<dimsize(DFselect,0);i+=1)
		if(DFselect[i][1])
			if(strlen(wavesel))
				wavesel+=";"
			endif
			wavesel+=getdatafolder(1)+DFname[i][1]
			if(stringmatch(DFname[i][1],"_none_"))
				wavesel=""
			endif
		endif
	endfor
	execute command
	execute/p/q "updatetracecontrols(-1)"
End

//cancel button
Function DFcancel(ctrlName) : ButtonControl
	String ctrlName
	killwindow DataFolderDialog
	setdatafolder root:DFselect:
	svar wavesel
	svar savedDF
	wavesel=""
	setdatafolder savedDF	
End

Function GraphControlLinktoGraph(ctrlName) : ButtonControl
	String ctrlName
	controlinfo/w=GraphControl $ctrlName
	if(strlen(S_userdata))
		Button PLOT_LINK,win=GraphControl,userdata="",title="Link"
	else
		Button PLOT_LINK,win=GraphControl,userdata="1",title="Unlink"
	endif
End

Function GraphControlDuplicateDF(ctrlName) : ButtonControl
	String ctrlName
	dowindow/F $winname(0,1)
	DoIgorMenu "Edit","Duplicate"
	ReplaceWave allinCDF
End

Function GraphControlEnhance(ctrlName) : ButtonControl
	String ctrlName
	ModifyGraph/w=$winname(0,1) btLen=2
End

Function GraphControlShowPlot(ctrlName) : ButtonControl
	String ctrlName
	dowindow/F $winname(0,1)
	getwindow $winname(0,1) wsizeDC
	movewindow 0,0,V_right-V_left,V_bottom-V_top
End

Function GraphControlLayout(ctrlName) : ButtonControl
	String ctrlName
	AppendLayoutObject/F=0/T=1 graph $winname(0,1)
End