Executescript not executing...

//	Windows: Execute a DOS command and get output, if any
// ExecuteDOSCommand(command, maxSecondsToWait)
// Executes a DOS command and returns any output text as the function result.
// Returns "" if the DOS command returns no text.
// maxSecondsToWait is the maximum number of seconds to wait for DOS to finish
// the command. If it takes longer than that, an error is generated.
// This function creates files in the Igor Pro User Folder:
//		igorBatch.bat	Holds command that DOS is to execute
//		igorBatchOutput.txt	Holds output generated by DOS command, if any
// Example:
//		Print ExecuteDOSCommand("echo %PATH%", 3)
Function/S ExecuteDOSCommand(command, maxSecondsToWait)
	String command	// e.g., "echo %PATH%"
	Variable maxSecondsToWait	// Error if DOS takes longer than this
	
	String quoteStr = "\""
	
	// Get path to batch file in "Igor Pro User Files"
	String dirPath = SpecialDirPath("Igor Pro User Files", 0, 0, 0)
	dirPath = ParseFilePath(5, dirPath, "\\", 0, 0)	// Convert to Windows path
	String batchFilePath = dirPath + "igorBatch.bat"
	String batchOutputFilePath = dirPath + "igorBatchOutput.txt"
	
	DeleteFile/Z batchOutputFilePath

	// Write DOS command to batch file
	String dosCommand = command + " > " + quoteStr + batchOutputFilePath + quoteStr
	Variable refNum
	Open refNum as batchFilePath
	FBinWrite refNum, dosCommand
	Close refNum
	
	// Execute batch file
	// The DOS command must complete in the number of seconds specified via /W
	// /C means cmd.exe quits after executing the command
	String text
	sprintf text, "cmd.exe /C \"%s\"", batchFilePath
	ExecuteScriptText/W=(maxSecondsToWait) text
	
	// Get output
	String result = ""
	Open/R/Z refNum as batchOutputFilePath
	if (V_flag != 0)
		result = ""
		// result = "<No output was generated by batch file>"	// For debugging
	else
		// Read contents of batch file into string
		FStatus refNum
		Variable numBytesInFile = V_logEOF
		result = PadString("", numBytesInFile, 0x20)
		FBinRead refNum, result
		Close refNum
	endif
	
	return result
End