#pragma rtGlobals=1		// Use modern global access method.
#include "MultiROI"
#include "CustomColor"
#include "SaveTiff"
#include "PopWaveBrowser3"

/////////INSTRUCTIONS////////////////////////////////////////////////////////////////////
 //  1. SARFIA must be installed																			//
 //  2. Threshold the kymograph;																		//
 //  3. If thresholding wasn't performed in SARFIA, run the function MultiROI(binarymask, targetwave) 	//
 //		on the binary mask. Targetwave is a string, which is the name of the resulting wave. Make sure	//
 //		the string contains "ROI". Otherwise skip this step.												//
 //  4. Execute KyCP(), which opens a control panel. Specify the waves containing the kymograph and 		//
 //		the MultiROI mask.																				//
 //  5. The results will be automatically displayed 														//
/////////////////////////////////////////////////////////////////////////////////////////


Function/wave SegregateROIsByLine(ROIwave)
	Wave ROIWave
	
	Variable xDim, nLines, ii, ROICount=0, ROIsFound
	

	xDim=DimSize(ROIWave, 0)
	nLines=DimSize(ROIWave,1)
	
	MatrixOP/o/free w_ROI = Replace(ROIWave,1,NaN)
	Duplicate/o ROIWave, segregatedROIs
	
	For(ii=0;ii<nLines;ii+=1)
		Duplicate/O/free/r=[0,*][ii] w_ROI line

		ROIsFound=MultiROI(line, "line_MR",roicount=ROICount)
		ROICount=ROIsFound
		Wave line_MR
		segregatedROIs[][ii]= line_MR[p]
	
	EndFor
	
	KillWaves line_MR
	Return segregatedROIs
End

////////////////////////////////////////////

Function AutomateKy(image, ROI)
	Wave image, ROI
	
	Variable nROIs, ii, nLines, nCoMs, OffSet, MaxCom = 0
	
	nROIs = abs(WaveMin(ROI))
	nLines=DimSIze(image,1)
	
	Make/o/n=(nLines,nROIs) KyAnal = NaN
	Make/o/n=(nLines,2,nROIs) MetaCoM = NaN
	Duplicate/o/free ROI AnalROI
	
	For(ii=0;ii<nROIs;ii+=1)
	
		MultiThread AnalROI = SelectNumber(ROI[p][q]==-ii-1,1,0)		//Make a ROI wave containing only 1 ROI
		Wave Seg = SegregateROIsByLine(AnalROI)
		CenterOfMass(image, Seg)
		Wave CoM
		nCoMs = DimSize(CoM,0)
		Make/o/d/free/n=(nCoMs-1) xDistance, yDistance
		xDistance = (-CoM[p][0] + CoM[p+1][0])
		yDistance = (-CoM[p][1] + CoM[p+1][1])
		OffSet = Round(CoM[0][1])
		
	 	KyAnal[0,nCoMs-2][ii]=SelectNumber(yDistance[p]==0,xDistance[p],NaN)		//Removing measurements where Æy == 0
		
		
		
		MetaCoM[0,nCoMs-1][][ii]=CoM[p][q]
		MaxCoM=Max(MaxCom, nCoMs)
		
	EndFor
	
	DeletePoints /m=0 MaxCoM-1, nLines, KyAnal,  MetaCoM

	
	SetScale /p x,DimOffSet(image,1),DimDelta(image,1),WaveUnits(image,1) KyAnal
	SetScale d, -inf,inf,WaveUnits(Image,0) KyAnal
	
	KillWaves/z Seg, CoM
	
End

///////////////////////////////////


Function/t DisplayMetaCoM(image,MetaCoM)
	wave image, metacom
	
	variable nComs=DimSize(MetaCoM,2), ii
	String GraphName, LUTName, TraceName
	
	LUTName=NameOfWave(MetaCoM)+"_LUT"
	
	rainbowLUT(nCoMs+1,LUTName)
	Wave LUTWave = $LUTName
	
	Display/k=1
	GraphName = s_Name
	AppendImage image
	
	
	
	For(ii=0;ii<nComs;ii+=1)
	
		if(ii==0)
			TraceName = NameOfWave(MetaCoM)
		else
			TraceName = NameOfWave(MetaCoM)+"#"+Num2Str(ii)
		endif
		
		AppendToGraph /w=$GraphName MetaCoM[][1][ii] vs MetaCoM[][0][ii]
		ModifyGraph rgb($TraceName) = (LUTWave[ii+1][0],LUTWave[ii+1][1],LUTWave[ii+1][2])
	
	EndFor
	
	DoUpDate
	SizeImage(300)
	
	Return GraphName
End


///////////////////////////////////

Function KyCP()

	String KyName, ROIName
	
	Prompt KyName, "Your data", popup, wavelist("*",";","DIMS:2")
	Prompt ROIName, "ROI wave", popup, wavelist("*ROI*",";","DIMS:2")

	Doprompt "Kymograph analysis", KyName, ROIName

	if(v_flag)		//Abort if cancelled
		Abort
	endif
	
	 AutomateKy($KyName, $ROIName)
	 
	 Wave KyAnal, MetaCoM		//make references to waves generated by AutomateKy
	 
	 Integrate/dim=0  kyanal /d=kyInt
	 
	 Edit/k=1 KyAnal
	 
	 String GraphName=DisplayMetaCoM($KyName, MetaCoM)
	DrawROINumbers($roiName, graphname)


	PopWaveBrowser(PopWave=KyAnal)
	


End