Averaging waves which has NaN for some rows

MatrixOP ReplaceNaNs(w, replacementVal)

Function Test()
//	Test Function

	//	Creates three waves to average
	Make/O Wave1={1, 2, NaN, 4, 5}
	Make/O Wave2={3, 2, 1, NaN, -1}
	Make/O Wave3={2, 2, 2, NaN, 2}

	//	Creates a wave reference wave to hold the three waves
	Make/O/FREE/WAVE AllWaves={Wave1, Wave2, Wave3}
	
	//	Averages the waves
	Wave AverageWave=AverageAllWaves(AllWaves)
	
	//	Displays the result
	DoWindow/K AverageTable
	Edit/N=AverageTable Wave1, Wave2, Wave3, AverageWave
End


Function/WAVE AverageAllWaves(AllWaves)
//	Averages all waves ignoring NaNs
Wave/WAVE AllWaves

	//	Calculates the number of waves to average. The waves should all have the same length
	Variable n=NumPnts(AllWaves)
	
	//	Checks that at least one wave exists
	if (n>0)
	
		//	Uses the first wave in the list to create the waves needed for the calculation
		Wave SingleWave=AllWaves[0]
		Duplicate/O/FREE SingleWave, NumTypeWave, DivisionWave, SumWave
		Duplicate/O SingleWave, AverageWave
	
		NumTypeWave=0
		DivisionWave=0
		SumWave=0
		AverageWave=0
	
		//	Counts through the waves one at a time
		Variable i=0
		for (i=0; i<n; i+=1)
	
			//	The next wave to add to the total sum
			Wave SingleWave=AllWaves[i]
		
			//	Checks if any of the values are NaN
			NumTypeWave=(NumType(SingleWave[p])!=2)
		
			//	Adds the value to the total, unless the value is NaN in which case 0 is added
			SumWave+=(NumTypeWave[p]==1 ? SingleWave : 0)
		
			//	Increases the number to divide the sum with by one, unless the value is NaN in which case 0 is added
			DivisionWave+=NumTypeWave[p]
		endfor

		//	Divides the sum by the number of valid data points
		AverageWave=SumWave/DivisionWave
		
		//	Returns the average
		Return AverageWave
	endif
end