#pragma TextEncoding = "UTF-8"
#pragma rtGlobals=3		// Use modern global access method and strict wave access.

//Ben Murphy-Baum, 09/2016
//Generates a graphical representation of the waves contained in every subfolder for a given parent folder
//Good for cleaning out unnecessary waves that are making the experiment file really big
//Run from command line using graphMem(folder), where folder is the path to a parent folder (string). 
//Put a colon after the path name. i.e. graphMem("root:Traces:")

Function graphMem(folder)
//Generates the graphical display of the waves (non-text)
	string folder
	string nameWave
	
	String/G root:folder
	SVAR parentFolder = root:folder
	parentFolder = folder
	
	String/G root:subFolder
	String/G root:previewHolder
	SVAR previewHolder = root:previewHolder
	
	Variable/G root:itemNum
	NVAR itemNum = root:itemNum
	itemNum = 0
	
	Variable/G root:sampleRate
	Variable/G root:samplePeriod
	NVAR samplePeriod=root:samplePeriod
	
	Variable/G root:undoCount
	
	variable numFolders = CountObjects(parentFolder,4)		//counts # data folders in parent
	Make/O/N=(numFolders) root:folderNumber = x
	wave folderNumber = root:folderNumber
	variable n,i
	
	Make/O/T/N=(10000,numFolders) root:WaveNames		//makes folder list and size/name matrix waves
	Make/O/T/N=(numFolders) root:folderList
	Make/O/N=(10000,numFolders) root:waveMatrix
	Make/O/N=(numFolders) root:totalFolderSize
	
	wave/T waveNames = root:WaveNames
	wave/T folderList = root:folderList
	wave waveMatrix = root:waveMatrix
	wave totalFolderSize = root:totalFolderSize
	variable left = 0
	
	String/G root:list
	SVAR list = root:list
	list = folder+";"
	
	variable/G root:folderSizeHolder
	NVAR folderSizeHolder = root:folderSizeHolder 
	folderSizeHolder = 0
	
	totalFolderSize = 0
	root:waveMatrix = 0
	variable numWaves,count,yppp
	
	//Outer loop runs through each subfolder in the parent
	//Inner loop runs through each wave in a given subfolder, finds its name and size and puts those values in the corresponding matrix wave
	For(n=0;n<numFolders;n+=1)						
		string folderName = parentFolder+GetIndexedObjName(parentFolder,4,n)
		If(strlen(folderName) == 0)
			break
		EndIf
		
		numWaves = CountObjects(folderName,1)	
		If(n==0)						//keeps track of the largest number of waves in a folder for scaling the image plot later
			count = numWaves
		Else
			count = (numWaves > count) ? numWaves : count
		EndIf
		
		folderList[n] = GetIndexedObjName(parentFolder,4,n)
		
		
		list += folderList[n]+";"
		
		For(i=0;i<numWaves;i+=1)		//allocates wave names and sizes into the corresponding 2D wave
			nameWave = folderName+":'"+GetIndexedObjName(folderName,1,i)+"'"
			If(strlen(nameWave) == 0)
				break
			EndIf
			
			If(WaveType($nameWave,1) != 2)
				waveNames[i][n] = nameWave
				waveMatrix[i][n] = numpnts($nameWave)
				totalFolderSize[n] += numpnts($nameWave)	//finds total size of each subfolder
				SetDimLabel 1,n,$folderName,waveMatrix
			EndIf
		EndFor
	EndFor
	
	waveMatrix = (waveMatrix == 0) ? nan : waveMatrix	//Sets waves with no contents to NaN

