#pragma rtGlobals=1		// Use modern global access method.

////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
//Procedure for analyzing Line Scan data from either an imported TIFF or an LSM file
//Written by Josef G. Trapani (jtrapani@amherst.edu) with input from Dominic (Dick) L. Poccia (dlpoccia@amherst.edu)
//v1.0 October 14, 2011
//v1.1 December, 2012 -- added choice of multiple stats output
//v2.0 February 2013 -- added direct analysis of Tiff images
//v2.1 March 2013 -- added a panel to select multiple options; added ability to load multiple TIFFs or an LSM file (requires LSMreader) from Panel
//v2.2 September 2013 --  Fixed the ImageLoad adding a zero to the wavename "temp.tif0" by using the /C=-1 flag. Now a multi-image tiff will be imported into a 3D wave.
// (the LSMreader.pxp is written by Stephen R Ikeda (download from Igor Exchange: http://www.igorexchange.com/project/LSMreader)
//
//
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
Menu "Macros"
	
	"Line Scan Analysis", start_LS_panel("start")

End

////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
Function start_LS_panel(ctrlName)
	String ctrlName
	String savedDF= GetDataFolder(1)	// Remember DF in a string.

	DoWindow LS_Panel0
	If (V_flag!=0)
		KillWindow LS_Panel0
		SetDataFolder root:Packages:LSVars
		KillVariables /Z /A
		KillStrings /Z /A
		KillWaves /Z /A
		SetDataFolder savedDF			// and restore
		KillDataFolder /Z  root:Packages:LSVars
	Endif

	If (cmpstr(ctrlName,"start")==0)
		NewDataFolder /O root:Packages
		NewDataFolder /O /S root:Packages:LSVars
		Variable /G filenameindex = 1
		Variable /G sampling = 0.1

		SetDataFolder savedDF			// and restore
		LS_Panel(ctrlName)
	Endif

End
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////

Function LS_Panel(ctrlName)
	String ctrlName
	
	String info = IgorInfo(0)
	String screen1RectStr = StringByKey("SCREEN1", info)		//e.g., "DEPTH=23,RECT=0,0,1280,1024"
	Variable depth, left, top, right, bottom
	sscanf screen1RectStr, "DEPTH=%d,RECT=%d,%d,%d,%d", depth, left,top, right, bottom
	
	String platform= UpperStr(igorinfo(2))
	If (cmpstr(platform,"WINDOWS")==0)
		NewPanel /N=LS_Panel0 /W=(left+100,top,left+400,200) /K=2 as "Ls Panel"
	Else	
		NewPanel /N=LS_Panel0 /W=(right-400,top,right-100,200) /K=2 as "Ls Panel"
	Endif
	ModifyPanel /W=LS_Panel0 noEdit=1, fixedSize=1


	SetDrawLayer /W=LS_Panel0 ProgFront
	DrawRRect /W=LS_Panel0 195,125,290,190
	SetDrawEnv fillfgc= (52428,52428,52428)
	DrawRRect /W=LS_Panel0 10,35,290,120
	SetDrawEnv /W=LS_Panel0 fsize= 16, fillbgc=(49151,53155,65535)
	DrawText /W=LS_Panel0 30,65,"Line Scan Analysis"
	SetDrawEnv /W=LS_Panel0 fsize= 12, fillbgc=(49151,53155,65535)

	Button closeLSPanelbutton,pos={230,10},size={60,20},proc=start_LS_panel,title="Close", win=LS_Panel0

	Button openLSimagebutton,pos={10,10},size={80,20},proc=load_LS_image,title="Load tiff(s)", win=LS_Panel0
	
	CheckBox checkLS0 pos={20,175}, title="LSM waves", mode=0, value=0

	DFREF dfr = root:LSMimages		// LSMimages may or may not exist
	If (DataFolderRefStatus(dfr) != 0)
		Button openLSMfilebutton,pos={100,10},size={80,20},proc=alt_readLSM,title="Load LSM", win=LS_Panel0
		CheckBox checkLS0 value=1
	Else
		CheckBox checkLS0 disable=1
	Endif
	
	CheckBox checkLS1 pos={130,130}, title="Baseline",mode=0, value=0
	
	CheckBox checkLS2 pos={130,150}, title="Crop",mode=0, value=0

	CheckBox checkLS3 pos={200,130}, title="Graph",mode=0, value=1
	
	CheckBox checkLS4 pos={200,150}, fsize=8, title="autofit curve",mode=0, value=0

	CheckBox checkLS5 pos={200,170}, fsize=8, title="linear fit",mode=0, value=0
		
	SetVariable setvarLS1,pos={20,150},size={100,100},title="Interval:"
	SetVariable setvarLS1,fSize=10,limits={0,1000,0},value= root:Packages:LSVars:sampling

	PopupMenu popupmenuLS1, pos={20,130}, size={400,20}, bodywidth=0, mode=1,title="Statistic:", value="sdev;avg;sem;rms;min;max;npnts"

	Button LSbutton0, appearance={native,all}, pos={90,80}, size={120,30}, title="Run...", proc=Linescan_stats, fColor=(65535,54607,32768), win=LS_Panel0

