Grouping points in XY data into user-defined bins for retrieving statistics

Here's an attempt to write discretize as a user function:

function/wave discretize(wave wX, wave edges)
	Make/free/N=(numpnts(wX), numpnts(edges)) M
	M[][1,] = q * ((wX[p] >= edges[q-1]) && (wX[p] < edges[q]))
	MatrixOP/free wOut = sumRows(M)
	wOut = wOut ? wOut : NaN
	return wOut
end

I assume edges to be monotonic.

The way I did it is probably wildly inefficient. Probably someone will be able to improve upon this.

Here is an arguably better way to do it with a user function:

function/wave discretize(wave wX, wave edges)
	duplicate /free wX wOut
	wOut = BinIndex(wX, edges)
	return wOut
end

function BinIndex(variable xval, wave edges)	
	int i
	int imax = numpnts(edges)
	
	if ( (xval < edges[0]) || (xval>=edges[imax-1]) )
		return NaN
	endif
	
	for (i=1;i<imax;i++)
		if ( (xval >= edges[i-1]) && (xval < edges[i]) )
			return i
		endif
	endfor
	return NaN
end

it's more efficient to use a built-in function:

function/wave discretize(wave wX, wave edges)
	Duplicate /free wX wOut
	wOut = BinIndex(wX, edges)
	return wOut
end

function BinIndex(variable xval, wave edges)
	FindLevel/EDGE=1/P/Q edges, xval
	return v_flag ? NaN : floor(v_levelX) + 1
end

Thank you for your work and thoughts Tony! I had not used FindLevel before, this works very well in the user-defined functions you made.