Detecting which subpanel & control was target of interaction

Function MakePanel()
    NewPanel /W=(0,0,1200,600) /N=MyFunnyPanel//k=1
    //Define Vertical guides
    DefineGuide UGV0={FL,200},UGV1={UGV0,0.33333333,FR},UGV2={UGV0,0.66666666, FR}
    //Define Horizonzal guides
    DefineGuide UGH0={FB,0.5,FT}
 
    string quote = "\""
    String DataTypeList = quote + "Alpha;Beta;Delta;Gamma;Theta" + quote
    String SectionList = quote + "First;Second;Third;Fourth;" + quote
   
    String sSubPanelName
 
    //Create subpanels/subwindows where data will be displayed according to user input on controls
    Variable i
    for(i = 0; i < 6; i += 1)
        switch(i)
            case 0:
                NewPanel/FG=(UGV0,FT,UGV1,UGH0)/HOST=MyFunnyPanel
                break
            case 1:
                NewPanel/FG=(UGV1,FT,UGV2,UGH0)/HOST=MyFunnyPanel
                break
            case 2:
                NewPanel/FG=(UGV2,FT,FR,UGH0)/HOST=MyFunnyPanel
                break
            case 3:
                NewPanel/FG=(UGV0,UGH0,UGV1,FB)/HOST=MyFunnyPanel
                break
            case 4:
                NewPanel/FG=(UGV1,UGH0,UGV2,FB)/HOST=MyFunnyPanel
                break
            case 5:
                NewPanel/FG=(UGV2,UGH0,FR,FB)/HOST=MyFunnyPanel
                break
        endswitch
       
        sSubPanelName = "P" + num2istr(i)
        RenameWindow #,$sSubPanelName //Each subwindow has a name
       
        //Names of Controls
 
        //Indicate controls needed             
        PopupMenu SelectData, title="Data Type", bodyWidth=110, value=#DataTypeList, pos={120,10}      
        PopupMenu SelectSection, title="Section", bodyWidth=100, value=#SectionList, pos={270,10}
 
        CheckBox CheckTS,pos={5,30},size={75,15},title="Time Series",value=1,mode=1, proc=CheckPlotTypeProc
        CheckBox CheckHist,pos={95,30},size={75,15},title="Histogram",value=0,mode=1, proc=CheckPlotTypeProc
        CheckBox CheckBar,pos={185,30},size={75,15},title="Average",value=0,mode=1, proc=CheckPlotTypeProc
 
        Button PopButton,title="pop",size={30,20}, pos={280,30}, proc=MyPopButtonProc
        // add more controls here...
 
        SetActiveSubwindow ## //Go back to parent window
    endfor
    String/G ListOFSubWindows = ChildWindowList("MYFunnyPanel")
End

Function MyPopButtonProc(B_Struct) : ButtonControl
    STRUCT WMButtonAction &B_Struct
   
    if(B_Struct.eventCode != 2) // ignore everything except mouse up
        return 0
    endif
   
    String sWin = B_Struct.win
   
    String sSubPanelNumber
    SplitString/E=("#P([[:digit:]]+)") sWin, sSubPanelNumber
    Variable vSubPanelNumber = str2num(sSubPanelNumber)
   
    String sSelectDataValue, sSelectSectionValue
   
    ControlInfo /W=$sWin SelectData
    sSelectDataValue    = S_Value
   
    ControlInfo /W=$sWin SelectSection
    sSelectSectionValue = S_Value
   
    printf "Panel = %g, DataValue = %s, SectionValue = %s\r", vSubPanelNumber, sSelectDataValue, sSelectSectionValue
   
    return 0
End

    ControlInfo /W=$sWin SelectData