End Function

////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
Function alt_readLSM(ctrlName)
	String ctrlName
	Variable refNum = 0
	String cmd
	String fnameStr=""

	Open/D/R/T=".lsm" refNum	// Not a real open - just returns S_fileName
	fnameStr = S_fileName		// S_fileName contains full filename returned from Open
	if (strlen(fnameStr) == 0)
		Print "Canceled in dialog box."
		return(0)
	endif

	Sprintf cmd, "readLSMfile(\"%s\",1)",fnameStr
	Execute cmd	
	
End
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
Function load_LS_image(ctrlName)
	String ctrlName
	String tempname, tempfiles,tempfile, tempstring1
	Variable refnum
	String message = "Select one or more tiff images (*.tif) to load as waves:"

	Open /R/D/T=".tif" /MULT=1 /M=message refnum
	tempfiles = S_fileName

	If (strlen(tempfiles) == 0)
		Abort "No file(s) selected"
	else
		Variable numFilesSelected = ItemsInList(tempfiles, "\r")
		Variable i
		for(i=0; i<numFilesSelected; i+=1)
			tempfile = StringFromList(i, tempfiles, "\r")
	
			//Load Image ***NOTE this will overwrite any waves with the same name!!
			ImageLoad /C=-1 /O /T=TIFF tempfile// To change the basename use:  /N=$("image"+num2str(tempnum))
			If(V_flag==1)	
				tempstring1 = StringFromList(i, S_Wavenames, ";")

				Variable tempnum = strsearch (tempstring1,".",0)
				If (tempnum!=-1&&cmpstr (tempstring1[tempnum+1],"t")==0)
					tempName = removeending (tempstring1, ".tif")
					//If file name begins with a number, the letter "x" will be appended to the beginning of it
					//This avoids problems with displaying graphs and tables, the names of which cannot start with numbers
					If (char2num(tempName[0])<65)
						tempName[0]="x"
					Endif
					KillWaves /Z $tempName
					Rename $tempstring1, $tempName
				ElseIf (char2num(tempName[0])<65)
					tempName = tempstring1
					tempName[0]="x"
					KillWaves $tempName
					Rename $tempstring1, $tempName
				Endif
			Endif
		Endfor	
	Endif
