Lispix format

GBLoadWave

#pragma rtGlobals=1		// Use modern global access method.

// adds a new menu to the right of the help menu
Menu "Lispix Support"
	"Import Lispix Files"
End

// to be called by user (e.g., through menu)
function/S ImportLispixFiles()
	variable refNum
	Open/D/R/T=".rpl"/M="Select one or more ripple (.rpl) files"/MULT=1 refNum
	string filePaths = S_fileName
	if( strlen(filePaths) == 0 )
		print "user cancelled."	
	else
		variable i, numFilesSelected = ItemsInList(filePaths, "\r")
		for( i = 0; i < numFilesSelected; i += 1 )
			string path = StringFromList(i, filePaths, "\r")
			ReadLispixFilePair(path)
		endfor
	endif
	return filePaths
end

// to be called by ImportLispixFiles()
function ReadLispixFilePair(ripplePath)
string ripplePath		// known to be a valid path to a ripple (.rpl) file

// 1. make sure there is an associated raw file, get its name
	string rawPath = ripplePath[0,strlen(ripplePath)-3] + "aw"
	GetFileFolderInfo/Q/Z rawPath
	if( V_Flag != 0 )
		print "no raw file found for "+ParseFilePath(0, ripplePath, ":", 1, 0)
	else
	
// 2. read ripple file, convert to keyword-value string
		variable refNum
		Open/R refNum as ripplePath
		string info = ""
		do
			string line
			FReadLine refNum, line
			if( strlen(line) == 0 )	// end of file
				break	// exit do-while loop
			endif
			if( !cmpstr(line[0],";") )	// comment line
				continue	// skip
			endif
			line = ReplaceString(" ", LowerStr(line), "")	// remove spaces and convert to lower case
			string keyStr, valStr
			sscanf line, "%s %s", keyStr, valStr
			info += keyStr + ":" + valStr + ";"	// convert to Igor-style keyword-value string
		while( 1 )	// exit is through break statement
		Close refNum

// 3. extract info from keyword-value string
		variable offset = NumberByKey("offset", info), byteOrder = 0
		if( !cmpstr(StringByKey("byte-order", info), "little-endian") )
			byteOrder = 1
		endif
		variable igorType = 0, length = NumberByKey("data-length", info)
		string dataType = StringByKey("data-type", info)
		strswitch(dataType)
			case "float":
				if( length == 4 || length == 8 )
					igorType = length/2
				endif
				break
			case "unsigned":
				igorType = 64
				// fall through
			case "signed":
				if( length == 1 || length == 2 || length == 4 )
					igorType += 8*length
				else
					igorType = 0
				endif
				break
		endswitch
		if( igorType == 0 )
			abort "illegal data type/length specification: "+dataType+"/"+num2str(length)
		endif
			
// 4. load raw file
		GBLoadWave /A=lispix /B=(byteOrder) /Q /S=(offset) /T={igorType,igorType} rawPath
		
// 5. report to history and rename wave to filename
		if( V_flag == 0 )
			printf "no waves"
		else
			printf S_waveNames
		endif
		print " loaded from "+S_path+S_fileName+"."
		if( V_Flag == 1 )	// should be one
			string oldName = StringFromList(0, S_waveNames)
			string newName = ParseFilePath(3, ripplePath, ":", 0, 0)
			wave oldWave = $oldName
			Duplicate/O oldWave, $newName
			KillWaves oldWave
			print oldName+" renamed to "+newName

// 6. redimension data cube
			variable width = NumberByKey("width", info)
			variable height = NumberByKey("height", info)
			variable depth = NumberByKey("depth", info)
			Redimension/N=(width, height, depth) $newName
			
// 7. set data scaling
			SetScale/P X, 0, 1, "Å", $newName
			SetScale/P Y, 0, 1, "Å", $newName
			if( !cmpstr(StringByKey("record-by", info), "vector") )
				variable Zscale = NumberByKey("ev-per-chan", info)
				SetScale/P Z, 0, Zscale, "eV", $newName
			else
				SetScale/P Z, 0, 1, "Å", $newName
			endif
	
		endif
	endif
end

harneit wrote: ... should go something like this (not tested! There's a little ambiguity in the doc about "little endian" being "low byte first"; also, scaling information is lacking in the official documentation)

Redimension/N=(width, height, depth) $newName

Redimension/N=(depth,width,height) $newname

newWave[][][] = oldWave[(p + q*width)*depth + r]

KillWaves oldWave

Wave NewWave= $newName

Last week I completed a hack to load raw WiRE files (proprietary filetype used in Renishaw Raman spectrometers, may hold 1d or 2d arrays of spectra and spatial coordinates). Jamie Boyd's BinaryReader procedure was indispensable for figuring out the structure of the binary files. I've used it to hack several file types, including Bruker FTIR files. If you haven't already tried it, you should check it out!

Edit: Oops, I just realized that this is an old thread that was resurrected when links were fixed. Still, I recommend BinaryReader to anyone reading this!