// PHI SPE File Loader
// version 2.0
// 2017.12.23
//  jjw

#pragma rtGlobals=3		// Use modern global access method and strict wave access

// constants to parse the header

Static StrConstant sVersion = "SoftwareVersion:*"
Static StrConstant sREX = "SoftwareVersion: [[:alpha:]]+[ ]?[[:alpha:]]?([[:digit:]]+)\.*"
Static StrConstant sNSpectra = "NoSpectralReg"
Static StrConstant sSpecRegDef = "SpectralRegDef"

// main routine
// load PHI SPE files 
// returns name of file loaded

Function/S LoadPHISPEFile()

	DFREF cdf = GetDataFolderDFR()

	// variables and strings

 	variable vFileRef
 	string sFilePath, sDataFolder, sFileName = ""
 	
 	// set the file path
 	// abort if cancelled
 	
 	if (SetPHISPEFilesPath() < 0)
 		return sFileName
 	endif
 	
 	// select a file to load
 
	Open/P=PHISPEFiles/D/R/F="PHI SPE Files (*.spe):.spe;"/M="Select the SPE file to load" vFileRef
	if( StrLen(S_fileName) == 0 )
		return sFileName	//user cancelled file selection
	endif
	sFilePath = S_fileName
	
	// create and move to a datafolder by the file name
	
	sFileName = ParseFilePath(3,SFilePath,":",0,0)
	sDataFolder = CleanUpName(sFileName,0)
 	NewDataFolder/O/S $sDataFolder

	// create the required globals
	
	variable/G nSpectra=0, nVersion=0
	make/D/O/N=4 PHISPEBinaryHeader=0
	make/D/O/T/N=0 PHISPETextHeader, wSpectrumNames
	make/D/O/N=(0,5) PHISPESpectraHeader, wSpectrumScales
	
	// label the spectrum scale dimensions
	
	SetDimLabel 1, 0, npnts, wSpectrumScales
 	SetDimLabel 1, 1, start, wSpectrumScales
 	SetDimLabel 1, 2, step, wSpectrumScales
 	SetDimLabel 1, 3, dwelltime, wSpectrumScales
 	SetDimLabel 1, 4, Ep, wSpectrumScales
	
 	// open the file to load
 	
	Open/R vFileRef as sFilePath
	
	// get and parse the text header
	
	GetPHISPETextHeader(vFileRef)
	ParsePHISPETextHeader()
	
	// get the binary headers
	
	GetPHISPEBinaryHeaders(vFileRef)
	// ParsePHISPESpectraHeader()
	
	// load the spectra
	
	LoadPHISPESpectra(vFileRef)
 
 	// close file, return to current data folder, and exit
 	
	close vFileRef
	
	SetDataFolder cdf
	
	return sFileName
end 

// load each spectrum

Static Function LoadPHISPESpectra(vFileRef)
	variable vFileRef

	// globals
	
	DFREF pdf = GetDataFolderDFR()

	NVAR/SDFR=pdf nSpectra, nVersion
	wave/T/SDFR=pdf wSpectrumNames
	wave/SDFR=pdf wSpectrumScales
	
	// variables and strings
	
	variable ic, npoints, vReadVal
	string sName
	
	// load spectra

	for(ic=0; ic<nSpectra; ic+=1)
	
		// set up
		
		npoints = wSpectrumScales[ic][0]
		sName = wSpectrumNames[ic]
		make/O/N=(npoints) $sName
		wave wSpectrum = $sName
		SetScale/P x, wSpectrumScales[ic][1], wSpectrumScales[ic][2], wSpectrum

		//read spectrum; format is 64 bit float
			
		switch(nVersion)
			case 1:
				FBinRead/B=0/F=5 vFileRef, wSpectrum
				break
			case 2:
				FBinRead vFileRef, wSpectrum
				break
		endswitch
	endfor

	return 0
end

// set the file path for the files
// path is stored in PHISPEFiles
// if it exists already, it is NOT overwritten

Static Function SetPHISPEFilesPath()

	PathInfo/S PHISPEFiles
	
	if (!v_flag)
		NewPath/Q/M="Where are the SPE files?" PHISPEFiles
	endif
	
	return v_flag
end

 // load the text header
 // generates (overwrites) a text wave for the file header
 // returns the file position of the last block read
 
