Loading spectroscopic data into igor from general text

Menu "Load Waves"
    "LoadMcIlhennyData...", LoadMcIlhennyData("", "")  
End

//  FindSectionNameAndDataStartLine(refNum, name, dataStartLine, numDataLines)
Function FindSectionNameAndDataStartLine(refNum, currentLine, sectionName, dataStartLine, numDataLines)
    Variable refNum
    Variable &currentLine           // Input and output
    String &sectionName         // Output - name of file section
    Variable &dataStartLine         // Output line where data starts
    Variable &numDataLines          // Output - number of data lines in this section
   
    String text
    do
        FReadLine refNum, text
        if (strlen(text) == 0)
            return -1                   // End of file
        endif
        if (CmpStr(text[0,4],"Area1") == 0)
            FReadLine refNum, text      // Skip the blank line
            if (strlen(text) == 0)
                return -2               // Unexpected end of file
            endif
            currentLine += 1
            FReadLine refNum, text      // Get the name line
            if (strlen(text) == 0)
                return -2               // Unexpected end of file
            endif
            currentLine += 1
            text = RemoveEnding(text, "\r")     // Remove CR
            sectionName = text
            dataStartLine = currentLine
           
            // Find number of lines in this section
            numDataLines = 0
            do
                FReadLine refNum, text
                text = RemoveEnding(text, "\r")     // Remove CR
                if (strlen(text) == 0)
                    break                           // Blank line or end of file
                endif
                currentLine += 1
                numDataLines += 1
            while(1)
            break
        endif
        currentLine += 1
    while(1)   
   
    return 0
End

Function/S LoadMcIlhennyData(pathName, fileName)    // Returns list of loaded waves
    String pathName     // Name of an Igor symbolic path or "".
    String fileName         // Name of file or full path to file.

    Variable refNum

    // First get a valid reference to a file.
    if ((strlen(pathName)==0) || (strlen(fileName)==0))
        // Display dialog looking for file.
        Open/D/R/P=$pathName refNum as fileName
        fileName = S_fileName           // S_fileName is set by Open/D
        if (strlen(fileName) == 0)      // User cancelled?
            return ""
        endif
    endif

    // Open file for searching for wave names and data
    Open /R /P=$pathName refNum as fileName
   
    String fileBaseName = ParseFilePath(3, fileName, ":", 0, 0) // File name without extension
    fileBaseName = CleanupName(fileBaseName, 0)

    Variable sectionsLoaded = 0, sectionsSkipped = 0
    Variable result = 0
    String waveNames = ""
   
    Variable currentLine = 0
    String sectionName
    Variable dataStartLine, numDataLines
   
    do
        result = FindSectionNameAndDataStartLine(refNum, currentLine, sectionName, dataStartLine, numDataLines)
        if (result == -1)
            break           // Normal end of file
        endif
        if (result != 0)
            Abort "Unexpected end of file"
        endif
       
        String xName, yName
        String columnInfo = ""
        xName = fileBaseName + "_EB_" + sectionName
        columnInfo += "N='" + xName + "';"          // e.g., "N='Spec1_EB_N1s';"
        yName = fileBaseName + "_Int_" + sectionName
        columnInfo += "N='" + yName + "';"          // e.g., "N='Spec1_EB_N1s';N='Spec1_Int_N1s';"
           
        LoadWave /G /P=$pathName /A /O/B=columnInfo /L={0,dataStartLine,numDataLines,0,0} /Q fileName
        if (V_flag == 2)    // V_flag is set by LoadWave to the number of waves loaded.
            Printf "Loaded '%s' and '%s' from line %d of \"%s\"\r", xName, yName, dataStartLine, fileName
            waveNames += S_waveNames
            sectionsLoaded += 1
        else
            Printf "Error in LoadWave while loading the file \"%s\"\r", fileName
            sectionsSkipped += 1
        endif
    while (1)                                       // Until IndexedFile runs out of files
   
    Close refNum
   
    Printf "%d sections loaded, %d sections skipped\r", sectionsLoaded, sectionsSkipped
   
    return waveNames    // Return list of loaded waves
End