//Displays the wave matrix	
	DoWindow/F graphMemory
	If(V_flag==0)
		previewHolder = ""
		Display/N=graphMemory/W=(0,0,705,500)/K=1
		DoWindow/T graphMemory,"graphMemory"
		DefineGuide graphGuide_T = {FT,30}
		
		AppendImage/W=graphMemory/L/T waveMatrix
		ModifyImage/W=graphMemory waveMatrix,ctab={*,*,Rainbow,1},log=1
		ModifyGraph/W=graphMemory userticks(left)={folderNumber,folderList},margin(left)=100,margin(top)=54,margin(bottom)=28,tkLblRot=0,axThick=0.5,gfsize=8
		Label/W=graphMemory top "# Waves"
		Label/W=graphMemory left "\\u#2"
		Redimension/N=(count,numFolders) waveMatrix,waveNames
		WaveStats /Q waveMatrix
		nameWave = waveNames[V_maxLoc]
		Tag/W=graphMemory/C/N=maxSize/F=0/Z=1/L=1/TL={lThick=0.5}/X=5/Y=5/A=MB waveMatrix, V_maxLoc,"\Z10"+nameWave+"\rMax: \OZ"
		
		//Defines some control buttons and a side panel
		DoUpdate/W=graphMemory
		GetAxis/Q/W=graphMemory Left
		GetWindow graphMemory psize
		///yppp=(V_max-V_min)/(V_bottom-V_top) //calculates points per pixel in the y dimension to calibrate slider dimensions
		///Slider folderSlider limits={V_top,V_bottom,1/yppp},live=1,pos={5,54},size={15,(V_max-V_min)/yppp},ticks=0
		
		NewPanel/N=CONTROLS/HOST=graphMemory/FG=(FL,FT,FR,graphGuide_T)	
		left+=15
	   Button Update win=#,title="Update",pos={left,5},size={100,20},proc=UpdateGraphProc
		left+=105
		Button AppendFolderSize win=#,title="Folder Size",pos={left,5},size={100,20},proc=AppendFolderSizeProc
		left+=105
		Button RemoveFolderSize win=#,title="Remove",pos={left,5},size={100,20},proc=RemoveFolderSizeProc
		left+=205
		PopupMenu folderListPopUp win=#,value=#"root:list",bodywidth=150,pos={left,6},proc=folderListPopMenuProc
		left+=55
		Button killWaveButton win=#,title="Kill Wave",pos={left,5},size={100,20},proc=killWaveProc
		ShowInfo
		//Builds Preview Panel
		NewPanel/HOST=graphMemory/EXT=0/N=previewPanel/W=(0,0,300,220)
		DefineGuide/W=graphMemory#previewPanel halfGuide = {FT,0.909,FB}
		Display/HOST=graphMemory#previewPanel/N=previewGraph/FG=(FL,FT,FR,halfGuide)/PG=(PL,PT,PR,PB)
		ValDisplay sampleRateVal win=graphMemory#previewPanel,title="∆(ms):",value=0,pos={10,202},size={100,20},valueBackColor=(0,0,0,0),frame=0,fsize=12
		Button resampleButton win=graphMemory#previewPanel,title="Resample",pos={110,201},size={80,20},proc=resampleButtonProc
		updatePreview(nameWave)
		SetVariable periodVar win=graphMemory#previewPanel,value=samplePeriod,pos={195,202},size={40,16},fsize=12,title=" ",frame=1,limits={0.05,inf,0}
		Button undoButton win=graphMemory#previewPanel,title="UNDO",pos={240,201},size={50,20},disable=2,proc=undoButtonProc
	Else
		//Does this if the wave matrix is already displayed so it doesn't recreate the graph, just updates it
		Redimension/N=(count,numFolders) waveMatrix,waveNames
		WaveStats /Q waveMatrix		
		nameWave = waveNames[V_maxLoc]	
		Tag/W=graphMemory/C/N=maxSize/F=0/Z=1/L=1/TL={lThick=0.5}/X=5/Y=5/A=MB waveMatrix, V_maxLoc,"\Z10"+nameWave+"\rMax: \OZ"
		
		updatePreview(nameWave)
		DoUpdate/W=graphMemory
		ShowInfo
	EndIf
	
	SetWindow graphMemory hook(cursorHook)=cursorMoveHook
	SetWindow graphMemory hook(windowHook)=windowSizeHook
	SetIgorHook AfterWindowCreatedHook 
