Irregular wave scaling

Share icon

Tue, 09/13/2011 - 05:16 am

Hi,

is anyone aware of a possibility to introduce an irregular scaling for a wave?

In my particular case I have a 2d wave. One of its dimensions is regular, so I can use SetScale to scale this.
The scaling of the second dimension should be irregular, best to be read from an additional 1d wave that contains the bin information. Finally I want to creat an image plot of the 2d wave that has one regular, linear axis (x-axis) and the second axis (y-axis) would be a log axis and the pixel size in the y dimension would vary.

Modifying the wave scaling was my best thought how to accomplish this, but
any other idea of how completing such a figure bypassing the irregular scaling would be highly appreciated.

Searching the IGOR forum I found this post:
http://www.igorexchange.com/node/1484
but the solution there is a graph with regular y axis scaling.
If I understand the question, here is a demonstration of the solution:

Function Demo()
    Make/O/N=(5,5) mat = p*q
   
    // Set X scaling
    SetScale/P x 0, .2, "x", mat
   
    // Make Y coordinate wave with one extra point
    // Each coordinate specifies the edge of a pixel and we need the extra point
    // to specify the right edge of the last pixel
    Variable numPoints = DimSize(mat,1) + 1
    Make/O/N=(numPoints) yCoordinates
    yCoordinates = 10^p
   
    // Make image plot
    Display;AppendImage mat vs {*,yCoordinates}
   
    // Put left axis in log mode
    ModifyGraph log(left)=1
End


For further information, execute this:
DisplayHelpTopic "Image X and Y Coordinates"

September 13, 2011 at 07:42 am - Permalink