Static Function GetPHISPETextHeader(vFileRef)
	variable vFileRef
	
	// globals
	
	DFREF pdf =  GetDataFolderDFR()
	wave/T PHISPETextHeader
	
	// variables and waves
	
	variable vIndex = 0
	string sLine
	
	// read the text file header
	
	do
		FReadLine vFileRef, sLine
		sLine = RemoveEnding(sLine,"\r")
		if( stringmatch( sLine,"EOFH" ) == 1 )
			break
		endif
		InsertPoints vIndex, 1, PHISPETextHeader
		PHISPETextHeader[vIndex] = sLine
		vIndex += 1
	while(1)
	
	// drop the first line
	
	DeletePoints 0, 1, PHISPETextHeader
	
	// return the current file position
	
	FStatus vFileRef
	return v_filePos
end

// parse the text header
// returns globals

Static Function ParsePHISPETextHeader()

	// globals
	
	DFREF pdf =  GetDataFolderDFR()

	NVAR/SDFR=pdf nSpectra, nVersion
	wave/T/SDFR=pdf PHISPETextHeader, wSpectrumNames
	wave/SDFR=pdf wSpectrumScales
	
	// variables and strings
	
	variable ic, jc=0, nlines, nPos
	string sLine, sRegLabel, stmp //, sRegName, sRegStart, sRegStep, sRegAcqTime
	
	// parse the text header wave
	
	nlines = numpnts(PHISPETextHeader)
	
	// get the software version
	
	for (ic=0;ic<nlines;ic+=1)
		sLine = PHISPETextHeader[ic]
		if (stringmatch(sLine,sVersion)==1)
			SplitString/E=(sREX) sLine, stmp
			nVersion = str2num(stmp)
			nPos = ic + 1
			break
		endif
	endfor

	// read the number of spectra
	
	for (ic=nPos;ic<nlines;ic+=1)
		sLine = PHISPETextHeader[ic]
		if (stringmatch(sLine,(sNSpectra+":*"))==1)
			nSpectra = NumberByKey(sNSpectra,sLine)
			nPos = ic + 1
			break
		endif
	endfor
	
	Redimension/N=(nSpectra) wSpectrumNames
	Redimension/N=(nSpectra,5) wSpectrumScales
	
	// read the region defintion info per spectrum
	// region information contains 13 items separated by spaces ... example below
	// 1 1 SUR 111 2201 -0.500 1100.000 0.000 1100.000 0.000 0.200 187.85 none
	
	make/N=13/FREE/T regionheader
	
	for (ic=nPos;ic<nlines;ic+=1)
		sLine = PHISPETextHeader[ic]
		// check for version 2 first
		if (stringmatch(sLine,(sSpecRegDef+":*"))==1)
			regionheader = StringFromList(p+1,sLine," ")
			wSpectrumNames[jc] = regionheader[2]
			sRegLabel = lowerstr(wSpectrumNames[jc])
			SetDimLabel 0, jc, $sRegLabel, wSpectrumScales
			// points
			wSpectrumScales[jc][0] = round(str2num(regionheader[4]))
			// start (eV)
			wSpectrumScales[jc][1] = round(1000*str2num(regionheader[6]))/1000
			// step (eV)
			wSpectrumScales[jc][2] = round(1000*str2num(regionheader[5]))/1000
			// total acq time (s)
			wSpectrumScales[jc][3] = 60*round(1000*str2num(regionheader[10]))/1000
			// pass energy (eV)
			wSpectrumScales[jc][4] = round(1000*str2num(regionheader[11]))/1000
			jc += 1
//		else
//			nPos = ic + 1
		endif
	endfor
	
	return nlines

end

// get the binary headers

Static Function GetPHISPEBinaryHeaders(vFileRef)
	variable vFileRef

	// globals
	
	DFREF pdf= GetDataFolderDFR()

	NVAR/SDFR=pdf nSpectra
	wave/SDFR=pdf PHISPEBinaryHeader,PHISPESpectraHeader
	
	//each spectrum gets 24 unsigned 4 byte integers
	
	Redimension/N=(24,nSpectra) PHISPESpectraHeader
	 
	//read the binary headers
	
	FBinRead/B=0/F=3/U vFileRef, PHISPEBinaryHeader
	FBinRead/B=0/F=3/U vFileRef, PHISPESpectraHeader
	FStatus vFileRef
	return v_filePos
end

// parse the binary spectra header
// returns globals

Static Function ParsePHISPESpectraHeader()

	// globals
	
	DFREF pdf =  GetDataFolderDFR()
	
	NVAR/SDFR=pdf nSpectra
	wave/SDFR=pdf wSpectrumScales, PHISPESpectraHeader
	
	// get points per spectrum
	
	Redimension/N=(nSpectra,3) wSpectrumScales	
	wSpectrumScales[][0] = PHISPESpectraHeader[5][p]
	
	return 0
end