End

Function IgorMenuHook(isSel,menuStr,itemStr,itemNo,activeWindowStr,wt)

	Variable isSel
	String menuStr, itemStr
	Variable itemNo
	String activeWindowStr
	Variable wt
	variable handled = 0
	If(CmpStr(menuStr,"Graph") == 0 && CmpStr(itemStr,"Append To Graph") == 0)
		if( wt == 1)
			print activeWindowStr
			handled = 1
		EndIf
	EndIf

	return handled
End

Function UpdateGraphProc(ba) : ButtonControl//Button for updating the graph
	STRUCT WMButtonAction &ba
	SVAR parentFolder = root:folder
	NVAR folderSizeHolder = root:folderSizeHolder
	wave folderNumber = root:folderNumber
	
	switch( ba.eventCode )
		case 2: // mouse up
			If(folderSizeHolder == 1)
				RemoveFromGraph/W=graphMemory folderNumber
				folderSizeHolder = 0
			EndIf
			graphMem(parentFolder)
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function DisplayCursorWaveProc(ba) : ButtonControl	//Button for displaying the wave corresponding to where the 'A' cursor is on the image plot
	STRUCT WMButtonAction &ba
	variable/G root:rightclick
	NVAR rightclick = root:rightclick
	
	switch(ba.eventCode)
		
		case 2: // mouse up
			wave/T waveNames = root:WaveNames
			string nameWave,csrStatus
			csrStatus = CsrInfo(A,"graphMemory")
			
			If(strlen(csrStatus) != 0)
				variable xVal = pcsr(A,"graphMemory")
				variable yVal = vcsr(A,"graphMemory")
				nameWave = waveNames[xVal][yVal]
				If(strlen(nameWave) == 0)
					break
				ElseIf(WaveType($nameWave,1) == 2)
					print "Text wave"
					break
				Else
					updatePreview(nameWave)
				EndIf
			EndIf
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function AppendFolderSizeProc(ba) : ButtonControl		//Button for appending a graph of each folders' total size
	STRUCT WMButtonAction &ba
	NVAR folderSizeHolder = root:folderSizeHolder
	
	switch( ba.eventCode )
		case 2: // mouse up
			wave folderNumber = root:folderNumber
			wave totalFolderSize = root:totalFolderSize
			variable numFolders = DimSize(folderNumber,0)
			If(folderSizeHolder != 1)
				AppendToGraph/W=graphMemory/B/L folderNumber vs totalFolderSize
				SetAxis /W=graphMemory bottom 0,*
				ModifyGraph/W=graphMemory axThick=0.5,standoff=0,btLen=3,gfSize=8,margin(bottom)=28,axisEnab(bottom)={0.6,1},mode=4,marker=19,msize=2
				Label/W=graphMemory bottom "Folder Size(\\U)"
				folderSizeHolder = 1
			EndIf
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function RemoveFolderSizeProc(ba) : ButtonControl		//Button for removing the total folder size plot
	STRUCT WMButtonAction &ba
	NVAR folderSizeHolder = root:folderSizeHolder
	
	switch( ba.eventCode )
		case 2: // mouse up
			wave folderNumber = root:folderNumber
			If(folderSizeHolder == 1)
				RemoveFromGraph/W=graphMemory folderNumber
			EndIf
			folderSizeHolder = 0
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function folderListPopMenuProc(pa) : PopupMenuControl		//drop down menu for all the subfolders in the parent folder.
	STRUCT WMPopupAction &pa											//Selecting a subfolder updates the graph to identify the largest wave in that subfolder
	SVAR list = root:list												//Selecting the parent folder (top choice) identifies the largest wave overall in any of the subfolders
	NVAR itemNum = root:itemNum
	SVAR subfolder = root:subfolder
	SVAR folder = root:folder
	variable location,size,xloc
	wave stats
	wave waveMatrix = root:waveMatrix
	string nameWave
	wave/T waveNames = root:WaveNames
	wave totalFolderSize = root:totalFolderSize
	
	switch( pa.eventCode )
		case 2: // mouse up
			variable popNum = pa.popNum
			string popStr = pa.popStr
			itemNum = popNum-1
			subfolder = popStr
			
			size = DimSize(waveMatrix,0)
			SetDataFolder root:
			WaveStats /Q/PCST waveMatrix
			wave stats = root:M_WaveStats
			
			If(itemNum == 0)
				WaveStats/Q waveMatrix
				nameWave = waveNames[V_maxLoc]
				Tag/W=graphMemory/C/N=maxSize/F=0/Z=1/L=1/TL={lThick=0.5}/A=MB/X=5/Y=5 waveMatrix, V_maxLoc,"\Z10"+nameWave+"\rMax: \OZ"
				updatePreview(nameWave)
			Else
				xloc = stats[11][itemNum-1]
				location = (itemNum-1)*size+xloc
				nameWave = waveNames[xloc][itemNum-1]
				Tag/W=graphMemory/C/N=maxSize/F=0/Z=1/L=1/TL={lThick=0.5}/A=MB/X=5/Y=5 waveMatrix, location,"\Z10"+nameWave+"\rMax: \OZ"
				updatePreview(nameWave)
			EndIf
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function windowSizeHook(s)		//hook function to call Update Control function when the cursor moves
	STRUCT WMWinHookStruct &s
	
	Variable hookResult = 0
	
	strswitch(s.eventName)
		case "resize":
			GetAxis/Q/W=graphMemory left
			GetWindow graphMemory psize
		//	UpdateSlider(V_max,V_min,V_top,V_bottom)
			break
	endswitch
	
	return hookResult
