Loading waves from csv consist of random number of text and data

LoadWave/J/D/E=1/L={0, 216, 0, 1, 3}

DisplayHelpTopic "Loading Delimited Text Files"

DisplayHelpTopic "LoadWave"

Function Test()

    //  Creates a path to "D:Temp:" I am lazy and that is where I placed the file.
    NewPath/Q/O/Z CSVDataPath "D:Temp:"

    //  Will use CSVDataPath with the next Open command. This is identical to Open/P=CSVDataPath, but it prevents a bug in Igor 6.36 or, most likely, Windows 10
    PathInfo/S CSVDataPath

    //  Display an open file dialog, showing only files with the extension .csv
    String FileExtension="CSV Files (*.csv):.csv;All Files (*.*):.*;"
    Open/D/F=FileExtension /R/MULT=0 /P=CSVDataPath RefNum
    String FullFileName=S_FileName
   
    //  Checks that a file was actually selected
    if (StrLen(FullFileName)!=0)
   
        //  Loads the file as a one long text wave
        LoadWave /O/N=LoadedTextWave /K=2 /Q /J /M FullFileName
        Wave/T LoadedTextWave=LoadedTextWave0
        Variable NumberOfLines=DimSize(LoadedTextWave, 0)
       
        //  Creates a table with the loaded text wave
        DoWindow/K LoadedTextTable
        Edit/N=LoadedTextTable LoadedTextWave
       
        //  Searches the first column for "DataValue"
        Duplicate/O/FREE/R=[][0] LoadedTextWave, Loaded1stColumn
        FindValue /S=0 /TEXT="DataValue" /TXOP=5 /Z Loaded1stColumn
       
        if (V_value!=-1)
   
            //  Loads DataValue part the file as a three-column numeric wave
            LoadWave /O/N=LoadedNumericWave /K=1 /L={0, V_value, NumberOfLines-V_value, 1, 3} /Q /J /M FullFileName
            Wave  LoadedNumericWave=LoadedNumericWave0

            //  Creates a table with the loaded numeric wave
            DoWindow/K LoadedNumericTable
            Edit/N=LoadedNumericTable LoadedNumericWave
        endif
    endif
end

strConstant DataKey = "*SPECTRUM*"
strConstant EnergyKey ="*XPERCHAN*"

function LoadEMSA()
    variable refNum
    Open/D/R/F="*.txt" refNum
    if (strlen(S_FileName) == 0)
        return -1
    endif
    Open/R refNum as S_fileName
   
    string wNote=""
    variable i=0
    variable Scaling, DataStart
       
    do
        // read file line by line
        string line
        FReadLine refNum, line
        if(strlen(line) == 0)                      
            break                                      
        endif
       
        // save header line to string
        wNote += line
       
        // extract value for x-scaling
        if(StringMatch(line, EnergyKey))
            sscanf line, "#XPERCHAN    :%f", Scaling
        endif
       
        // stop reading when DataKey is hit
        if(StringMatch(line, DataKey))
            DataStart = i+1
            break
        endif
        i+=1
    while(1)
    Close refNum
   
    // load the spectral part of the data, scale wave and add header as wave note
    LoadWave/B="N='_skip_'; N=Counts;"/O/A/G/D/L={0,DataStart,0,0,0} S_fileName
    wave Counts
    SetScale/P x 0, Scaling, "keV", Counts
    Note/K Counts, wNote
    return 1
end

LoadWave/J/D/W/K=0/L={215,216,0,0,0} "path:example_0.csv"