#pragma rtGlobals=1		// Use modern global access method.

Function doSubtractOnAllWindows()
	String allGraphNames = WinList("*", ";", "WIN:1")
	Variable nGraphs = ItemsInList(allGraphNames)
	Variable i
	
	for (i=0; i<nGraphs; i+=1)
		String currGraph = StringFromList(i, allGraphNames)
		// do the subtraction and plot it on the graph
		subtract_1st2waves(currGraph, "txtxR")
	endfor
end


// Note: assumes liberal names are used - meaning the string functions assume a leading and trailing ' (single quote)
Function /WAVE subtract_1st2waves(graphName, aStrID)
	String graphName		// Name of graph or "" for top graph
	String aStrID		      // substring identifying the A wave
	
	Variable i
	String traceList = TraceNameList(graphName, ";", 5)
	
	// check for too few waves
	if (ItemsInList(traceList) < 2)
		Printf "Error in subtract_1st2waves(\""+graphName+"\") - too few waves"
		return NaN
	endif
	
	// use the first 2 waves
	for (i=0; i<2; i+=1) 
		String currStr = StringFromList(i,traceList)  // get one wave name
		if (stringmatch(currStr, "*"+aStrID+"*"))                      // determine if its the A wave or the B wave
			Wave aY = TraceNameToWaveRef(graphName, currStr)    // get the A Y wave
			Wave aX = XWaveRefFromTrace(graphName, currStr)	  // get the A X wave

			String baseName = RemoveEnding(currStr, "."+aStrID+"'")   // for naming the A-B wave
			baseName = CleanupName(baseName, 0)                           // pretty the name up a bit
			baseName = ReplaceString("X_", baseName, "")
		else
			Wave bY = TraceNameToWaveRef(graphName, currStr)  // get the B Y wave
			Wave bX = XWaveRefFromTrace(graphName, currStr)     // get teh B X wave
		endif
	endfor
	
	// interpolate B to A
	Duplicate /FREE aY, interp_bY
	Make /O/N=(DimSize(aY,0)), $(baseName+"_AminusB")

	interp_bY = interp(aX, bX, bY)
	
	// do subtraction
	Wave sub_wave=$(baseName+"_AminusB") 
	sub_wave = aY - interp_bY
	
	// add subtracted wave to the graph
	AppendToGraph /W=$graphName sub_wave vs aX
	ModifyGraph /W=$graphName rgb($(baseName+"_AminusB"))=(0, 0, 2^16-1)
end