AI programming - skills.md anyone?

I have found that Claude Opus 4.5/4.6 is pretty good at writing Igor code that compiles successfully and does what I want it to do. I've had it write several hundred lines of Igor code several times and there is often one or two compile errors.

A barrier to this kind of skill is that the AI using the skill needs to have a way to compile a file and get back the errors. As I understand it, our compiler stops at the first compile error (not just in a single file, but in all files being compiled within Igor's environment). There is an undocumented way to have Igor write that compile error to stdout instead of putting up the "compile error" dialog, but even so just one error is written. This feature is used by our CI and is intended to be used only on headless systems, which is why it's undocumented.

Once compile errors are fixed, I think it's conceivable that a skill could be written that starts Igor, includes a procedure file, then runs a command that does something to test the code that was written. We do something similar in our CI already.

    - name: Get IgorInfo
      shell: cmd
      id: igor-info
      working-directory: ${{inputs.igor-folder}}\IgorBinaries_x64
      run: |
        ${{inputs.igor-executable}} /UNATTENDED /I /X "Execute/P/Q "INSERTINCLUDE \"${{ github.action_path }}\IgorInfoForGitHub\""; Execute/P/Q "COMPILEPROCEDURES "; Execute/P/Q "WriteIgorInfo()""

IgorInfoForGitHub.ipf contains:

#pragma TextEncoding = "UTF-8"
#pragma rtGlobals=3				// Use modern global access method and strict wave access
#pragma DefaultTab={3,20,4}		// Set default tab width in Igor Pro 9 and later

Function WriteIgorInfo()
	WriteIgorInfoToGitHubOutput()
	WriteIgorInfoToGitHubStepSummary()
	Execute/P/Q "Quit/N"
End

Function WriteIgorInfoToGitHubOutput()
	// Get the value of the environment variable that contains
	// the file that needs to be written to.
	String outputFile = GetEnvironmentVariable("GITHUB_OUTPUT")
	if (strlen(outputFile) > 0)
		Variable refNum
		Open/A/Z refNum as outputFile
		if (V_Flag == 0)
			// Create a semicolon separated list of key:value pairs
			String infoList = ""
			infoList += IgorInfo(0)
			infoList += IgorInfo(3)
			infoList += "QT:" + IgorInfo(6) + ";"
			infoList += "XOPs:" + RemoveEnding(ReplaceString(";", IgorInfo(10), ","), ",") + ";"
			infoList += "BUILD-TYPE:" + IgorInfo(-106) + ";"
			infoList += "SN:" + IgorInfo(5) + ";"	// Serial number of "_none_"
			
			// Print info to stdout
			fprintf -1, "%s\n", infoList

			
			// Write each of the pairs to the file
			Variable numPairs = ItemsInList(infoList, ";")
			Variable n
			For (n=0; n < numPairs; n++)
				String thisPair = StringFromList(n, infoList, ";")
				thisPair = TrimString(thisPair)
				if (strlen(thisPair) > 1)
					String key = StringFromList(0, thisPair, ":")
					String value = StringFromList(1, thisPair, ":")
					// Replace any "=" characters in value with " is "
					// because GitHub expects key=value.
					value = ReplaceString("=", value, " is ")

					fprintf refNum, "%s=%s\n", lowerStr(key), value
				endif
			EndFor
			Close refNum
		endif
	endif
End

Function WriteIgorInfoToGitHubStepSummary()
	// Get the value of the environment variable that contains
	// the file that needs to be written to.
	String outputFile = GetEnvironmentVariable("GITHUB_STEP_SUMMARY")
	if (strlen(outputFile) > 0)
		Variable refNum
		Open/A/Z refNum as outputFile
		if (V_Flag == 0)
			String info0 = IgorInfo(0)
			String locale = StringByKey("LOCALE", IgorInfo(3))
			String localeString = ""
			StrSwitch (locale)
				case "US":
					localeString = ":us:"
					break
					
				case "JAPAN":
					localeString = ":jp:"
					break
			
				default:
					localeString = ":question:"
					break					
			EndSwitch
			fprintf refNum, "# Igor Pro Version %g %s\n", IgorVersion(), localeString
			
			fprintf refNum, "**Build:** %s", StringByKey("BUILD", info0)
			String commit = StringByKey("COMMIT", info0)
			if (strlen(commit) > 0)
				fprintf refNum, " **Commit:** %s", commit
			endif
			fprintf refNum, " **Qt Version:** %s", IgorInfo(6)
			fprintf refNum, " **Serial Number:** %s", IgorInfo(5)
			fprintf refNum, "\n"
			
			Close refNum
		endif
	endif
End

This runs as part of a GitHub action and writes some information to stdout and some to a file that GitHub creates before running the step and then reads after it completes. Capturing stdout on Windows is tricky and I don't know if AI running a step would be able to read stdout in the same way this action can read it.

That's a long way of saying that Igor has most but not all of the fundamental capabilities I think would be necessary to do what you're trying to do. So far we don't have anything more to contribute the the cause.

You might be able to use the skills.md file to direct the AI to read our documentation from the new documentation website (docs.wavemetrics.com/igorpro/commands, or other relevant URLs within docs.wavemetrics.com). I've played around with this a bit, not in a skills file, but as an initial prompt. As long as it comes up with a valid URL to check, it does manage to digest parts of the documentation enough to answer questions and provide our actual code examples. I would assume this means it would produce more accurate 'novel' code as well, but I haven't thoroughly tested that theory.

I've used github copilot succesfully via the web interface. See e.g. https://github.com/AllenInstitute/MIES/pull/2686. This was done without any compile feedback or skills file. The codebase is sufficiently large for it to come up with relatively okayish code.

thomas_braun wrote:

I've used github copilot succesfully via the web interface. See e.g. https://github.com/AllenInstitute/MIES/pull/2686. This was done without any compile feedback or skills file. The codebase is sufficiently large for it to come up with relatively okayish code.

According to https://github.com/AllenInstitute/MIES/agents/pull/2686?session_id=b10fcbd6-09e7-4c61-a617-c02789769fb6 it looks like Copilot is calling your  ./tools/run-ipt.sh script to do some linting, though in this particular case that didn't find any errors so wasn't truly necessary.

Copilot was using Claude Opus 4.5 for that run. We've found that Claude Opus 4.5/4.6 is pretty good at writing Igor code. We haven't tested other models much.

Well, few hours and some tokens with Claude and here is my first attempt at skills 

 https://github.com/jilavsky/igorpro-skills

I tested that with my VSCode Claude extension on macOS and it sees the files and can use them. Not sure how much it helps in real life, but was more or less free. If anyone can improve on these files, please do so. 

Note that I trained it on some of my own panels, so it will have some significant bias towards my dense panels at this time. Better, more generic, panel guidance would probably be more useful for general audience.