Custom Fit Function using Predefined waves

This should do it:

Function FitMixture(w,x) : FitFunc
	Wave w
	Variable x

	//CurveFitDialog/ These comments were created by the Curve Fitting dialog. Altering them will
	//CurveFitDialog/ make the function less convenient to work with in the Curve Fitting dialog.
	//CurveFitDialog/ Equation:
	//CurveFitDialog/ WAVE sp1, sp2
	//CurveFitDialog/ 
	//CurveFitDialog/ f(x) = A*sp1(x) + B*sp2(x)
	//CurveFitDialog/ End of Equation
	//CurveFitDialog/ Independent Variables 1
	//CurveFitDialog/ x
	//CurveFitDialog/ Coefficients 2
	//CurveFitDialog/ w[0] = A
	//CurveFitDialog/ w[1] = B

	WAVE sp1, sp2
	
	Variable xx = x
	
	if (x < leftx(sp1))
		xx = sp1(leftx(sp1))
	elseif (x > pnt2x(sp1,numpnts(sp1)-1))
		xx = pnt2x(sp1,numpnts(sp1)-1)
	endif
		
	return w[0]*sp1(xx) + w[1]*sp2(xx)
End

Note that this function assumes that sp1 and sp2 have the X scaling set (if this is not familiar, execute this command in Igor: DisplayHelpTopic "The Waveform Model of Data").

It handles the case where the fit X range is outside the range of sp1 and sp2 by returning the value at one end or the other as appropriate. It *does* assume that sp1 and sp2 have the SAME X range.

It looks up interpolated values from sp1 and sp2 using X indexing.

Oh, and it assumes that the waves with your standard spectra are named literally "sp1" and "sp2".