End

//Function UpdateSlider(maxPt,minPt,top,bottom)
//	variable maxPt,minPt,top,bottom
//	variable yppp
//	yppp=(maxPt-minPt)/(bottom-top)    //calculates points per pixel in the y dimension to calibrate slider dimensions
//	Slider folderSlider win=graphMemory,limits={top+50,bottom,1/yppp},size={15,(maxPt-minPt)/yppp},pos={5,33}
//End

//Function sliderMoveHook(S_Struct) : SliderControl
//	STRUCT WMSliderAction &S_Struct
//	Variable hookResult = 0
//End

Function cursorMoveHook(s)		//hook function to call Update Control function when the cursor moves
	STRUCT WMWinHookStruct &s
	
	Variable hookResult = 0
	string csrStatus
	
	strswitch(s.eventName)
		case "cursormoved":
			UpdateControls(s.pointNumber,s.yPointNumber)
			break
	endswitch
	
	return hookResult
End
		
Function UpdateControls(xPoint,yPoint)		//Annotates the wave name and size at the cursor location
	variable xPoint,yPoint
	variable size,location,xppp,yppp,xlocale,ylocale
	string nameWave,csrStatus
	wave/T waveNames = root:WaveNames
	wave waveMatrix = root:waveMatrix
	
	csrStatus = CsrInfo(A,"graphMemory")
	If(strlen(csrStatus) != 0)
		size = DimSize(waveMatrix,0)
		nameWave = waveNames[xPoint][yPoint]
		location = (yPoint)*size + xPoint
		GetWindow graphMemory psize
		GetAxis/Q/W=graphMemory Top
		xppp=(V_max-V_min)/(V_right-V_left)
		xlocale = (xPoint-V_min)/xppp
		GetAxis/Q/W=graphMemory Left
		yppp=(V_max-V_min)/(V_bottom-V_top)
		ylocale = 0.93*((V_max - V_min - (yPoint-V_min))/yppp)
		//Button that moves with the A cursor
		Button cursorButton win=graphMemory,title="\JL   "+nameWave+"\r   Size:"+num2str(waveMatrix[xPoint][yPoint]),pos={xlocale,ylocale},size={250,30},fsize=8,proc=DisplayCursorWaveProc
		Button cursorButton win=graphMemory,disable=0
		//Button killWaveButton win=graphMemory,title="KILL",pos={xlocale+250,ylocale},size={30,30},proc=killWaveProc
		//Button killWaveButton win=graphMemory,disable=0
	Else
		Button cursorButton win=graphMemory,disable=1
		Button killWaveButton win=graphMemory,disable=1
	EndIf
