#pragma rtGlobals=3		// Use modern global access method and strict wave access.

Function fSpanov5Fit(w,yw,xw)
	Wave w,yw,xw
	
	Variable i,m,n
	Variable Amplitude
	Variable Gaussian
	Variable Total
	
	Variable HRF=1;
	Variable IVE=0.179;
	//w[0] = exciton Bandwidth
	//w[1] = E_0 = 0-0 Vibrational Transition Energy
	//w[2] = h = Gaussian Width
	//w[3] = lim, i.e. maximum value of m and n
	//w[4] = amplitude parameter

	i=0
	do
		Total=0
		m=0	//Used a do-while loop to control the series summation
		do
			n=0
			do
				if (m!=n)	//Transition can't occur in same vibrational level		
					Amplitude=(exp(-HRF)*(HRF)^m)/(factorial(m))*((1 - ((w[0]*exp(-HRF))/(2*IVE))*(((HRF)^n)/(factorial(n)*(n-m))))^2)		
					Gaussian=exp(-(((xw[i]-w[1]-m*IVE-.5*w[0]*((HRF)^m)*exp(-HRF))^2)/(2*(w[2])^2)))
					Total+= w[4]*Amplitude*Gaussian
				endif
				n+=1
			while(n<=w[3]) 
			m+=1
		while(m<=w[3])
		yw[i]=Total
		i+=1
	while(i<numpnts(xw))
end

Function/S Spanov5_PeakFuncInfo(InfoDesired)
	Variable InfoDesired

	String info=""
		
	Switch (InfoDesired)
		case PeakFuncInfo_ParamNames:
			info = "Bandwidth;Vib00Energy;GaussWidth;mnLim;Amp;"
			break;
		case PeakFuncInfo_PeakFName:
			info = "FSpanov5Fit"
			break;
		case PeakFuncInfo_GaussConvFName:
			info = "GaussToSpanov5Guess"
			break;
		case PeakFuncInfo_ParameterFunc:
			info = "Spanov5PeakParams"
			break;
		case PeakFuncInfo_DerivedParamNames:
			info = "Location;Height;Area;FWHM;"
			break;
		default:
			break;
	endSwitch
	
	return info
end

Function GaussToSpanov5Guess(w)
	Wave w
	
	Variable Bandwidth = 0.05
	Variable Vib00Energy = w[0]
	Variable GaussWidth = w[1]/3
	Variable mnLim = 2
	Variable Amp=w[2]
	
	Redimension/N=5 w
	
	w[0] = BandWidth
	w[1] = Vib00Energy
	w[2] = GaussWidth
	w[3]= mnLim
	w[4] = Amp
	
	return 0
end

Function Spanov5_Location(w)
	Wave w
	Return w[1]
end

Function Spanov5_Height(w)
	Wave w
	return w[4]
end

Function Spanov5FWHM(w)
	Wave w
	return w[2]
end

Function Spanov5PeakParams(cw, sw, outWave)
	Wave cw, sw, outWave
	// location
	outWave[0][0] = Spanov5_Location(cw)
	outWave[0][1] = NaN //fix this, should be std dev
	// Height
	outWave[1][0] = Spanov5_Height(cw)
	outWave[1][1] = NaN //fix this, should be std deve
	// area
	outWave[2][0] = NaN //fix this, should be area
	outWave[2][1] = NaN //fix this, should be area std dev
	// FWHM
	outWave[3][0] = Spanov5FWHM(cw)
	outWave[3][1] = NaN
end