Replace Waves In Table

//	ShowWavesInTable(tableName, title, waveNames)
//	Used to display a list of waves in a table which may or may not already exist.
//	The listed waves replace any waves already displayed in the table.
//	If the table does not already exist, it is created.
//	If the table does already exist, replaces the currently displayed waves in the table with the listed waves.
static Function ShowWavesInTable(tableName, title, waveNames)
	String tableName
	String title
	String waveNames			// Semicolon-separated list
	
	Variable numNewWaves = ItemsInList(waveNames)
	Variable i
	String name
	
	DoWindow $tableName
	if (V_flag == 0)
		Edit /N=$tableName /W=(25,60,1200,700) /K=3 as title
		for(i=0; i<numNewWaves; i+=1)
			name = StringFromList(i, waveNames)
			AppendToTable /W=$tableName $name
			Wave w = $name
			if (CmpStr(WaveUnits(w,-1),"dat")==0 && WaveType(w)==4)		// Is data wave?
				ModifyTable /W=$tableName format($name)=6				// Date format
			endif
		endfor
		ModifyTable /W=$tableName autosize={1, 0, -1, 0, 0}
	else
		String options = "WIN:" + tableName
		String tableWaveList = WaveList("*", ";", options)			// List of waves already in table
		if (CmpStr(tableWaveList,waveNames) != 0)				// Do nothing if table already contains the right waves in the right order
			Variable numOldWaves = ItemsInList(tableWaveList)
			for(i=0; i<numOldWaves; i+=1)					// Remove all old waves
				name = StringFromList(i, tableWaveList)
				Wave w = $name
				RemoveFromTable /W=$tableName w.i, w.l, w.d
			endfor
			for(i=0; i<numNewWaves; i+=1)						// Append all new waves
				name = StringFromList(i, waveNames)
				AppendToTable /W=$tableName $name
				Wave w = $name
				if (CmpStr(WaveUnits(w,-1),"dat")==0 && WaveType(w)==4)		// Is data wave?
					ModifyTable /W=$tableName format($name)=6				// Date format
				endif
			endfor
			ModifyTable /W=$tableName autosize={1, 0, -1, 0, 0}
		endif	
	endif
End