End

Function killWaveProc(ba) : ButtonControl		//Button for killing the wave displayed in the preview panel
	STRUCT WMButtonAction &ba
	SVAR previewHolder = root:previewHolder
	
	switch( ba.eventCode )
		case 2: // mouse up
			wave folderNumber = root:folderNumber
			
			DoAlert/T="Kill Wave" 1,"Are you sure?"
			If(V_flag == 1)
				RemoveFromGraph/W=graphMemory#previewPanel#previewGraph $"#0"
				KillWaves $previewHolder
				previewHolder = ""
			Else
				break
			EndIf
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function updatePreview(nameWave)		//updates the preview panel
	String nameWave
	SVAR previewHolder = root:previewHolder
	NVAR sampleRate = root:sampleRate
	NVAR undoCount = root:undoCount
	
	If(strlen(previewHolder) != 0)
		RemoveFromGraph/W=graphMemory#previewPanel#previewGraph $"#0"		//only removes wave from preview if there is a wave is there
	EndIf
	previewHolder = nameWave
	AppendToGraph/W=graphMemory#previewPanel#previewGraph $nameWave
	
	sampleRate = 1000*(DimDelta($nameWave,0))
	ValDisplay sampleRateVal win=graphMemory#previewPanel,value=_NUM:sampleRate
	Button undoButton win=graphMemory#previewPanel,disable=2
	undoCount = 0
End

Function resampleButtonProc(ba) : ButtonControl//Button for resampling the wave in the preview graph
	STRUCT WMButtonAction &ba
	SVAR previewHolder = root:previewHolder
	NVAR samplePeriod = root:samplePeriod
	NVAR sampleRate = root:sampleRate
	NVAR undoCount = root:undoCount
	variable period
	
	period = 1000/samplePeriod
	switch( ba.eventCode )
		case 2: // mouse up
			If(strlen(previewHolder) != 0)
				If(samplePeriod < sampleRate)
					print "No upsampling"
					break
				Else
					If(undoCount == 0)
						Make/O/N=(DimSize($previewHolder,0)) root:tempWave
						wave tempWave = root:tempWave
						Duplicate/O $previewHolder,tempWave
					EndIf
						Button undoButton win=graphMemory#previewPanel,disable=0
						Resample/RATE=(period) $previewHolder
						sampleRate = 1000*(DimDelta($previewHolder,0))
						ValDisplay sampleRateVal win=graphMemory#previewPanel,value=_NUM:sampleRate
						undoCount+=1
				EndIf
			Else
				print "No wave to resample"
			EndIf
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function undoButtonProc(ba) : ButtonControl//Button for resampling the wave in the preview graph
	STRUCT WMButtonAction &ba
	SVAR previewHolder = root:previewHolder
	wave tempWave = root:tempWave
	NVAR sampleRate = root:sampleRate
	NVAR undoCount = root:undoCount
	
	switch( ba.eventCode )
		case 2: // mouse up
			Duplicate/O tempWave,$previewHolder
			sampleRate = 1000*(DimDelta($previewHolder,0))
			ValDisplay sampleRateVal win=graphMemory#previewPanel,value=_NUM:sampleRate
			undoCount = 0
			Button undoButton win=graphMemory#previewPanel,disable=2
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End