End Function
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
Function Linescan_stats(ctrlName)
	String ctrlName
	Variable i,m,n,z,rval, index
	Variable cropdata, y1, y2
	String currentDF = GetDataFolder(1)	// Save

	String FolderNameList = GetDataFolder(0)+":;"
	String FolderName
	String WaveTemp, LinescanFolder,LinescanWaveName
	String LinescanWaveList=""
	
	DFREF LSvarFolderref = root:Packages:LSVars
	String LSvarFolder = "root:Packages:LSVars:"

	//Check for LSM files
	controlInfo /W=LS_Panel0 checkLS0
	If(V_Value==1)	
		LinescanFolder = "root:LSMimages:"
	Else
		index = 0
		Do
			FolderName = GetIndexedObjName(":", 4, index)
			If (strlen(Foldername) == 0)
				break
			ElseIf  (cmpstr(FolderName,"Packages")!= 0)
				FolderNameList+=Foldername+";"
			Endif
			index += 1
		while(1)
	

		Prompt LinescanFolder, "Select a Line Scan Data Folder:", popup FolderNameList
		DoPrompt "Line Scan Stats Analysis", LinescanFolder
		If (V_flag!=0)
			Abort
		Endif	
	
		If (cmpstr(LinescanFolder,"root:")!=0)		
			LinescanFolder = "root:"+LinescanFolder+":"
		Endif
	
	Endif
	

	index=0
	Do
		WaveTemp = GetIndexedObjName(LinescanFolder, 1, index)
		If  (strlen(WaveTemp) == 0)
			break
		Endif
		LinescanWaveList += WaveTemp+";"
		index += 1
	while(1)

	If  (strlen(LinescanWaveList) == 0)
		Abort "No linescan waves present"
	Endif

	ControlInfo /W=LS_Panel0 popupmenuLS1
	String tempStat = S_Value
	
	Prompt LinescanWaveName, "Wave:", popup LinescanWaveList
	DoPrompt "Data Analysis", LinescanWaveName
	
	If (V_flag==0)
		Variable tempStatnum
		WAVE /Z /C lsWave = $(LinescanFolder+LinescanWaveName)
		If (Waveexists (lsWave)!=1)
			Abort "No Linescan file loaded!"
		Endif
	
		SetDataFolder LSvarFolder ///change to the folder for storing analysis waves, variables, and strings****************
		NVAR /z tempnum = LSvarFolderref:filenameindex
		If (NVAR_exists(tempnum))
			tempnum=tempnum+1
		Else
			tempnum = 1
		Endif
	
		String tempname=LinescanWaveName+"_"+num2str(tempnum)
		NVAR tempscale1 = root:Packages:LSVars:sampling

	
		Variable numRows = DimSize (lsWave,0) 
		Variable numCols = DimSize (lsWave,1)
		String tempWave1 = LSvarFolder+tempname
		String tempWave2 = LSvarFolder+tempname+"_coef"
		String tempWave3 = LSvarFolder+tempname+"_display"
		String tempstring4,tempstring5


		String statsWavename = LSvarFolder+ tempname+"_Colstats"
		Make /O /N=(numCols+1) $statsWavename
		WAVE statsWave = $statsWavename

		/////////////////////////////////
		/////////////////////////////////
		//Display the wave to set cursors pairs
		Make /O /N=(numRows) $tempWave3
		Wave displayTemp = $tempWave3
		
		Make /O /N=(numRows) $tempWave2
		Wave W_coefTemp = $tempWave2
		
		
		displayTemp = lsWave[p][0]
		
		//Baseline the data column
		controlInfo /W=LS_Panel0 checkLS1
		If(V_Value==1)
			CurveFit /Q/M=2/W=0 line, displayTemp /D
			Wave coef_Wave = W_coef
			W_coefTemp=coef_Wave[1]*x+coef_Wave[0]
			displayTemp=displayTemp-W_coefTemp
		Endif			
		Display  /W=(200,10,1200,610 )  /K=1 $tempWave3
		ModifyGraph rgb=(0,0,0)

		Label left "Intensity";DelayUpdate
		Label bottom "??"
		SetAxis/A/N=0/E=1 bottom
		SetAxis/A/N=2/E=2 left
		Showinfo
		string topGraph = WinName (0, 1)		// get name of the target graph

		//Crop the data column
		controlInfo /W=LS_Panel0 checkLS2
		If(V_Value==1)	
			Variable numCursorsToAdd=1
			Prompt numCursorsToAdd, "How many cursor pairs?", popup "1;2;3;4"
			DoPrompt "Enter values:", numCursorsToAdd
			If (V_flag==0)	//if cancel clicked on DoPrompt, then skip rest of proc
					
				String cursorNames = "ABCDEFGHIJ"
				Variable numCursors = strlen(cursorNames)
	
				// Check for bad values in numCursors.
				if (numtype(numCursorsToAdd) != 0 || numCursorsToAdd < 0)
					return 0
				elseif (numCursorsToAdd > numCursors)
					numCursorsToAdd = numCursors
				else
					numCursorsToAdd=2*numCursorsToAdd	
				endif
				Variable lsTemp_numpnts = numpnts($tempWave3)	
				lsTemp_numpnts = lsTemp_numpnts/numCursorsToAdd
		
				//Add cursors	
				For (n=0; n<numCursorsToAdd; n+=1)
					Cursor /H=2 /S=1 /C=(65535,0,0) /W=$(topGraph) $(cursorNames[n]) $NameOfWave(tempwave3), (n+1)*lsTemp_numpnts
					tempstring4 = "cursorval_"+cursorNames[n]
					Variable /G $tempstring4= pcsr($(cursorNames[n]))
				EndFor

				//pause for cursor adjust
				rval= specifiedCursorAdjust(topGraph)
				if (rval == -1)							// Graph name error?
					SetDataFolder currentDF
					DoAlert 0,"Graph name error?"
				Elseif (rval == 1)								// User canceled
					
					If (numCursorsToAdd>0) //Delete cursors on Graph
						For (m=0;m<numCursorsToAdd; m+=1)
							Cursor/W=$topGraph /K $(cursorNames[m])
							Killvariables /Z $("cursorval_"+cursorNames[m])
						Endfor
					Endif
					 
				Elseif (rval == 0)								// 

					//Record new cursor locations	
					For (n=0; n<numCursorsToAdd; n+=1)
						tempstring4 = "cursorval_"+cursorNames[n]
						Variable /G $tempstring4= pcsr($(cursorNames[n]))
					EndFor


					//DISPLAY WAVE delete points outside the cursors (B to C etc..)		
					//delete start to first cursor and last cursor to end
					tempstring5 = "cursorval_"+cursorNames[numCursorsToAdd-1]
					NVAR tempvar2=$tempstring5
					DeletePoints tempvar2,(numpnts(displayTemp)-tempvar2), displayTemp
		

					For (n=(numCursorsToAdd-2);n>=1; n-=2)
						tempstring4 = "cursorval_"+cursorNames[n]
						tempstring5 = "cursorval_"+cursorNames[n-1]
						NVAR tempvar1=$tempstring4
						NVAR tempvar2=$tempstring5
						DeletePoints tempvar2,(tempvar1-tempvar2), displayTemp
					Endfor	

					tempstring4 = "cursorval_A"
					NVAR tempvar1=$tempstring4
					DeletePoints 0,tempvar1, displayTemp

					If (numCursorsToAdd>0) //Delete cursors on Graph
						For (m=0;m<numCursorsToAdd; m+=1)
							Cursor/W=$topGraph /K $(cursorNames[m])
						Endfor
					Endif
					cropdata=3 //correct for whether cropping was cancelled
				Endif
			Endif
			/////////////////////////////////
			/////////////////////////////////		

		Endif

		//Extract each column from LS file and run stats on it
		For (i=0;i<=numCols;i+=1)
				
			Make /O /N=(numRows) $tempWave1
			Make /O /N=(numRows) $tempWave2
			Wave lsTemp = $tempWave1
			Wave W_coefTemp = $tempWave2

			lsTemp = lsWave[p][i]
					
					
			If (cropdata==3)
				//delete start to first cursor and last cursor to end
				tempstring5 = "cursorval_"+cursorNames[numCursorsToAdd-1]
				NVAR tempvar2=$tempstring5
				DeletePoints tempvar2,(numpnts(lstemp)-tempvar2), lstemp
		

				//delete points outside the cursors (B to C etc..)		
				For (n=(numCursorsToAdd-2);n>=1; n-=2)
					tempstring4 = "cursorval_"+cursorNames[n]
					tempstring5 = "cursorval_"+cursorNames[n-1]
					NVAR tempvar1=$tempstring4
					NVAR tempvar2=$tempstring5
					DeletePoints tempvar2,(tempvar1-tempvar2), lsTemp
				Endfor	

				tempstring4 = "cursorval_A"
				NVAR tempvar1=$tempstring4
				DeletePoints 0,tempvar1, lstemp


			Endif
			
			//Baseline the data column
			controlInfo /W=LS_Panel0 checkLS1
			If(V_Value==1)
				CurveFit /Q/M=2/W=0 line, lsTemp /D
				Wave coef_Wave = W_coef
				W_coefTemp=coef_Wave[1]*x+coef_Wave[0]
				lsTemp=lsTemp-W_coefTemp
			Endif
			
			//Stats of data column
			WaveStats /Q /C=0 /W lsTemp
			Wave M_WaveStats
			tempStatNum = M_WaveStats[%$tempStat]
			statsWave[i]= tempStatnum
					
			//kill the temp files
			killwaves W_coefTemp
			killwaves lsTemp
		EndFor

		SetScale /P x, 0, tempscale1, " s", $statsWavename


		Edit /N= statsWavetable /W=(350,0,450,500) /Hide=0 /K=1 statsWave//Make new table for accumulating ISI values
 
		controlInfo /W=LS_Panel0 checkLS3
		If(V_Value==1)
			Display  /W=(550,0,1200,400 ) /K=1 statsWave
			ModifyGraph mode=3,marker=19, useMrkStrokeRGB=1, rgb=(52428,52428,52428)
			SetAxis/A/N=1/E=1 bottom
			SetAxis/A/N=1/E=3 left
			Label left tempSTat
			Label bottom "Time"
			string statGraph = WinName (0, 1)		// get name of the target graph

			//Fit a line to the initial part of the plot
			controlInfo /W=LS_Panel0 checkLS5
			If(V_Value==1&&numpnts($statsWavename)>1)	
				y1 = WaveMin ($statsWavename)
				FindValue /V=(y1) $statsWavename
				y1 = pnt2X($statsWavename,V_value)
				y2 = 1.2*y1
				Cursor /H=2 /S=1 /W= $statGraph A, $nameofwave(statsWavename), y1
				Cursor /H=2 /S=1 /W=$ statGraph B, $nameofwave(statsWavename), y2

				topGraph = WinName(0, 1)	// Name of top graph

				rval= specifiedCursorAdjust(topGraph)
				if (rval == -1)							// Graph name error?
					SetDataFolder currentDF
					DoAlert 0,"Graph Name?"
				Elseif (rval == 1)								// User canceled?
					SetDataFolder currentDF
					DoAlert 0,"Fit Canceled"
				Elseif(rval==0)
					CurveFit/NTHR=0/TBOX=768 line $(statsWavename) [pcsr(A),pcsr(B)] /D
					//TextBox/C/N=Line_ChD_ColumnStats/A=RB
					string statsfitName = nameofwave(statsWave)
					Wave statfitWave = $("fit_"+statsfitName)
					ModifyGraph rgb($nameofwave(statfitWave))=(1,16019,65535)
					String newstatFitWave = "linefit_"+statsfitName
					Rename  statfitWave, $newstatFitWave
					
				Endif
			Endif				
				
			//Fit a curve to the plot
			controlInfo /W=LS_Panel0 checkLS4
			If(V_Value==1&&numpnts($statsWavename)>1)	
				y1 = WaveMin ($statsWavename)
				FindValue /V=(y1) $statsWavename
				y1 = 1.3*(pnt2X($statsWavename,V_value))
				y2 = 0.5*(numpnts($statsWavename))
				Cursor /H=2 /S=1 /W= $statGraph C, $nameofwave(statsWavename), y1
				Cursor /H=2 /S=1 /W=$ statGraph D, $nameofwave(statsWavename), y2

				topGraph = WinName(0, 1)	// Name of top graph
				rval= specifiedCursorAdjust(topGraph)
				if (rval == -1)							// Graph name error?
					SetDataFolder currentDF
					DoAlert 0,"Graph Name?"
				Elseif (rval == 1)								// User canceled?
					SetDataFolder currentDF
					DoAlert 0,"Fit Canceled"
				Elseif(rval==0)
					CurveFit/NTHR=0/TBOX=768 exp_XOffset $(statsWavename) [pcsr(C),pcsr(D)] /D 
					//TextBox/C/N=Curve_ChD_ColumnStats/A=RB
				Endif
			Endif
		Endif

		//Could also use this: Duplicate /R=[*][i]

	Endif

	If (cropdata==3)
		For (m=0;m<numCursorsToAdd; m+=1)
			Killvariables /Z $("cursorval_"+cursorNames[m])
		Endfor
	Endif
	SetDataFolder currentDF
	
End



////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
Function specifiedCursorAdjust(graphName)  //Cursor Adjust from WaveMetrics Igor Exchange website
	String graphName
	
	DoWindow/F $graphName			// Bring graph to front
	if (V_Flag == 0)					// Verify that graph exists
		return -1
	endif

	NewDataFolder/O root:tmp_PauseforCursorDF
	Variable /G root:tmp_PauseforCursorDF:canceled
	String /G root:tmp_PauseforCursorDF:graph
	SVAR graph=root:tmp_PauseforCursorDF:graph
	graph=graphName
	NVAR canceled= root:tmp_PauseforCursorDF:canceled
	Variable returncanceled
	
	NewPanel/EXT=0 /N=tmp_PauseforCursor /Host=$graphname /W=(0,0,110,80) as "Paused!"

	DrawText /W=# 10,20,"Adjust cursors..."
	Button button0,win=#, pos={10,30},size={92,20}, fColor=(65535,0,0 ), proc=specCrsrAdjust_ContButtonProc, title="Continue"
	Button button1,win=#, pos={10,50},size={92,20}, proc=specCrsrAdjust_CancelBProc,title="Cancel"
	
	PauseForUser $graphName#tmp_PauseforCursor, $graphName

	returncanceled = canceled			// Copy from global to local before global is killed
	KillDataFolder root:tmp_PauseforCursorDF

	//will return -1 for no graph, 0 for completed, and 1 for cancelled
	return returncanceled
End

Function specCrsrAdjust_ContButtonProc(ctrlName) : ButtonControl
	String ctrlName
	NVAR canceled= root:tmp_PauseforCursorDF:canceled
	SVAR graph= root:tmp_PauseforCursorDF:graph
	
	canceled=0
	KillWindow $graph#tmp_PauseforCursor			// Kill self
End

Function specCrsrAdjust_CancelBProc(ctrlName) : ButtonControl
	String ctrlName
	NVAR canceled= root:tmp_PauseforCursorDF:canceled
	SVAR graph= root:tmp_PauseforCursorDF:graph

	canceled=1
	KillWindow $graph#tmp_PauseforCursor			// Kill self
End
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////////////////////////